GROUP 1. Run identifiers and other preliminaries.
TEXT(ASM Single Wafer Si3N4 Reactor :D103
TITLE
DISPLAY
This q1 file simulates an ASM single wafer chemical vapour
deposition reactor using Wilke diffusion and
Langmuir-Hinshelwood Si3N4 chemistry; the reactor is
axisymmetric and the geometry was provided by TU Delft.
Laminar, steady-state flow is assumed.
ENDDIS
------> Y
|
|
| Z
V
| INLET FLOW |**********************|
C| PLUG PROFILE |**********************|
E|||||||||||||||||||||||**********************|
N|VVVVVVVVVVVVVVVVVVVVV|***** BLOCKAGE *******|W
T| |**********************|A
R| | |**********************|L
E| V | ___________________|L
| |**| |
L| |**| |
I| | |**| |
N| V |**| |
E| |__| |
| |
| | |W
C| V |A
E| --> --> | |L
N| V |L
T| |
R| |
E|___________________________ |
|****** SUSCEPTOR **********| | |
L|***************************|_______ V |
I|***********************************| |
N|***********************************| |W
E|***********************************| |A
|***********************************| | |L
|************ BLOCKAGE *************| V |L
|***********************************| |
|***********************************| |
|***********************************| |
|***********************************|PRESSURE|
|***********************************| OUTLET |
************************************************************
*
* GROUP 2. Time-dependence and related parameters.
*
* Steady-state simulation
STEADY=T
*
************************************************************
*
* GROUP 3. x-direction grid specification.
*
CARTES=F
*
* Total number of REGIONS in X direction 1
* Total number of cells in X direction 1
* Total length in X direction 0.01 RAD
*
NREGX=1;REGEXT(X,1)
IREGX=1;GRDPWR(X,1,0.01,1)
*
************************************************************
*
* GROUP 4. y-direction grid specification.
*
* Total number of REGIONS in Y direction 5
* Total number of cells in Y direction 18
* Total length in Y direction 2.1000E-01 m
*
NREGY=5;REGEXT(Y,1)
IREGY=1;GRDPWR(Y,10,0.10,1)
IREGY=2;GRDPWR(Y,1,0.005,1)
IREGY=3;GRDPWR(Y,1,0.015,1)
IREGY=4;GRDPWR(Y,2,0.035,1)
IREGY=5;GRDPWR(Y,4,0.055,1)
*
************************************************************
*
* GROUP 5. z-direction grid specification.
*
* Total number of REGIONS in Z direction 5
* Total number of cells in Z direction 26
* Total length in Z direction 3.4000E-01 m
*
NREGZ=5;REGEXT(Z,1)
IREGZ=1;GRDPWR(Z,5,0.10,1)
IREGZ=2;GRDPWR(Z,2,0.04,1)
IREGZ=3;GRDPWR(Z,12,0.095,-1.2)
IREGZ=4;GRDPWR(Z,1,0.005,1.0)
IREGZ=5;GRDPWR(Z,6,0.10,-0.9)
*
************************************************************
*
* GROUP 6. Body-fitting and other grid distortions.
*
************************************************************
*
* GROUP 7. Variables (including porosities) named,
* stored & solved.
*
SOLVE(P1,V1,W1,TEM1)
SOLUTN(P1,Y,Y,Y,N,N,N)
SOLUTN(TEM1,Y,Y,Y,N,N,Y)
** Specify species
** Numbers refer to the integer indices in species database
NAME(C1) = S226
NAME(C2) = S125
NAME(C3) = S227
NAME(C4) = S80
NAME(C5) = S174
NAME(C6) = S116
** Note that one mass fraction is STOREd and the rest SOLVEd
STORE(S226)
SOLVE(S125)
SOLVE(S227)
SOLVE(S80)
SOLVE(S174)
SOLVE(S116)
** Use wholefield solver and harmonic averaging
** for mass fractions
SOLUTN(S125,Y,Y,Y,N,N,Y)
SOLUTN(S227,Y,Y,Y,N,N,Y)
SOLUTN(S80,Y,Y,Y,N,N,Y)
SOLUTN(S174,Y,Y,Y,N,N,Y)
SOLUTN(S116,Y,Y,Y,N,N,Y)
** Additional STOREd varaibles
STORE(RHO1)
STORE(VPOR)
STORE(EMIS)
STORE(CNDT)
STORE(SPHT)
** Deposition rate
STORE(DEPO)
STORE(PRPS,BLOK,ENUL)
*
************************************************************
*
* GROUP 8. Terms (in differential equations) and devices.
*
* Activate block-correction
IVARBK=-1;ISOLBK=1
ISOLX=0;ISOLY=0;ISOLZ=0
** Activate user sources to include additional source terms
USOURC=T;UDIFNE=T;DIFCUT=0.0
*
************************************************************
*
* GROUP 9. Properties of the medium (or media).
SETPRPS(1,70,Q1)
** Diffusivities for species MUST be set to -GRND8
** Diffusion law is selected by SPEDAT below
PRNDTL(S226) = -GRND8
PRNDTL(S125) = -GRND8
PRNDTL(S227) = -GRND8
PRNDTL(S80) = -GRND8
PRNDTL(S174) = -GRND8
PRNDTL(S116) = -GRND8
* Reference pressure (N/m^2)
PRESS0=133.0
** For material definition, values MUST be set to GRND8
** Property option is selected by SPEDAT below
CSG10 = 'q1'
MATFLG=T;IMAT=1
70 GRND8 GRND8 GRND8 GRND8 1.000
0.0 0.0 0.0
0.0 0.0 0.0
0.0 0.0 0.0
0.0 0.0 0.0
*
************************************************************
*
* GROUP 10. Interphase-transfer processes and properties.
*
************************************************************
*
* GROUP 11. Initialization of fields of variables,
* porosities, etc.
*
INIADD=F
FIINIT( P1 ) = 0.0
FIINIT( V1 ) = 0.0
FIINIT( W1 ) = 0.0
FIINIT(TEM1) = 290
FIINIT( S226 ) = 0.887
FIINIT( S125 ) = 0.113
FIINIT( S227 ) = 1.0E-10
FIINIT( S80 ) = 1.0E-10
FIINIT( S174 ) = 1.0E-10
FIINIT( S116 ) = 1.0E-10
FIINIT(VPOR) = 1.0
FIINIT(EMIS) = 0.0
FIINIT(PRPS) = -1
FIINIT(BLOK) = 1.0
** Participating and non-participating blockages are used
** A PRPS value of 111 refers to steel which is a built-in
** material
* Blockages
CONPOR(WAL1,-1,CELL,-#1,-#1,-#1,-#3,-#4,-#4)
COVAL(WAL1,PRPS,0.0,111)
COVAL(WAL1,BLOK,0.0,2)
CONPOR(WAL2,0,CELL,-#1,-#1,-#2,-#5,-#1,-#1)
CONPOR(WAL3,-1,CELL,-#1,-#1,-#2,-#2,-#2,-#2)
COVAL(WAL3,PRPS,0.0,111)
COVAL(WAL3,BLOK,0.0,4)
CONPOR(WAL4,0,CELL,-#1,-#1,-#1,-#4,-#5,-#5)
*
************************************************************
*
* GROUP 12. Convection and diffusion adjustments
*
************************************************************
*
* GROUP 13. Boundary conditions and special sources
*
REAL(SCDCS,SCAMM,RDIUS)
REAL(RHOIN,UAV,MFDCS,MFAMM)
* Input: Radius of inlet, inlet mass flow of SiH2Cl2 and NH3 in
sccm
RDIUS = 0.1
SCDCS = 60
SCAMM =200
* Calculating inlet velocity, density and mass fractions
UAV = (SCDCS+SCAMM)*5.31E-4/(PRESS0*RDIUS*RDIUS)
RHOIN = PRESS0*4.12E-7*(SCDCS*101+SCAMM*17)/(SCDCS+SCAMM)
MFDCS = SCDCS * 101 / (SCDCS * 101 + SCAMM * 17)
MFAMM = SCAMM * 17 / (SCDCS * 101 + SCAMM * 17)
* INLET boundary condition
INLET(INLET,LOW,#1,#1,#1,#1,#1,#1,#1,#NREGT)
VALUE(INLET,V1,0.0)
VALUE(INLET,W1,UAV)
VALUE(INLET,TEM1,290)
VALUE(INLET,P1,UAV*RHOIN)
VALUE(INLET,S226,MFDCS)
VALUE(INLET,S125,MFAMM)
VALUE(INLET,S227,0.000)
VALUE(INLET,S80,0.000)
VALUE(INLET,S174,0.000)
VALUE(INLET,S226,0.000)
* OUTLET boundary condition
OUTLET(OUT,HIGH,#1,#1,#5,#5,#5,#5,#1,#NREGT)
VALUE(OUT,V1,SAME)
VALUE(OUT,W1,SAME)
VALUE(OUT,P1,0)
VALUE(OUT,TEM1,SAME)
VALUE(OUT,S226,SAME)
VALUE(OUT,S125,SAME)
VALUE(OUT,S227,SAME)
VALUE(OUT,S80,SAME)
VALUE(OUT,S174,SAME)
VALUE(OUT,S116,SAME)
* Wafer
PATCH(WAFER,CELL,#1,#1,#1,#3,#4,#4,#1,#NREGT)
COVAL(WAFER,TEM1,FIXVAL,1043)
** Outer walls are taken to be cooled to 290K
* Wall boundary conditions
PATCH(DOME,HWALL,#1,#1,#4,#4,#4,#4,#1,#NREGT)
COVAL(DOME,TEM1,1.0,290.0)
PATCH(WAND1,SWALL,#1,#1,#5,#5,#5,#5,#1,#NREGT)
COVAL(WAND1,TEM1,1.0,290.0)
PATCH(WAND2,NWALL,#1,#1,#5,#5,#2,#5,#1,#NREGT)
COVAL(WAND2,TEM1,1.0,290)
COVAL(WAND2,W1,1.0,0.0)
PATCH(WAND3,LWALL,#1,#1,#2,#5,#2,#2,#1,#NREGT)
COVAL(WAND3,TEM1,1.0,290)
PATCH(WAND4,NWALL,#1,#1,#1,#1,#1,#1,#1,#NREGT)
COVAL(WAND4,TEM1,1.0,290)
* Gas phase chemistry source term
PATCH(CHEM,VOLUME,1,NX,1,NY,1,NZ,1,LSTEP)
COVAL(CHEM,TEM1,GRND1,GRND1)
COVAL(CHEM,S125,GRND1,GRND1)
COVAL(CHEM,S227,GRND1,GRND1)
COVAL(CHEM,S80,GRND1,GRND1)
COVAL(CHEM,S174,GRND1,GRND1)
COVAL(CHEM,S116,GRND1,GRND1)
** For surface chemistry, COVALs must be specified for ALL
** species, P1 and TEM1. Additionally, CO for P1 set to 1.0
** to indicate simple single wafer. CO of > 1.0 is used to
** represent multiple (batch) wafers.
* Surface chemistry source term
PATCH(SURF1,HIGH,#1,#1,#1,#3,#3,#3,#1,#NREGT)
COVAL(SURF1,S125,FIXFLU,GRND1)
COVAL(SURF1,S227,FIXFLU,GRND1)
COVAL(SURF1,S80,FIXFLU,GRND1)
COVAL(SURF1,S174,FIXFLU,GRND1)
COVAL(SURF1,S116,FIXFLU,GRND1)
COVAL(SURF1,P1,1.000,GRND1)
COVAL(SURF1,TEM1,FIXFLU,GRND1)
* Automatic underrelaxation for chemistry
PATCH(RELT,PHASEM,1,NX,1,NY,1,NZ,1,LSTEP)
COVAL(RELT,S125,GRND1,SAME)
COVAL(RELT,S227,GRND1,SAME)
COVAL(RELT,S80,GRND1,SAME)
COVAL(RELT,S174,GRND1,SAME)
COVAL(RELT,S116,GRND1,SAME)
COVAL(RELT,S80,GRND1,SAME)
* Radiation zones
** S2SR=T activates surface-to-surface radiation
S2SR=T
IF(S2SR) THEN
PATCH(@RI001,LOW,1,1,#1,#1,#1,#1,1,LSTEP)
COVAL(@RI001,TEM1,0.0,290)
COVAL(@RI001,EMIS,111,290.0)
PATCH(@RI002,NORTH,1,1,#1,#1,#1,#1,1,LSTEP)
COVAL(@RI002,TEM1,0.0,290)
COVAL(@RI002,EMIS,111,290.0)
PATCH(@RI003,SOUTH,1,1,#2,#2,#2,#2,1,LSTEP)
COVAL(@RI003,TEM1,GRND1,GRND1)
COVAL(@RI003,EMIS,111,300.0)
PATCH(@RI004,HIGH,1,1,#2,#2,#2,#2,1,LSTEP)
COVAL(@RI004,TEM1,GRND1,GRND1)
COVAL(@RI004,EMIS,111,300.0)
PATCH(@RI005,NORTH,1,1,#2,#2,#2,#2,1,LSTEP)
COVAL(@RI005,TEM1,GRND1,GRND1)
COVAL(@RI005,EMIS,111,300.0)
PATCH(@RI006,LOW,1,1,#3,#5,#2,#2,1,LSTEP)
COVAL(@RI006,TEM1,0.0,290)
COVAL(@RI006,EMIS,111,290.0)
PATCH(@RI007,NORTH,1,1,#5,#5,#2,#5,1,LSTEP)
COVAL(@RI007,TEM1,0.0,290)
COVAL(@RI007,EMIS,111,290.0)
PATCH(@RI008,HIGH,1,1,#5,#5,#5,#5,1,LSTEP)
COVAL(@RI008,TEM1,0.0,290)
COVAL(@RI008,EMIS,111,290.0)
PATCH(@RI009,SOUTH,1,1,#5,#5,#5,#5,1,LSTEP)
COVAL(@RI009,TEM1,0.0,290)
COVAL(@RI009,EMIS,111,290.0)
PATCH(@RI010,HIGH,1,1,#4,#4,#4,#4,1,LSTEP)
COVAL(@RI010,TEM1,0.0,290)
COVAL(@RI010,EMIS,111,0.0)
PATCH(@RI011,NORTH,1,1,#3,#3,#4,#4,1,LSTEP)
COVAL(@RI011,TEM1,GRND1,GRND1)
COVAL(@RI011,EMIS,111,900.0)
PATCH(@RI012,LOW,1,1,#1,#3,#4,#4,1,LSTEP)
COVAL(@RI012,TEM1,GRND1,GRND1)
COVAL(@RI012,EMIS,111,900.0)
ENDIF
** Additional TEM1 relaxation in solids for use
** when GRND2 used as CO in radiation patches
PATCH(RELSOL1,PHASEM,#1,#1,#1,#3,#4,#4,1,LSTEP)
COVAL(RELSOL1,TEM1,5.E2,SAME)
PATCH(RELSOL3,PHASEM,#1,#1,#2,#2,#2,#2,1,LSTEP)
COVAL(RELSOL3,TEM1,5.E2,SAME)
************************************************************
*
* GROUP 14. Downstream pressure (for free parabolic flow).
*
************************************************************
*
* GROUP 15. Termination criteria for sweeps and
* outer iterations.
*
* Number of sweeps
LSWEEP=100
*
************************************************************
*
* GROUP 16. Termination criteria for inner iterations.
*
SELREF=T; RESFAC=1.0000E-03
** Increase iterations to speed up convergence
LITER (S125) = 200
LITER (S227) = 200 ;LITER (S80 ) = 200
LITER (S174) = 200 ;LITER (S116) = 200
*
************************************************************
*
* GROUP 17. Under-relaxation and related devices.
*
* Variable declarations
REAL(MAXV,MINL,RELX)
* Estimate of the maximum velocity within domain
MAXV=5
* Estimate of the minimum cell dimension
MINL=1.0E-3
* Level of relaxation (100 - weak, 0.1 - strong)
RELX=100
RELAX(P1,LINRLX,1.0)
RELAX(V1,FALSDT,MINL/MAXV*RELX)
RELAX(W1,FALSDT,MINL/MAXV*RELX)
RELAX(TEM1,LINRLX,0.7)
** Extra underrelaxation for concentrations, independent
** of chemistry
REAL(TREL)
TREL=1000
RELAX(S125,FALSDT,TREL)
RELAX(S227,FALSDT,TREL)
RELAX(S80,FALSDT,TREL)
RELAX(S174,FALSDT,TREL)
RELAX(S116,FALSDT,TREL)
*
************************************************************
*
* GROUP 18. Limits on variables values or increments
* to them.
*
** Minimum value for species set to 1.0E-20
VARMIN( S226 ) = 1.0E-20; VARMAX( S226 ) = 1.0
VARMIN( S125 ) = 1.0E-20; VARMAX( S125 ) = 1.0
VARMIN( S227 ) = 1.0E-20; VARMAX( S227 ) = 1.0
VARMIN( S80 ) = 1.0E-20; VARMAX( S80 ) = 1.0
VARMIN( S174 ) = 1.0E-20; VARMAX( S174 ) = 1.0
VARMIN( S116 ) = 1.0E-20; VARMAX( S116 ) = 1.0
VARMIN(TEM1) = 200.0; VARMAX(TEM1) = 2000.0
*
************************************************************
*
* GROUP 19. Data communicated by SATELLITE to GROUND
*
** SPEDAT used for passing options and additional information
** to GROUND.
** MCDOPT = 2 Wilke Multi-component Diffusion Law
** BINOPT = 4 Bin. diff. coeff. based on actual temperature
** MCPROP = 3 Multi-component properties based on local gas
** mixture and local gas temperature
** CHMRLX = 0.5 Relaxation factor for RELT patch
** NGREAC/NSEARC Number of gas/surface reactions
** GREAC/SREAC Integer index of gas/surface species in
** chemistry database
SPEDAT(SET,CVD,MCDOPT,I,2)
SPEDAT(SET,CVD,BINOPT,I,4)
SPEDAT(SET,CVD,MCPROP,I,3)
SPEDAT(SET,CVD,CHMRLX,R,0.9)
SPEDAT(SET,CVD,NGREAC,I,1)
SPEDAT(SET,CVD,GREAC(1),I,75)
SPEDAT(SET,CVD,NSREAC,I,3)
SPEDAT(SET,CVD,SREAC(1),I,76)
SPEDAT(SET,CVD,SREAC(2),I,77)
SPEDAT(SET,CVD,SREAC(3),I,78)
SPEDAT(SET,CVD,RADCVD,L,T)
NAMGRD=CVD
*
************************************************************
*
* GROUP 20. Control of preliminary printout
*
************************************************************
*
* GROUP 21. Frequency and extent of field printout.
*
************************************************************
*
* GROUP 22. Location of spot-value & frequency of
* residual printout.
TSTSWP=-1
IYMON=5
IZMON=NZ-14
TSTSWP=-1
*
************************************************************
*
* GROUP 23. Variable-by-variable field printout and plot
* and/or tabulation of spot-values and residuals.
*
************************************************************
*
* GROUP 24. Preparation for continuation runs.
*
************************************************************
RESTRT(ALL)
RSTPRP=T