TALK=T;RUN( 1, 1)
 ** LOAD(x311) from the x Input Library
    GROUP 1. Run title and other preliminaries
TEXT(REALISABLE_KE SCAL_WF BLUNT PLATE:T311
TITLE
  DISPLAY
  The case considered is 2D incompressible, turbulent flow
  past a thick flat rectangular plate with a sharp leading
  edge, as studied experimentally by Djilali,N. & Gartshore,I.S.,
  "Turbulent flow around a bluff rectangular plate, Part I:
  Experimental Investigation", Journal of Fluid Mechanics,
  Vol.113, pp51-59, (1991).
 
  The flow separates at the leading edge of the plate, and then
  reattaches further downstream to form a long separation zone on
  top of the plate. The thickness of the plate H is taken as 0.1m,
  and the working fluid is air at standard temperature and
  pressure.The flow Reynolds number based on the free-stream
  velocity and plate thickness H is 50,000.
 
  The inlet and outlet planes are located 10H upstream and
  downstream of the leading edge of the plate. The height of the
  solution domain is taken as 10H, and for simplicity a zero
  flux boundary is assumed here. Symmetry is exploited so that
  only one half of the flow is simulated. A fixed-pressure boundary
  condition is applied at the outlet, and uniform flow profiles are
  specified at the inlet. Scalable wall functions are used at
  the walls of the plate.
 
  The default simulation is made with the realisable k-e model, but
  the case can also be run with the standard k-e and k-w models, the
  revised Wilcox k-w, Menter k-w and k-w-SST model, and the following
  k-e variants: Chen-Kim, RNG,  Kato-Launder, Murakami et al. The
  measured and predicted reattachment points are listed below:
 
           KE   RKE   CK   RNG  MMK   KL   KW   KWR  KWM SST EXPT
 
    Xr/H=  1.1  4.8  4.7   3.9  3.2  3.2  0.73  3.7 0.94 5.1  4.7
 
  These results are not grid independent. It can be seen that the
  standard k-e and k-w models seriously underestimate the separation
  length. This is because this model predicts excessive turbulence
  production at the stagnation zone on the front of the plate, and
  the high turbulence levels are then convected into the separation
  zone. The other models perform much better, with the revised
  Wilcox, Chen-Kim and Realisable models showing close agreement
  with the measurement.
  ENDDIS
 
  This AUTOPLOT sequence provides a plot of the axial velocity U1
  along the top of the plate against axial distance normalised by
  the step height. The axial coordinate 0.0 corresponds to the
  front of the step. The reattachment point corresponds the axial
  location where U1 changes from negative to positive.
 
   AUTOPLOT USE
   file
   phida 3
 
   da 1 u1 y 11
   divide x .1 1
   shift x -10 1
   colf 1
   level y 0;level x 0
   scale x 0 6
   redraw
   msg Velocity (U1) profile
   msg Press e to END
   ENDUSE
 
CHAR(CTURB,TLSC)
BOOLEAN(KWMOD);KWMOD=F
REAL(THICKNESS,DHEIGHT,DLEN,PLEN,PHEIGHT,REYNO,UIN)
REAL(TKEIN,EPSIN,MIXL,FRIC)
INTEGER(NYP,NYF,NXF,NXP)
     ** Calculation of domain specifications
THICKNESS=0.1;PHEIGHT=0.5*THICKNESS
DHEIGHT=10.*THICKNESS;PLEN=10.*THICKNESS;DLEN=20.*THICKNESS
REYNO=5.0E4;UIN=7.3
TKEIN=(0.01*UIN)**2;MIXL=0.05*DHEIGHT
EPSIN=0.1643*TKEIN**1.5/MIXL
    GROUP 3. X-direction grid specification
    GROUP 4. Y-direction grid specification
NXF=60;NXP=55;NYP=10;NYF=65
NREGX=2
IREGX=1;GRDPWR(X,NXF,-(DLEN-PLEN),-1.04)
IREGX=2;GRDPWR(X,NXP,-PLEN,1.04)
NREGY=2
IREGY=1;GRDPWR(Y,NYP,-PHEIGHT,1.04)
IREGY=2;GRDPWR(Y,NYF,-(DHEIGHT-PHEIGHT),1.04)
    GROUP 7. Variables stored, solved & named
SOLVE(P1,U1,V1);STORE(ENUT,EL1,DEN1)
 
MESG( Enter the required turbulence model:
MESG(  CK   - Chen-Kim k-e model
MESG(  KE   - Standard k-e model
MESG(  KL   - Kato-Launder k-e model
MESG(  MMK  - Murakami k-e model
MESG(  RNG  - RNG k-e model
MESG(  RKE  - Realisable k-e model (default)
MESG(  KW   - Wilcox 1988 k-w model
MESG(  KWR  - Wilcox 2008 k-w model
MESG(  KWM  - Menter k-w model
MESG(  KWS  - k-w SST model
MESG(
READVDU(CTURB,CHAR,RKE)

CASE :CTURB: OF
WHEN CK,2
TEXT(Chen_Kim_KE Blunt Flat Plate:T311
+ MESG(Chen-Kim k-e model
+ TURMOD(KECHEN);TLSC=EP
WHEN KE,2
TEXT(Standard_KE Blunt Flat Plate:T311
+ MESG(Standard k-e model
+ TURMOD(KEMODL);TLSC=EP
WHEN KL,2
+ TEXT(Kato_Launder_KE Blunt Flat Plate:T311
+ MESG(Kato-Launder k-e model
+ TURMOD(KEKL);TLSC=EP
WHEN MMK,3
+ TEXT(MMK_K-E Blunt Flat Plate:T311
+ MESG(MMK k-e model
+ TURMOD(KEMMK);TLSC=EP
WHEN RNG,3
+ TEXT(RNG_K-E Blunt Flat Plate:T311
+ MESG(RNG k-e model
+ TURMOD(KERNG);TLSC=EP
+ STORE(ETA,ALF,GEN1)
+ OUTPUT(ALF,Y,N,P,Y,Y,Y);OUTPUT(ETA,Y,N,P,Y,Y,Y)
    ** change from default of 1.0 to secure convergence
+ SPEDAT(SET,MAXINC,KE,R,0.1)
WHEN RKE,3
+ TEXT(Realisable_KE Blunt Flat Plate:T311
+ MESG(Realisable k-e model
+ TURMOD(KEREAL);TLSC=EP;STORE(C1E)
+ OUTPUT(CMU,P,P,P,P,Y,Y);OUTPUT(C1E,P,P,P,P,Y,Y)
WHEN KW,2
TEXT(Wilcox 1988 k-w Blunt Flat Plate:T311
+ MESG(Wilcox 1988 k-w model (default)
+ TURMOD(KWMODL);TLSC=OMEG;KWMOD=T
+ STORE(EP);EPSIN=EPSIN/(0.09*TKEIN)
WHEN KWR,3
TEXT(Wilcox 2008 k-w Blunt Flat Plate:T311
+ MESG(Wilcox k-w model (default)
+ TURMOD(KWMODLR);TLSC=OMEG;FIINIT(FBP)=1.0;KWMOD=T
+ EPSIN=EPSIN/(0.09*TKEIN)
WHEN KWM,3
TEXT(Menter k-w Blunt Flat Plate:T311
+ MESG(Menter 1992 k-w model:
+ TURMOD(KWMENTER);TLSC=OMEG;KWMOD=T
+ STORE(EP);FIINIT(BF1)=1.0
+ STORE(BF1,GEN1)
  ** The following are for printout only
+ STORE(DKDX,DKDY,DKDZ,DFDX,DFDY,DFDZ,CDWS,SIGK,SIGW)
+ EPSIN=EPSIN/(0.09*TKEIN)
WHEN KWS,3
TEXT(SST k-w Blunt Flat Plate:T311
+ MESG(k-w SST model
+ TURMOD(KWSST);TLSC=OMEG;KWMOD=T
+ STORE(EP);FIINIT(BF1)=1.0;FIINIT(BF2)=1.0
+ STORE(BF1,BF2,GEN1)
  ** The following are for printout only
+ STORE(DKDX,DKDY,DKDZ,DFDX,DFDY,DFDZ,CDWS,SIGK,SIGW)
+ EPSIN=EPSIN/(0.09*TKEIN)  
ENDCASE
STORE(YPLS,STRS,SKIN)
    GROUP 8. Terms (in differential equations) & devices
DENPCO=T
   ADDDIF=T
    GROUP 9. Properties of the medium (or media)
RHO1=1.225;ENUL=UIN*THICKNESS/REYNO
    GROUP 11. Initialization of variable or porosity fields
FIINIT(U1)=UIN;FIINIT(V1)=0.001*UIN
FIINIT(KE)=TKEIN;FIINIT(:TLSC:)=EPSIN
 
     ** Initialization of variables in blocked region
     CONPOR(PLATE,0.0,CELL,-#2,#2,-#1,#1,#1,#1)

    ** Initialization of variables in blocked region
STORE(PRPS)
PATCH(PLATE,INIVAL,#2,#2,#1,#1,#1,#1,1,1)
INIT(PLATE,PRPS,0.,198)
EGWF=T

    GROUP 13. Boundary conditions and special sources
INLET(INLET,WEST,#1,#1,#1,#NREGY,#1,#1,1,1)
VALUE(INLET,P1,RHO1*UIN);VALUE(INLET,U1,UIN)
VALUE(INLET,KE,TKEIN);VALUE(INLET,:TLSC:,EPSIN)
 
PATCH(OUTLET,EAST,#NREGX,#NREGX,#2,#NREGY,#1,#1,1,1)
COVAL(OUTLET,P1,1.0E3,0.0)
COVAL(OUTLET,U1,ONLYMS,0.0);COVAL(OUTLET,V1,ONLYMS,0.0)

SCALWF=T   ! Scalable wall functions

    GROUP 15. Termination of sweeps
LSWEEP=1500
    GROUP 16. Termination of iterations
SELREF=T;RESFAC=1.E-4
    GROUP 17. Under-relaxation devices
CONWIZ=T
IF(.NOT.KWMOD) THEN
+KELIN=3
ENDIF
CASE :CTURB: OF
WHEN RKE,3
+ VARMAX(ENUT)=0.1
WHEN KWR,3
+ SCALWF=F
WHEN KW,2
+ CONWIZ=F;KELIN=0
+ REAL(DTF);DTF=0.1*XULAST/UIN
+ RELAX(V1,FALSDT,DTF);RELAX(U1,FALSDT,DTF)
+ RELAX(KE,FALSDT,DTF);RELAX(OMEG,FALSDT,DTF)
WHEN KWM,3
+ CONWIZ=F;KELIN=0
+ REAL(DTF);DTF=XULAST/UIN
+ RELAX(V1,FALSDT,DTF);RELAX(U1,FALSDT,DTF)
+ RELAX(KE,FALSDT,DTF);RELAX(OMEG,FALSDT,DTF)
+ RELAX(ENUT,LINRLX,0.5)
+ RELAX(BF1,LINRLX,0.05)
WHEN KWS,3
+ CONWIZ=F
+ REAL(DTF);DTF=XULAST/(UIN*NX)
+ RELAX(V1,FALSDT,DTF);RELAX(U1,FALSDT,DTF)
+ RELAX(KE,FALSDT,DTF);RELAX(:TLSC:,FALSDT,DTF)
+ RELAX(ENUT,LINRLX,0.5)
ENDCASE
 
IYMON=NYP+2;IXMON=NXF+13;NPRMON=100
    GROUP 23. Field print-out and plot control
ITABL=3;NPLT=10;IPLTL=LSWEEP;NXPRIN=23;NYPRIN=15
TSTSWP=-1
SPEDAT(SET,GXMONI,PLOTALL,L,T)
DISTIL=T
 
EX(PRPS)=9.362E-01;EX(DEN1)=1.147E+00
CASE :CTURB: OF
WHEN CK,2
+EX(P1  )=5.509E+00;EX(U1  )=6.621E+00
+EX(V1  )=4.384E-01;EX(KE  )=1.068E-01
+EX(EP  )=4.566E+00;EX(EPKE)=6.777E+00
+EX(EL1 )=2.751E-02;EX(STRS)=2.418E-04
+EX(YPLS)=1.484E-01;EX(SKIN)=5.053E-05
+EX(ENUT)=1.388E-03
WHEN KE,2
+EX(P1  )=4.615E+00;EX(U1  )=6.763E+00
+EX(V1  )=3.448E-01;EX(KE  )=4.162E-01
+EX(EP  )=1.812E+01;EX(EPKE)=4.837E+00
+EX(EL1 )=4.060E-02;EX(STRS)=3.877E-04
+EX(YPLS)=1.835E-01;EX(SKIN)=4.730E-05
+EX(ENUT)=3.523E-03
WHEN MMK,3
+EX(P1  )=5.157E+00;EX(U1  )=6.666E+00
+EX(V1  )=4.003E-01;EX(KE  )=1.236E-01
+EX(EP  )=5.389E+00;EX(EPKE)=5.019E+00
+EX(DVDX)=3.924E+00;EX(DUDY)=1.759E+01
+EX(FOMG)=2.061E-01;EX(EL1 )=4.050E-02
+EX(STRS)=2.645E-04;EX(YPLS)=1.536E-01
+EX(SKIN)=5.030E-05;EX(ENUT)=5.105E-04
WHEN RNG,3
+EX(P1  )=5.344E+00;EX(U1  )=6.643E+00
+EX(V1  )=4.205E-01;EX(KE  )=1.291E-01
+EX(EP  )=5.132E+00;EX(EPKE)=5.857E+00
+EX(GEN1)=5.710E+03;EX(ALF )=8.198E+00
+EX(ETA )=8.497E+00;EX(EL1 )=3.148E-02
+EX(STRS)=2.585E-04;EX(YPLS)=1.527E-01
+EX(SKIN)=5.016E-05;EX(ENUT)=1.707E-03
WHEN RKE,3
+EX(P1  )=5.421E+00;EX(U1  )=6.629E+00
+EX(V1  )=4.262E-01;EX(KE  )=1.230E-01
+EX(EP  )=4.972E+00;EX(SKIN)=5.051E-05
+EX(STRS)=2.497E-04;EX(YPLS)=1.502E-01
+EX(C1E )=5.868E-01;EX(DVDY)=5.134E+00
+EX(DVDX)=3.958E+00;EX(DUDY)=1.836E+01
+EX(DUDX)=5.133E+00;EX(EPKE)=5.302E+00
+EX(CMU )=7.094E-02;EX(DEN1)=1.147E+00
+EX(EL1 )=4.079E-02;EX(ENUT)=1.602E-03
WHEN KL,2
+EX(P1  )=5.146E+00;EX(U1  )=6.667E+00
+EX(V1  )=3.990E-01;EX(KE  )=1.247E-01
+EX(EP  )=5.601E+00;EX(EPKE)=5.071E+00
+EX(DVDX)=3.928E+00;EX(DUDY)=1.757E+01
+EX(FOMG)=2.223E-01;EX(EL1 )=4.046E-02
+EX(STRS)=2.654E-04;EX(YPLS)=1.539E-01
+EX(SKIN)=5.027E-05;EX(ENUT)=1.935E-03
WHEN KW,2
+EX(U1  )=6.655E+00;EX(DEN1)=1.147E+00
+EX(P1  )=5.427E+00;EX(V1  )=3.554E-01
+EX(KE  )=2.318E+00;EX(EP  )=4.445E+01
+EX(SKIN)=4.484E-05;EX(STRS)=5.342E-04
+EX(YPLS)=2.129E-01;EX(OMEG)=4.823E+01
+EX(EL1 )=6.173E-02;EX(ENUT)=3.347E-02
WHEN KWR,3
+EX(P1  )=5.199E+00;EX(U1  )=6.661E+00
+EX(V1  )=4.027E-01;EX(KE  )=1.410E-01
+EX(EP  )=6.496E+00
+EX(SKIN)=7.760E-05;EX(STRS)=2.706E-04
+EX(YPLS)=1.483E-01;EX(DVDY)=4.987E+00
+EX(DVDX)=3.942E+00;EX(DUDY)=1.858E+01
+EX(DUDX)=5.031E+00;EX(GEN1)=7.505E+03
+EX(FBP )=9.336E-01;EX(XWP )=2.446E-01
+EX(OMEG)=4.410E+01;EX(EL1 )=4.161E-02
+EX(ENUT)=1.218E-03
WHEN KWM,3
+EX(P1  )=4.631E+00;EX(U1  )=6.763E+00
+EX(V1  )=3.445E-01;EX(KE  )=4.589E-01
+EX(SKIN)=4.703E-05;EX(STRS)=3.972E-04
+EX(YPLS)=1.858E-01;EX(SIGW)=1.277E+00
+EX(SIGK)=1.157E+00;EX(DFDX)=7.892E+02
+EX(GEN1)=5.972E+03;EX(LTLS)=4.368E-01
+EX(WDIS)=4.522E-01;EX(BF1 )=2.203E-01
+EX(OMEG)=5.394E+01;EX(EL1 )=4.063E-02
+EX(ENUT)=3.595E-03;EX(EP  )=2.097E+01
+EX(CDWS)=4.416E+05;EX(DFDY)=3.106E+03
+EX(DKDY)=2.936E+01;EX(DKDX)=1.082E+01
WHEN KWS,3
+EX(P1  )=5.572E+00;EX(V1  )=4.397E-01
+EX(KE  )=1.194E-01;EX(EP  )=4.939E+00
+EX(STRS)=2.593E-04;EX(SIGW)=1.244E+00
+EX(SIGK)=1.117E+00;
+EX(DFDX)=7.986E+02;EX(GEN1)=8.297E+03
+EX(BF2 )=6.768E-01;EX(BF1 )=1.807E-01
+EX(OMEG)=5.316E+01;EX(EL1 )=3.382E-02
+EX(ENUT)=1.128E-03;EX(WDIS)=4.522E-01
+EX(U1  )=6.615E+00;EX(SKIN)=5.013E-05
+EX(YPLS)=1.531E-01;EX(LTLS)=4.368E-01
+EX(CDWS)=1.138E+04;EX(DFDY)=2.665E+03
+EX(DKDY)=7.237E+00;EX(DKDX)=6.701E-01
 ENDCASE
 LIBREF = 311

idispa=50
csg1=sw
STOP