GROUP 1. Run title and other preliminaries
TEXT(Tungsten Reactor - normal inlet :D104
TITLE
DISPLAY
This file simulates a simple chemical vapour deposition
reactor for depositing tungsten; the reactor is axisymmetric
and the geometry was provided by Siemens.
Laminar, steady-state flow is assumed.
The susceptor temperature is 733K.
------> Y
|
|
| Z
V
| OUTLET |**********************|
C| |**********************|
E| |**********************|
N| |***** BLOCKAGE *******|W
T| |**********************|A
R| |**********************|L
E| |______________________|L
| |
L| |
I| |
N| |W
E| |A
|***************************************| |L
|********************** BLOCKAGE *******| |L
|***************************************| |
|******* INLET *************************| |
| | | | | | | |*****| |W
| V V V V V V |*****| |A
| |*****| |L
| |*****| |L
| |*****| |
|___________________________ |*****| |
|****** SUSCEPTOR **********| |_____| |
|***************************| |
|______________________________________________|
FLOOR
ENDDIS
************************************************************
*
* GROUP 2. Transience; time-step specification
*
* Steady-state simulation
STEADY=T
*
************************************************************
*
* GROUP 3. X-direction grid specification
*
CARTES=F
XULAST=0.1
*
************************************************************
*
* GROUP 4. Y-direction grid specification
*
YVLAST=1.0
NY=21
YFRAC(1)= -7 ; YFRAC(2)= 0.010
YFRAC(3)= 2 ; YFRAC(4)= 0.009
YFRAC(5)= 2 ; YFRAC(6)= 0.007
YFRAC(7)= 2 ; YFRAC(8)= 0.0075
YFRAC(9)= 2 ; YFRAC(10)= 0.006
YFRAC(11)= 2 ; YFRAC(12)= 0.009
YFRAC(13)= 4 ; YFRAC(14)= 0.0025
*
************************************************************
*
* GROUP 5. Z-direction grid specification
*
ZWLAST=1.0
NZ=23
ZFRAC(1)= -5 ; ZFRAC(2)= 0.010
ZFRAC(3)= 1 ; ZFRAC(4)= 0.0035
ZFRAC(5)= 4 ; ZFRAC(6)= 0.010
ZFRAC(7)= 1 ; ZFRAC(8)= 0.0035
ZFRAC(9)= 2 ; ZFRAC(10)= 0.010
ZFRAC(11)= 1 ; ZFRAC(12)= 0.006
ZFRAC(13)= 6 ; ZFRAC(14)= 0.005333
ZFRAC(15)= 1 ; ZFRAC(16)= 0.004
ZFRAC(17)= 2 ; ZFRAC(18)= 0.005
*
************************************************************
*
* GROUP 6. Body-fitted coordinates or grid distortion
*
************************************************************
*
* GROUP 7. Variables stored, solved & named
*
SOLVE(P1,V1,W1,TEM1)
SOLUTN(P1 ,Y,Y,Y,N,N,N)
SOLUTN(TEM1,Y,Y,Y,N,N,Y)
** Specify species
** Numbers refer to the integer indices in species database
NAME(C1) = S177
NAME(C2) = S80
NAME(C3) = S97
** Note that one mass fraction is STOREd and the rest SOLVEd
STORE(S177)
SOLVE(S80)
SOLVE(S97)
** Use wholefield solver and harmonic averaging
** for mass fractions
SOLUTN(S80,Y,Y,Y,N,N,Y)
SOLUTN(S97,Y,Y,Y,N,N,Y)
** Additional STOREd varaibles
STORE(RHO1)
STORE(VPOR)
STORE(EMIS)
STORE(CNDT)
STORE(SPHT)
** Deposition rate
STORE(DEPO)
STORE(PRPS,BLOK,ENUL)
*
************************************************************
*
* GROUP 8. Terms (in differential equations) and devices.
*
IVARBK=-1;ISOLBK=1
ISOLX=0;ISOLY=0;ISOLZ=0
** Activate user sources to include additional source terms
USOURC=T;UDIFNE=T;DIFCUT=0.0
*
************************************************************
*
* GROUP 9. Properties of the medium (or media).
*
** Diffusivities for species MUST be set to -GRND8
** Diffusion law is selected by SPEDAT below
PRNDTL(S177) = -GRND8
PRNDTL(S80) = -GRND8
PRNDTL(S97) = -GRND8
* Reference pressure (N/m^2)
PRESS0=133.0
* Take values from the property library
;
;
** For material definition, values MUST be set to GRND8
** Property option is selected by SPEDAT below
CSG10 = 'q1'
MATFLG=T;IMAT=2
70 GRND8 GRND8 GRND8 GRND8 1.000
0.0 0.0 0.0
0.0 0.0 0.0
0.0 0.0 0.0
0.0 0.0 0.0
154 1.926E4 1.0 134.0 178.0 0.0
*
************************************************************
*
* GROUP 10. Inter-phase-transfer processes and properties
*
************************************************************
*
* GROUP 11. Initialization of variable or porosity fields
*
INIADD=F
FIINIT( P1 ) = 0.0
FIINIT( W1 ) = 0.0
FIINIT( V1 ) = 0.0
FIINIT(TEM1) = 293
FIINIT( S177 ) = 0.94
FIINIT( S80 ) = 0.06
FIINIT( S97 ) = 1.0E-10
FIINIT(BLOK) = 1.0
FIINIT(VPOR) = 1.0
FIINIT(PRPS) = 70
FIINIT(EMIS) = 0.0
** Participating and non-participating blockages are used
** A PRPS value of 111 refers to steel which is a built-in
** material
** Wafer & heater
CONPOR(BLK1,-1.0,CELL,1,NX, 1,13,21,NZ)
COVAL (BLK1,PRPS,0.0,154)
COVAL (BLK1,BLOK,0.0,2)
** Block
CONPOR(BLK2, 0.0,CELL,1,NX,11,NY, 1, 5)
** Block off shower head area
CONPOR(BLK3,-1.0,CELL,1,NX, 1,17,12,14)
COVAL (BLK3,PRPS,0.0,111)
COVAL (BLK3,BLOK,0.0,3)
CONPOR(BLK4,-1.0,CELL,1,NX,16,17,15,21)
COVAL (BLK4,PRPS,0.0,111)
COVAL (BLK4,BLOK,0.0,3)
*
************************************************************
*
* GROUP 12. Convection and diffusion adjustments
*
************************************************************
*
* GROUP 13. Boundary conditions and special sources
*
REAL(RHOIN,UAV)
RHOIN=1.7E-3
UAV =1.345*3.
* INLET Boundary Condition
INLET(INLET,LOW,1,1,1,11,15,15,1,LSTEP)
VALUE(INLET,TEM1,293.)
VALUE(INLET,P1,UAV*RHOIN)
VALUE(INLET,W1,UAV)
VALUE(INLET,S177,0.94)
VALUE(INLET,S80,0.06)
VALUE(INLET,S97,0.000)
* OUTLET Boundary Condition
OUTLET(OUT,LOW,1,1,1,10,1,1,1,LSTEP)
VALUE(OUT,V1,SAME)
VALUE(OUT,W1,SAME)
VALUE(OUT,P1,0)
VALUE(OUT,TEM1,SAME)
VALUE(OUT,S177,SAME)
VALUE(OUT,S80,SAME)
VALUE(OUT,S97,SAME)
* Wafer surface
PATCH(WAFER,CELL,1,1,1,11,21,23,1,LSTEP)
COVAL(WAFER,TEM1,FIXVAL,733)
* Floor
PATCH(FLOOR,HWALL,1,1,14,NY,NZ,NZ,1,LSTEP)
COVAL(FLOOR,V1,1,0)
COVAL(FLOOR,TEM1,1.0,328)
* Outer wall
PATCH(WALL,NWALL,1,1,NY,NY,6,NZ,1,LSTEP)
COVAL(WALL,W1,1,0)
COVAL(WALL,TEM1,1.0,328)
* Large block (bottom)
PATCH(LBCKB,LWALL,1,1,11,NY,6,6,1,LSTEP)
COVAL(LBCKB,TEM1,1.0,328)
* Large block (side)
PATCH(LBCKL,NWALL,1,1,10,10,1,5,1,LSTEP)
COVAL(LBCKL,TEM1,1.0,328)
* Gas phase chemistry source term
PATCH(CHEM,VOLUME,1,NX,1,NY,1,NZ,1,LSTEP)
COVAL(CHEM,TEM1,GRND1,GRND1)
COVAL(CHEM,S80,GRND1,GRND1)
COVAL(CHEM,S97,GRND1,GRND1)
CHEM=SKIP
** For surface chemistry, COVALs must be specified for ALL
** species, P1 and TEM1. Additionally, CO for P1 set to 1.0
** to indicate simple single wafer. CO of > 1.0 is used to
** represent multiple (batch) wafers.
* Surface chemistry source term
PATCH(SURF1,HIGH,1,NX,1,13,20,20,1,LSTEP)
COVAL(SURF1,S80,FIXFLU,GRND1)
COVAL(SURF1,S97,FIXFLU,GRND1)
COVAL(SURF1,P1,1.000,GRND1)
COVAL(SURF1,TEM1,FIXFLU,GRND1)
* Automatic underrelaxation for chemistry
PATCH(RELT,PHASEM,1,NX,1,NY,1,NZ,1,LSTEP)
COVAL(RELT,S80,GRND1,SAME)
COVAL(RELT,S97,GRND1,SAME)
RELT=SKIP
* Radiation patches
** S2SR=T activates surface-to-surface radiation
S2SR=T
IF(S2SR) THEN
PATCH(@RI001,LOW,1,NX,1,13,21,21,1,LSTEP)
COVAL(@RI001,TEM1,GRND1,GRND1)
COVAL(@RI001,EMIS, 154 , 733.0 )
PATCH(@RI002,NORTH,1,NX,13,13,21,NZ,1,LSTEP)
COVAL(@RI002,TEM1,GRND1,GRND1)
COVAL(@RI002,EMIS, 154 , 733.0 )
PATCH(@RI003,HIGH,1,NX,14,NY,NZ,NZ,1,LSTEP)
COVAL(@RI003,TEM1, 0.0 ,328.0)
COVAL(@RI003,EMIS, 111 ,328.0 )
PATCH(@RI004,NORTH,1,NX,NY,NY,6,NZ,1,LSTEP)
COVAL(@RI004,TEM1, 0.0 ,328.0)
COVAL(@RI004,EMIS, 111 ,328.0 )
PATCH(@RI005,LOW,1,NX,11,NY,6,6,1,LSTEP)
COVAL(@RI005,TEM1, 0.0 ,328.0)
COVAL(@RI005,EMIS, 111 ,328.0 )
PATCH(@RI006,NORTH,1,NX,10,10,1,5,1,LSTEP)
COVAL(@RI006,TEM1, 0.0 ,328.0)
COVAL(@RI006,EMIS, 111 ,328.0 )
PATCH(@RI007,LOW,1,NX,1,10,1,1,1,LSTEP)
COVAL(@RI007,TEM1, 0.0 , 300 )
COVAL(@RI007,EMIS, 111 , 300.0 )
PATCH(@RI008,LOW,1,NX,1,17,12,12,1,LSTEP)
COVAL(@RI008,TEM1,GRND1,GRND1)
COVAL(@RI008,EMIS, 111 , 440.0 )
PATCH(@RI009,NORTH,1,NX,17,17,12,21,1,LSTEP)
COVAL(@RI009,TEM1,GRND1,GRND1)
COVAL(@RI009,EMIS, 111 , 440.0 )
PATCH(@RI010,HIGH,1,NX,16,17,21,21,1,LSTEP)
COVAL(@RI010,TEM1,GRND1,GRND1)
COVAL(@RI010,EMIS, 111 , 440.0 )
PATCH(@RI011,SOUTH,1,NX,16,16,15,21,1,LSTEP)
COVAL(@RI011,TEM1,GRND1,GRND1)
COVAL(@RI011,EMIS, 111 , 440.0 )
PATCH(@RI012,HIGH,1,NX,1,15,14,14,1,LSTEP)
COVAL(@RI012,TEM1,GRND1,GRND1)
COVAL(@RI012,EMIS, 111 , 440.0 )
ENDIF
*
************************************************************
*
* GROUP 14. Downstream pressure for PARAB=.TRUE.
*
************************************************************
*
* GROUP 15. Termination of sweeps
*
* Number of sweeps
LSWEEP=200
*
************************************************************
*
* GROUP 16. Termination of iterations
*
SELREF=T; RESFAC=1.0000E-06
*
************************************************************
*
* GROUP 17. Under-relaxation devices
*
RELAX(TEM1,LINRLX,0.7)
RELAX(P1,LINRLX,1.0)
RELAX(V1,FALSDT,1E3)
RELAX(W1,FALSDT,1E3)
** Extra underrelaxation for concentrations, independent
** of chemistry
REAL(TREL)
TREL=1.0E2
RELAX(S80,FALSDT,TREL)
RELAX(S97,FALSDT,TREL)
*
************************************************************
*
* GROUP 18. Limits on variables or increments to them
*
** Minimum value for species set to 1.0E-20
VARMIN(S177) = 1.0E-20; VARMAX(S177) = 1.0
VARMIN(S80) = 1.0E-20; VARMAX(S80) = 1.0
VARMIN(S97) = 1.0E-20; VARMAX(S97) = 1.0
VARMIN(TEM1)=293.0; VARMAX(TEM1)=1000.0
** Protection to prevent negative absolute pressures during
** convergence
VARMIN(P1) = -0.8*PRESS0
*
************************************************************
*
* GROUP 19. Data communicated by satellite to GROUND
*
** SPEDAT used for passing options and additional information
** to GROUND.
** MCDOPT = 2 Wilke Multi-component Diffusion Law
** BINOPT = 4 Bin. diff. coeff. based on actual temperature
** MCPROP = 3 Multi-component properties based on local gas
** mixture and local gas temperature
** CHMRLX = 0.5 Relaxation factor for RELT patch
** NGREAC/NSEARC Number of gas/surface reactions
** GREAC/SREAC Integer index of gas/surface species in
** chemistry database
SPEDAT(SET,CVD,MCDOPT,I,2)
SPEDAT(SET,CVD,BINOPT,I,4)
SPEDAT(SET,CVD,MCPROP,I,3)
SPEDAT(SET,CVD,CHMRLX,R,0.5)
SPEDAT(SET,CVD,NGREAC,I,0)
SPEDAT(SET,CVD,NSREAC,I,1)
SPEDAT(SET,CVD,SREAC(1),I,17)
SPEDAT(SET,CVD,RADCVD,L,T)
NAMGRD=CVD
*
************************************************************
*
* GROUP 20. Preliminary print-out
*
************************************************************
*
* GROUP 21. Print-out of variables
*
************************************************************
*
* GROUP 22. Spot-value print-out
*
IYMON=12; IZMON=19
TSTSWP=-1
*
************************************************************
*
* GROUP 23. Field print-out and plot control
*
************************************************************
*
* GROUP 24. Preparation for continuation runs.
*
************************************************************
RESTRT(ALL)
RSTPRP=T