PHOTON USE
  p;;;;;
 
  up z
  msg grid
  gr x 1
  msg Press  to continue
  pause;  cl
  msg 1st-phase (liquid) velocity vectors
  set vec ref;0.5;vec x 1 sh;  gr ou x 1
  msg Press  to continue
  pause;  cl
  msg 2nd-phase (solid) velocity vectors
    set vec comp;  - v2 e2;  vec x 1 sh;  gr ou x 1
  msg Press  to continue
  pause ;  cl
  msg contour of pressure
  con p1 x 1 fi;0.002;  gr ou x 1
  msg Press  to continue
  pause;  cl
  msg contour of 1st-phase (liquid) volume fraction
  con r1 x 1 fi;0.002;  gr ou x 1
  msg Press  to continue
  pause;  cl
  msg contour of soluble material concentration
  con c1 x 1 fi;0.002;  gr ou x 1
  msg Press  to continue
  pause;  cl
  msg contour of 1st-phase (liquid) enthalpy
  con liqt x 1 fi;0.002;  gr ou x 1
  msg Press  to continue
  pause;  cl
  msg contour of 2nd-phase (solid) enthalpy
  con solt x 1 fi;0.002;  gr ou x 1
  msg Press e to END
  enduse
    GROUP 1. Run title
TEXT(STIRRED TANK; RUN1 STRONG STIRRING: W918
TITLE
  DISPLAY
    * A finely-divided solid is supposed to be uniformly
      distributed within a liquid, which is at rest in a
      cylindrical container, of diameter 1  meter and height 1
      meter. The particles and liquid are at different
      temperatures; and the particles are soluble in the liquid.
    * A paddle wheel, situated on the axis near the floor
      of the tank, is suddenly set in motion.
    * The subsequent motions of the liquid and of the particles
      are computed, together with their changes in temperature,
      and the increase in concentration of the soluble material in
      the liquid.
    * Three runs are set up, with varying paddle speed. It is
      suggested that a series of runs should be performed, showing
      the influences on the rate of dissolution of, for example:-
      * the paddle speed;    * the paddle size;
      * the density ratio between solid and liquid;
      * the various factors influencing the transfer
        rates of heat, mass and momentum between the
        particles and their surroundings;etc.
    Note that 100 sweeps per time step are needed for convergence.
  ENDDIS
    Special variables introduced for this problem are:-
    UDRPAD= circumferential velocity u divided by radius
            imposed by paddle
    HEIGHT & DIAM have obvious meanings
    CHATIM= characteristic time of the process
REAL(UDRPAD,HEIGHT,DIAM,CHATIM)
UDRPAD=20.0;HEIGHT=1.0;DIAM=1.0
CHATIM=0.1*HEIGHT/UDRPAD
    GROUP 2. Transience; time-step specification
    The process is simulated for a 10-second period, divided
    into 10 equal intervals
STEADY=F;GRDPWR(T,10,10.0,1.0)
    GROUP 3. X-direction grid specification
CARTES=F;xulast=0.1
    GROUP 4. Y-direction grid specification
GRDPWR(Y,10,DIAM/2.0,1.0)
    GROUP 5. Z-direction grid specification
GRDPWR(Z,10,HEIGHT,1.0)
    GROUP 7. Variables stored, solved & named
ONEPHS=F;SOLVE(P1,U1,U2,V1,V2,W1,W2,R1,R2,H1,H2,C1,C2)
STORE(INTMDT)
NAME(H1)=LIQT;NAME(H2)=SOLT;NAME(INTMDT)=MDOT;NAME(C2)=D2
NAME(W2)=E2
    GROUP 9. Properties of the medium (or media)
ENUL=1.E-2;ENUT=0.01*DIAM**2*UDRPAD
PRNDTL(LIQT)=5.0;RHO1=1.E3;RHO2=2.0*RHO1
    GROUP 10. Inter-phase-transfer processes and properties
CFIPS=GRND2;CFIPA=0.01;CFIPC=1.E4
CINT(LIQT)=0.01;CINT(SOLT)=0.001
CINT(C1)=0.0;CINT(D2)=0.0;PHINT(C1)=1.0;PHINT(D2)=1.0;CMDOT=1.E-4
    GROUP 11. Initialization of variable or porosity fields
FIINIT(R1)=0.99;FIINIT(R2)=0.01;FIINIT(LIQT)=0.0;FIINIT(SOLT)=1.0
FIINIT(C1)=0.0;FIINIT(D2)=1.0;FIINIT(MDOT)=0.0
    GROUP 13. Boundary conditions and special sources
    Cylindrical-wall friction
WALL (CYLWALL,NORTH,1,1,NY,NY,1,NZ,1,LSTEP)
COVAL(CYLWALL,W1,1.0,0.0);COVAL(CYLWALL,E2,1.0,0.0)
COVAL(CYLWALL,U1,1.0,0.0);COVAL(CYLWALL,U2,1.0,0.0)
    Top-wall friction
WALL (TOP,HIGH,1,1,1,NY,NZ,NZ,1,LSTEP)
COVAL(TOP,U1,1.0,0.0);COVAL(TOP,U2,1.0,0.0)
COVAL(TOP,V1,1.0,0.0);COVAL(TOP,V2,1.0,0.0)
    Bottom-wall friction
WALL (BOTTOM,LOW,1,1,1,NY,1,1,1,LSTEP)
COVAL(BOTTOM,U1,1.0,0.0);COVAL(BOTTOM,U2,1.0,0.0)
COVAL(BOTTOM,V1,1.0,0.0);COVAL(BOTTOM,V2,1.0,0.0)
    Pressure-relief condition to ensure that problem is well-posed
PATCH(PRELIEF,HIGH,1,1,NY,NY,NZ,NZ,1,100)
COVAL(PRELIEF,P1,FIXP,0.0)
COVAL(PRELIEF,LIQT,ONLYMS,0.0);COVAL(PRELIEF,C1,ONLYMS,0.0)
    Paddle condition, a fixed value for the liquid u/r
PATCH(PADDLE,CELL,1,1,NY/2,NY/2,1,NZ/5,1,LSTEP)
IURVAL=-1;COVAL(PADDLE,U1,FIXVAL,UDRPAD)
    Gravity exerts a downward force on both phases
PATCH(GRAVITY,PHASEM,1,1,1,NY,1,NZ,1,LSTEP)
COVAL(GRAVITY,W1,FIXFLU,-9.81);COVAL(GRAVITY,E2,FIXFLU,-9.81)
    GROUP 15. Termination of sweeps
    The following conditions are not necessarily optimal
LSWEEP=20;SELREF=T;RESFAC=0.1
    GROUP 17. Under-relaxation devices
RELAX(W1,FALSDT,CHATIM);RELAX(V1,FALSDT,CHATIM)
RELAX(E2,FALSDT,CHATIM);RELAX(V2,FALSDT,CHATIM)
RELAX(U1,FALSDT,CHATIM);RELAX(U2,FALSDT,CHATIM)
RELAX(R1,LINRLX,0.75);RELAX(R2,LINRLX,0.75)
SPEDAT(SET,GXMONI,TRANSIENT,L,F)
    GROUP 22. Spot-value print-out
TSTSWP=-1;NPRMON=20;IYMON=NY-1;IZMON=NZ-1
    GROUP 23. Field print-out and plot control
IURPRN=-1;NYPRIN=NY/5;NXPRIN=NZ/5
    Field print-out for liquid volume fraction is suppressed
OUTPUT(R1,N,Y,Y,Y,Y,Y)
    Line-printer contour plots for various quantities are called for
PATCH(MAP,CONTUR,1,1,1,NY,1,NZ,1,LSTEP)
PLOT(MAP,W1,0.0,10);PLOT(MAP,E2,0.0,10)
PLOT(MAP,U1,0.0,10);PLOT(MAP,V1,0.0,10)
PLOT(MAP,LIQT,0.0,10);PLOT(MAP,R2,0.0,10)
PLOT(MAP,SOLT,0.0,10);PLOT(MAP,C1,0.0,10.0)
PLOT(MAP,MDOT,0.0,10.0)
    A line-printer profile plot for the topmost-but-one
    slab is called for
PATCH(IZEQNZM1,PROFIL,1,1,1,NY,NZ-1,NZ-1,1,LSTEP)
PLOT(IZEQNZM1,W1,0.0,0.0);PLOT(IZEQNZM1,E2,0.0,0.0)
PATCH(IZEQNZD2,PROFIL,1,1,1,NY,1,NZ/2,1,LSTEP)
PLOT(IZEQNZD2,W1,-1.0,-1.0);PLOT(IZEQNZD2,E2,-1.0,-1.0)
PLOT(IZEQNZD2,R2,0.0,0.0)
PATCH(TIMEPLOT,PROFIL,1,1,NY/2,NY/2,NZ/2,NZ/2,1,LSTEP)
PLOT(TIMEPLOT,LIQT,-2.0,-2.0);PLOT(TIMEPLOT,SOLT,-2.0,-2.0)
PLOT(TIMEPLOT,U1,0.0,0.0);PLOT(TIMEPLOT,V1,0.0,0.0)
PLOT(TIMEPLOT,W1,0.0,0.0)
PLOT(TIMEPLOT,R2,0.0,0.0);PLOT(TIMEPLOT,C1,0.0,0.0)