AUTOPLOT USE
  file
  phi 5
 
  da 1
  p1
  screen
  msg pressure profile
  pl 1
  msg press  to continue
  pause
  cl
  da 1
  1w
  screen
  msg gas velocity
  pl 1
  msg press  to continue
  pause
  cl
  da 1
  liq
  screen
  msg liquid volume fraction
  pl 1
  msg press  to continue
  pause
  cl
  da 1
  h2
  screen
  msg liquid enthalpy
  pl 1
  msg press e to END
  enduse
 
    GROUP 1. Run title and other preliminaries
TEXT(1D-Z PIPE BOILING  PH1-GAS,PH2-LIQ: W352
TITLE
  DISPLAY
  This run performs the same analysis as the previous one but
  considers phase 1 as the light phase and phase 2 as the
  heavy one. The reader may confirm that this run and the
  previous one produced the same answers.
  ENDDIS
    GROUP 5. Z-direction grid specification
GRDPWR(Z,5,1.0,1.0)
    GROUP 7. Variables stored, solved & named
ONEPHS=F;SOLVE(P1,W1,W2,R1,R2,H1,H2);STORE(MDOT)
NAME(W1)=1W;NAME(W2)=2W;NAME(R1)=GAS;NAME(R2)=LIQ
    GROUP 8. Terms (in differential equations) & devices
TERMS(H1,N,Y,N,Y,Y,Y);TERMS(H2,N,Y,N,Y,N,Y)
TERMS(GAS,Y,Y,N,Y,Y,Y);TERMS(LIQ,Y,Y,N,Y,N,Y)
TERMS(1W,Y,Y,N,Y,Y,Y);TERMS(2W,Y,Y,N,Y,N,Y)
    GROUP 9. Properties of the medium (or media)
RHO2=1.0E3
    GROUP 10. Inter-phase-transfer processes and properties
  ** Set a constant inter-phase friction coefficient and
     activate the computation of inter-phase mass transfer
     by means of a heat balance.
CFIPS=-2500.;CMDOT=HEATBL;RLOLIM=0.01
  ** Set the inter-phase heat transfer coefficients.
CINT(H2)=1.E0;CINT(H1)=1.E-2
  ** Set the enthalpy values at the interface.
PHINT(H2)=4.0E5;PHINT(H1)=2.5E6
    GROUP 11. Initialization of variable or porosity fields
FIINIT(LIQ)=.99;FIINIT(GAS)=1.E-2
FIINIT(1W)=0.01;FIINIT(2W)=0.01
FIINIT(H2)=4.0E5;FIINIT(H1)=2.5E6
    GROUP 13. Boundary conditions and special sources
  ** Inlet at bottom
INLET(BOTTOM,LOW,1,1,1,1,1,1,1,1)
VALUE(BOTTOM,P2,10.0);VALUE(BOTTOM,2W,0.01)
VALUE(BOTTOM,H2,4.0E5)
  ** Outlet
PATCH(OUTLET,CELL,1,1,1,1,NZ,NZ,1,1)
COVAL(OUTLET,P2,1.E3,0.0);COVAL(OUTLET,P1,FIXP,0.0)
COVAL(OUTLET,1W,ONLYMS,0.0);COVAL(OUTLET,2W,ONLYMS,0.0)
COVAL(OUTLET,H2,ONLYMS,SAME);COVAL(OUTLET,H1,ONLYMS,SAME)
  ** Gravity
PATCH(GRAVITY,PHASEM,1,1,1,1,1,NZ,1,1)
COVAL(GRAVITY,1W,FIXFLU,-9.81);COVAL(GRAVITY,2W,FIXFLU,-9.81)
  ** Heated region
PATCH(HEATER,PHASEM,1,1,1,1,2,NZ,1,1)
COVAL(HEATER,H2,FIXFLU,1.E5)
    GROUP 15. Termination of sweeps
LSWEEP=50
RESREF(P1)=1.E-5;RESREF(1W)=1.E-4
RESREF(2W)=1.E-4;RESREF(H1)=1.E-4
RESREF(H2)=1.E-4;RESREF(GAS)=1.E-4;RESREF(LIQ)=1.E-4
    GROUP 17. Under-relaxation devices
RELAX(1W,FALSDT,0.05);RELAX(2W,FALSDT,0.05)
RELAX(GAS,LINRLX,0.5);RELAX(LIQ,LINRLX,0.5)
RELAX(H1,FALSDT,1.0);RELAX(H2,FALSDT,1.0)
    GROUP 22. Spot-value print-out
IZMON=NZ/2;NPLT=LSWEEP/20;TSTSWP=-1;ITABL=1
    GROUP 23. Field print-out and plot control
PATCH(IZ1TONZ,PROFIL,1,1,1,1,1,NZ,1,1)
PLOT(IZ1TONZ,LIQ,0.0,1.0);PLOT(IZ1TONZ,1W,0.0,2.0)
PLOT(IZ1TONZ,2W,0.0,2.0)