GROUP 1. Run title and other preliminaries
TEXT(2S K-E MODEL_PARABOLIC ROUND JET   :T404
TITLE
  DISPLAY
  The problem considered is the submerged free heated turbulent
  round jet in stagnant surroundings, as described under PHOENICS
  Library cases 153-155. The calculations are started at the jet
  discharge, and the parabolic marching integration is carried
  out until both the mean flow and turbulence profiles become self
  similar.
 
  The calculations are made with 30 grid cells across the jet and
  a forward step size of 5% (DZW1) of the local jet width. The y-
  extent of the grid is set equal to the diameter at z = 0,
  thereafter being caused to increase linearly with downstream
  distance so as to accommodate the radial spread of the jet. For
  testing purposes the number of forward steps is set equal to 20,
  but for the attainment of self-similarity, it is recommended that
  NZ is set equal to 210, so that the marching integration is
  terminated at an axial distance of about 50 diameters from the
  jet discharge.
  ENDDIS
 
  Calculations are performed with both the standard k-e model, and
  also with the 2-scale k-e model. The turbulent Prandtl number is
  set equal to 0.7.
 
  The experimental data indicate velocity and temperature half-
  width spreading rates of 0.086 and 0.11, respectively, in the
  self-similar region of the jet. The present calculation with the
  standard k-e model predicts values of 0.11 and 0.135,
  respectively, and the 2-scale k-e model produces very similar
  results yielding spreading rates of 0.107 and 0.13.
 
BOOLEAN(TSKE);TSKE=T
REAL(WJET,REYNO,DIAM,TJET,TFREE,TKEIN,EPSIN)
REYNO=5.E5;DIAM=0.1;WJET=10.0;TJET=1.0;TFREE=0.0
TKEIN=WJET*WJET*0.0001
EPSIN=TKEIN**1.5/(0.035*DIAM*.1643)
    GROUP 3. X-direction grid specification
CARTES=F;XULAST=0.1
    GROUP 4. Y-direction grid specification
NY=30;YVLAST=DIAM;YFRAC(1)=-30;YFRAC(2)=1.0/30.0
   *** Linear grid expansion of DYGDZ
REAL(DYGDZ);DYGDZ=0.086*3.;AZYV=1.0;ZWADD=DIAM/DYGDZ
    GROUP 5. Z-direction grid specification
PARAB=T;NZ=20;AZDZ=PROPY
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,H1);NAME(H1)=TEMP;STORE(ENUT,LEN1)
IF(TSKE) THEN
+ TURMOD(TSKEMO)
ELSE
+ TURMOD(KEMODL)
ENDIF
    GROUP 8. Terms (in differential equations) & devices
DIFCUT=0.0;TERMS(TEMP,N,Y,Y,Y,Y,Y)
    GROUP 9. Properties of the medium (or media)
ENUL=WJET*DIAM/REYNO;PRT(TEMP)=0.7
    GROUP 11. Initialization of variable or porosity fields
IF(TSKE) THEN
+ REAL(KTDKP,KPIN,KTIN);KTDKP=0.25
+ KPIN=TKEIN/(1.+KTDKP);KTIN=KTDKP*KPIN
+ FIINIT(KE)=TKEIN;FIINIT(KP)=KPIN;FIINIT(KT)=KTIN
+ FIINIT(EP)=EPSIN;FIINIT(ET)=EPSIN
ENDIF
FIINIT(ENUT)=TKEIN**2/EPSIN
    GROUP 13. Boundary conditions and special sources
    1. Outer Boundary-- free stream
PATCH(HIGHY,NORTH,1,1,NY,NY,1,NZ,1,1)
COVAL(HIGHY,P1,1.0E4,0.0)
COVAL(HIGHY,V1,ONLYMS,0.0);COVAL(HIGHY,TEMP,ONLYMS,TFREE)
COVAL(HIGHY,W1,ONLYMS,0.0);COVAL(HIGHY,EP,ONLYMS,1.E-10)
    2. Inlet Boundary-- uniform flow
PATCH(NOZZLE,LOW,1,1,1,NY/2,1,1,1,1)
COVAL(NOZZLE,P1,FIXFLU,RHO1*WJET);COVAL(NOZZLE,W1,ONLYMS,WJET)
COVAL(NOZZLE,TEMP,ONLYMS,TJET);COVAL(NOZZLE,EP,ONLYMS,EPSIN)
IF(TSKE) THEN
+ COVAL(HIGHY,KP,ONLYMS,1.E-10);COVAL(HIGHY,KT,ONLYMS,1.E-10)
+ COVAL(HIGHY,ET,ONLYMS,1.E-10)
+ COVAL(NOZZLE,KP,ONLYMS,KPIN);COVAL(NOZZLE,KT,ONLYMS,KTIN)
+ COVAL(NOZZLE,ET,ONLYMS,EPSIN)
ELSE
+ COVAL(HIGHY,KE,ONLYMS,1.E-10)
+ COVAL(NOZZLE,KE,ONLYMS,TKEIN)
ENDIF
    GROUP 14. Downstream pressure for PARAB=T
IPARAB=1
    GROUP 16. Termination of iterations
LITHYD=25;SELREF=T; RESFAC=0.1
    GROUP 17. Under-relaxation devices
RELAX(V1,FALSDT,10.0); RELAX(W1,FALSDT,10.0); RELAX(ENUT,LINRLX,0.5)
RELAX(TEMP,FALSDT,10.0); RELAX(EP,LINRLX,0.5)
IF(TSKE) THEN
+ RELAX(V1,FALSDT,1.0); RELAX(W1,FALSDT,1.0)
+ RELAX(KT,LINRLX,0.5); RELAX(KP,LINRLX,0.5)
+ RELAX(ET,LINRLX,0.5); RELAX(EP,LINRLX,0.5)
ELSE
+ RESREF(KE)=1.E-8; RELAX(KE,LINRLX,0.5)
ENDIF
    GROUP 18. Limits on variables or increments to them
VARMIN(V1)=-1.E3;VARMAX(V1)=1.E3
    GROUP 19. Data communicated by SATELLITE to GROUND
DZW1=0.05;DWDY=T
    GROUP 22. Monitor print-out
IZMON=NZ/2;IYMON=NY/2;ITABL=1;NPLT=1;IPLTL=LITHYD
TSTSWP=-1
    GROUP 23. Field print-out and plot control
ORSIZ=0.4;PATCH(IZEQNZ,PROFIL,1,1,1,NY,NZ,NZ,1,1)
PLOT(IZEQNZ,W1,0.0,0.0);PLOT(IZEQNZ,TEMP,0.0,0.0)
PLOT(IZEQNZ,ENUT,0.0,0.0)
NZPRIN=NZ
    GROUP 24. Dumps for restarts