GROUP 1. Run title and other preliminaries
TEXT(Parallel Plate Plasma Reactor :D109
TITLE
DISPLAY
This case simulates a reactor using a plasma to enhance
the gas phase chemistry. The reactor is axisymmetric,
the geometry shown below.
Laminar, steady-state flow is assumed.
The susceptor temperature is 533K.
------> Y
|
|
| Z
V
|************************************| INLET |
|*********** BLOCKAGE****************| |
|____________________________________| |W
C| |A
E| |L
N| PLASMA REGION |L
T| |
R| |
E|-----------WAFER-------------- |W
|******************************| |A
L|******************************| |L
I|******************************| |L
N|********* BLOCKAGE ***********| |
E|******************************| |
|******************************| |W
|******************************| |A
|******************************| |L
|******************************| |L
|______________________________| OUTLET |
ENDDIS
************************************************************
*
* GROUP 2. Transience; time-step specification
*
* Steady-state simulation
STEADY=T
*
************************************************************
*
* GROUP 3. X-direction grid specification
*
CARTES=F
XULAST=0.1; NX=1
*
************************************************************
*
* GROUP 4. Y-direction grid specification
*
YVLAST=1.0;NY=29
YFRAC(1)=-4.;YFRAC(2)=0.005
YFRAC(3)=9.;YFRAC(4)=0.008
YFRAC(5)=2.;YFRAC(6)=0.004
YFRAC(7)=1.;YFRAC(8)=0.002
YFRAC(9)=1.;YFRAC(10)=0.0015
YFRAC(11)=1;YFRAC(12)=0.002
YFRAC(13)=1.;YFRAC(14)=0.0015
YFRAC(15)=1.;YFRAC(16)=0.003
YFRAC(17)=4.;YFRAC(18)=0.005
YFRAC(19)=3.;YFRAC(20)=0.009
YFRAC(21)=1.;YFRAC(22)=0.004
YFRAC(23)=1.;YFRAC(24)=0.002
*
************************************************************
*
* GROUP 5. Z-direction grid specification
*
ZWLAST=1.; NZ=19
ZFRAC(1)=-1.;ZFRAC(2)=0.01
ZFRAC(3)=2.;ZFRAC(4)=0.001
ZFRAC(5)=7.;ZFRAC(6)=0.0022
ZFRAC(7)=2.;ZFRAC(8)=0.001
ZFRAC(9)=2.;ZFRAC(10)=0.0026
ZFRAC(11)=4.;ZFRAC(12)=0.0052
ZFRAC(13)=1.;ZFRAC(14)=0.01
*
************************************************************
*
* GROUP 6. Body-fitted coordinates or grid distortion
*
************************************************************
*
* GROUP 7. Variables stored, solved & named
*
SOLVE(P1,V1,W1,TEM1)
SOLUTN(P1,Y,Y,Y,N,N,N)
SOLUTN(TEM1,Y,Y,Y,N,N,Y)
** Specify species
** Numbers refer to the integer indices in species database
NAME(C1)=S140
NAME(C2)=S142
NAME(C3)=S145
NAME(C4)=S158
NAME(C5)=S80
** Note that one mass fraction is STOREd and the rest SOLVEd
STORE(S140)
SOLVE(S142)
SOLVE(S145)
SOLVE(S158)
SOLVE(S80)
** Use wholefield solver and harmonic averaging
** for mass fractions
SOLUTN(S142,Y,Y,Y,N,N,Y)
SOLUTN(S145,Y,Y,Y,N,N,Y)
SOLUTN(S158,Y,Y,Y,N,N,Y)
SOLUTN(S80,Y,Y,Y,N,N,Y)
** Plasma features
** All variables are solved whole-field
SOLVE(PHI1,PHI2,NE,T0)
STORE(PHIT,GAMM,GION)
SOLUTN(NE ,Y,Y,Y,N,N,Y)
SOLUTN(T0 ,Y,Y,Y,N,N,Y)
SOLUTN(PHI1,Y,Y,Y,N,N,Y)
SOLUTN(PHI2,Y,Y,Y,N,N,Y)
** Additional STOREd varaibles
STORE(RHO1,VPOR,DEPO)
STORE(PRPS,BLOK,ENUL)
STORE(SPHT)
*
************************************************************
*
* GROUP 8. Terms (in differential equations) & devices
*
* Activate block-correction
IVARBK=-1; ISOLBK=1
ISOLX=0; ISOLY=0; ISOLZ=0
** Activate user sources to include additional source terms
USOURC=T;UDIFNE=T;DIFCUT=0.0
** Add diffusion term to pressure correction equation to aid
** convergence
ADDDIF=T
** For pure diffusion, cut out built-in source and convection
** term
TERMS(NE ,N,N,Y,P,Y,N)
TERMS(PHI1,N,N,Y,P,Y,N)
TERMS(PHI2,N,N,Y,P,Y,N)
TERMS(T0 ,N,N,Y,P,Y,N)
*
************************************************************
*
* GROUP 9. Properties of the medium (or media)
SETPRPS(1,70,Q1)
** Diffusivities for species MUST be set to -GRND8
** Diffusion law is selected by SPEDAT below
PRNDTL(S140)=-GRND8
PRNDTL(S142)=-GRND8
PRNDTL(S145)=-GRND8
PRNDTL(S158)=-GRND8
PRNDTL(S80) =-GRND8
** Diffusivities for plasma variables must be set to -GRND7
PRNDTL(PHI1)=-GRND7
PRNDTL(PHI2)=-GRND7
PRNDTL(NE) =-GRND7
PRNDTL(T0) =-GRND7
* Reference pressure (N/m^2)
PRESS0=10
** For material definition, values MUST be set to GRND8
** Property option is selected by SPEDAT below
CSG10 = 'Q1'
MATFLG=T;IMAT=1
70 GRND8 GRND8 GRND8 GRND8 1.000
0.0 0.0 0.0
0.0 0.0 0.0
0.0 0.0 0.0
0.0 0.0 0.0
*
************************************************************
*
* GROUP 10. Inter-phase-transfer processes and properties
*
************************************************************
*
* GROUP 11. Initialization of variable or porosity fields
*
INIADD=F
FIINIT(P1)=0.0
FIINIT(W1)=0.0
FIINIT(V1)=0.0
FIINIT(S140)=1.0
FIINIT(S142)=1.E-10
FIINIT(S145)=1.E-10
FIINIT(S158)=1.E-10
FIINIT(S80) =1.E-10
FIINIT(TEM1)=300
FIINIT(BLOK)=1
FIINIT(PRPS)=-1
** Plasma features inititalisation
FIINIT(NE)=0.01
FIINIT(T0)=1.1E4
FIINIT(PHI1)=100
FIINIT(PHI2)=0
** Non-participating blockages are used
** Upper Electrode **
CONPOR(0.0,VOLUME,1,NX,1,24,1,1)
** Lower Electrode **
CONPOR(0.0,VOLUME,1,NX,1,15,13,NZ)
*
************************************************************
*
* GROUP 12. Convection and diffusion adjustments
*
************************************************************
*
* GROUP 13. Boundary conditions and special sources
*
REAL(PI,TAREA)
PI=3.14159
TAREA=PI*(0.163*0.163-0.13*0.13)
** Volumetric Flow Inlet **
** P1 VAL gives volumetric flow rate in sccm
** Normal vel. (W1) VAL gives area of inlet
** Species VALs give volume fraction at inlet
PATCH(VIN1,LOW,1,NX,25,NY,1,1,1,1)
COVAL(VIN1,P1,FIXFLU,10.0)
COVAL(VIN1,W1,ONLYMS,TAREA)
COVAL(VIN1,S140,ONLYMS,1.0)
COVAL(VIN1,S142,ONLYMS,0.0)
COVAL(VIN1,S145,ONLYMS,0.0)
COVAL(VIN1,S158,ONLYMS,0.0)
COVAL(VIN1,S80,ONLYMS,0.0)
COVAL(VIN1,TEM1,ONLYMS,300.)
** Outlet **
PATCH(OUTLET,HIGH,1,NX,16,NY,NZ,NZ,1,1)
COVAL(OUTLET,P1,FIXP,0.0)
COVAL(OUTLET,S142,ONLYMS,SAME)
COVAL(OUTLET,S145,ONLYMS,SAME)
COVAL(OUTLET,S158,ONLYMS,SAME)
COVAL(OUTLET,S80,ONLYMS,SAME)
COVAL(OUTLET,TEM1,ONLYMS,SAME)
** Substrate **
PATCH(SUBS,HIGH,1,NX,1,15,12,12,1,1)
COVAL(SUBS,TEM1,FIXVAL,533.)
COVAL(SUBS,PHI1,FIXFLU,GRND7)
COVAL(SUBS,PHI2,FIXFLU,GRND7)
COVAL(SUBS,NE,GRND7,0)
PATCH(SUBS1,SOUTH,1,NX,16,16,13,NZ,1,1)
COVAL(SUBS1,PHI1,FIXFLU,GRND7)
COVAL(SUBS1,PHI2,FIXFLU,GRND7)
COVAL(SUBS1,NE,GRND7,0)
** Cooled no-slip outer wall, earthed **
PATCH(WALL0,NWALL,1,NX,NY,NY,1,NZ,1,1)
COVAL(WALL0,TEM1,1.0,300.)
COVAL(WALL0,W1,1.0,0.0)
PATCH(WALL01,NORTH,1,NX,NY,NY,1,NZ,1,1)
COVAL(WALL01,PHI1,FIXFLU,GRND7)
COVAL(WALL01,PHI2,FIXFLU,GRND7)
COVAL(WALL01,NE,GRND7,0)
** Cooled Upper Electrode **
PATCH(ELEPBOT,LWALL,1,NX,1,24,2,2,1,1)
COVAL(ELEPBOT,TEM1,1.0,300.)
PATCH(ELE1BOT,LOW,1,NX,1,15,2,2,1,1)
COVAL(ELE1BOT,PHI1,FIXFLU,GRND7)
COVAL(ELE1BOT,PHI2,FIXFLU,GRND7)
COVAL(ELE1BOT,NE,GRND7,0)
PATCH(ELRING,LOW,1,NX,16,24,2,2,1,1)
COVAL(ELRING,PHI1,FIXFLU,GRND7)
COVAL(ELRING,PHI2,FIXFLU,GRND7)
COVAL(ELRING,NE,GRND7,0)
** Ionization sources **
PATCH(COOL,VOLUME,1,NX,1,NY,1,NZ,1,LSTEP)
COVAL(COOL,T0,GRND7,GRND7)
COVAL(COOL,NE,GRND7,GRND7)
PATCH(IONIZE,VOLUME,1,NX,1,NY,1,NZ,1,1)
COVAL(IONIZE,NE,GRND7,GRND7)
COVAL(IONIZE,T0,GRND7,GRND7)
** Gas phase chemistry source term **
PATCH(CHEM,VOLUME,1,NX,1,NY,1, NZ,1,1)
COVAL(CHEM,S142,GRND1,GRND1)
COVAL(CHEM,S145,GRND1,GRND1)
COVAL(CHEM,S158,GRND1,GRND1)
COVAL(CHEM,S80,GRND1,GRND1)
COVAL(CHEM,TEM1,GRND1,GRND1)
** Automatic underrelaxation for chemistry **
PATCH(RELT,PHASEM,1,NX,1,NY,1,NZ,1,1)
COVAL(RELT,S142,GRND1,SAME)
COVAL(RELT,S145,GRND1,SAME)
COVAL(RELT,S158,GRND1,SAME)
COVAL(RELT,S80,GRND1,SAME)
** For surface chemistry, COVALs must be specified for ALL
** species, P1 and TEM1. Additionally, CO for P1 set to 1.0
** to indicate simple single wafer. CO of > 1.0 is used to
** represent multiple (batch) wafers.
* Surface chemistry source term
PATCH(SURF1,HIGH,1,NX,1,15,12,12,1,1)
COVAL(SURF1,P1,1.000,GRND1)
COVAL(SURF1,S142,FIXFLU,GRND1)
COVAL(SURF1,S145,FIXFLU,GRND1)
COVAL(SURF1,S158,FIXFLU,GRND1)
COVAL(SURF1,S80,FIXFLU,GRND1)
COVAL(SURF1,TEM1,FIXFLU,GRND1)
*
************************************************************
*
* GROUP 14. Downstream pressure for PARAB=.TRUE.
*
************************************************************
*
* GROUP 15. Termination of sweeps
*
* Number of sweeps
LSWEEP=300
*
************************************************************
*
* GROUP 16. Termination of iterations
*
SELREF=T; RESFAC = 1.000E-03
** Increase iterations to speed up convergence
LITER (S142) = 200 ;LITER (S145) = 200
LITER (S158) = 200 ;LITER (S80 ) = 200
*
************************************************************
*
* GROUP 17. Under-relaxation devices
*
** P1 highly relaxed because ADDDIF=T
RELAX(P1,LINRLX,0.3)
RELAX(V1,FALSDT,1.E-4)
RELAX(W1,FALSDT,1.E-4)
RELAX(TEM1,LINRLX,0.3)
RELAX(S142,FALSDT,1.E-0)
RELAX(S145,FALSDT,1.E-0)
RELAX(S158,FALSDT,1.E-0)
RELAX(S80,FALSDT,1.E-0)
RELAX(PHI2,FALSDT,1.0E-6)
RELAX(PHI1,FALSDT,1.0E-6)
RELAX(NE,FALSDT,1.0E-8)
RELAX(T0,FALSDT,1.0E-8)
*
************************************************************
*
* GROUP 18. Limits on variables or increments to them
*
** Minimum value for species set to 1.0E-20
VARMIN(S140)=1.0E-20; VARMAX(S140)=1.0
VARMIN(S142)=1.0E-20; VARMAX(S142)=1.0
VARMIN(S145)=1.0E-20; VARMAX(S145)=1.0
VARMIN(S158)=1.0E-20; VARMAX(S158)=1.0
VARMIN(S80) =1.0E-20; VARMAX(S80) =1.0
VARMIN(TEM1)=260.; VARMAX(TEM1)=2000.
** Protection needed to prevent negative absolute pressures
** during convergence
VARMIN(P1)=-0.8*PRESS0
*
************************************************************
*
* GROUP 19. Data communicated by satellite to GROUND
*
** SPEDAT used for passing options and additional information
** to GROUND.
** MCDOPT = 2 Wilke Multi-component Diffusion Law
** BINOPT = 4 Bin. diff. coeff. based on actual temperature
** MCPROP = 3 Multi-component properties based on local gas
** mixture and local gas temperature
** CHMRLX = 0.5 Relaxation factor for RELT patch
** NGREAC/NSEARC Number of gas/surface reactions
** GREAC/SREAC Integer index of gas/surface reactions in
** chemistry database
** PHIPAR
** NEPAR
** T0PAR
** LNELIM = T Limit NE value in diff. coeff. calculation
SPEDAT(SET,CVD,MCDOPT,I,2)
SPEDAT(SET,CVD,BINOPT,I,4)
SPEDAT(SET,CVD,MCPROP,I,3)
SPEDAT(SET,CVD,CHMRLX,R,1.0)
SPEDAT(SET,CVD,NGREAC,I,3)
SPEDAT(SET,CVD,GREAC(1),I,18)
SPEDAT(SET,CVD,GREAC(2),I,21)
SPEDAT(SET,CVD,GREAC(3),I,22)
SPEDAT(SET,CVD,NSREAC,I,2)
SPEDAT(SET,CVD,SREAC(1),I,19)
SPEDAT(SET,CVD,SREAC(2),I,20)
SPEDAT(SET,CVD,PHIPAR(1),R,2)
SPEDAT(SET,CVD,PHIPAR(2),R,0.8)
SPEDAT(SET,CVD,PHIPAR(3),R,0.0)
SPEDAT(SET,CVD,PHIPAR(4),R,200.0)
SPEDAT(SET,CVD,NEPAR(1),R,18.0)
SPEDAT(SET,CVD,NEPAR(2),R,5.E5)
SPEDAT(SET,CVD,NEPAR(3),R,3.E5)
SPEDAT(SET,CVD,NEPAR(4),R,1.3E5)
SPEDAT(SET,CVD,NEPAR(5),R,0.18)
SPEDAT(SET,CVD,T0PAR(2),R,0.3)
SPEDAT(SET,CVD,T0PAR(1),R,0.35E4)
SPEDAT(SET,CVD,T0PAR(3),R,6.E5)
SPEDAT(SET,CVD,T0PAR(4),R,1.0E4)
SPEDAT(SET,CVD,LNELIM,L,F)
SPEDAT(SET,CVD,RADCVD,L,T)
NAMGRD=CVD
*
************************************************************
*
* GROUP 20. Preliminary print-out
*
************************************************************
*
* GROUP 21. Print-out of variables
*
************************************************************
*
* GROUP 22. Spot-value print-out
*
IXMON=1
IYMON=1
IZMON=12
TSTSWP=-1
*
************************************************************
*
* GROUP 23. Field print-out and plot control
*
YZPR=T
*
************************************************************
*
* GROUP 24. Preparation for continuation runs.
*
************************************************************
RESTRT(ALL)
RSTPRP=T