GROUP 1. Run title and other preliminaries
TEXT(KE_PIPE FLOW OF A BINGHAM FLUID: T305
 
  DISPLAY
  The problem concerns the steady fully-developed turbulent flow
  of a Bingham-plastic non-Newtonian fluid. This type of fluid
  remains rigid when the shearing stress is less than the yield
  stress tauy and flows somewhat like a Newtonian fluid when the
  shearing stress exceeds tauy. The turbulence is simulated by the
  high-Reynolds number k-e model plus wall functions, although the
  user might like to try the low-Reynolds-number k-e model because
  the laminar viscosity varies rapidly in the near-wall layer due
  to the rapid increase in the rate of strain as the wall is
  approached.
  ENDDIS
 
  The apparent viscosity of such a fluid is given by
  the following two-paramter formula:
 
    enul = [n + tauy/(dw/dy)]/rho    for tau >  tauy
 
    enul = infinity                  for tau << tauy
 
  where n is the rigidity coefficient, and tau is the shear
  stress. Examples of fluids which behave as, or nearly as,
  Bingham plastics include water suspensions of clay, sewage
  sludge, some emulsions and thickened hydrocarbon greases.
 
  The flow may be characterised by Re the Bingham Reynolds number,
  defined by:
 
    Re = rho*win*D/n
 
  and Y the yield number, defined by:
 
    Y = D*tauy/(win*n)
 
  For sufficiently high Reynolds numbers, experimental data confirm
  that the friction factor f is independent of the Yield number.
  The data are fairly well correlated by the simplified Torrance
  relation:
 
    1./sqrt(f) = 2.265*log10[0.5*Re*sqrt(f)] - 1.15
 
  where f = 2*D*(dp/dz)/rho/win**2. The present calculations are for
  Re = 3.E4 and Y = 5.0 for which PHOENICS yields f = 0.0265 and the
  Torrance correlation yields f = 0.0239. The effect of grid size
  has not been investigated, and the user may like to try performing
  the calculation with the the low-Reynolds-number k-e model.
 
   AUTOPLOT USE
   file
   phi 5
 
   da 1 w1
   col9 1
   msg Velocity (W1) profile
   msg Press RETURN to continue
   pause
 
   clear;da 1 ke
   col9 1
   msg KE profile
   msg Press e to END
   ENDUSE
 
REAL(FRIC,TKEIN,MIXL,EPSIN,RIN,DIN,WIN,AIN,DPDZ,YPLS1)
REAL(DELT,US,REY,YIELDN,FLOWIN,KAPPA); REY=3.E4;YIELDN=5.0
RIN=0.1;DIN=2.*RIN;WIN=1.0;AIN=RIN*RIN/2.; RHO1=1.0
ENULA=DIN*WIN*RHO1/REY;ENULB=YIELDN*WIN*ENULA/DIN
  ** use Newtonian pipe-flow correlation to estimate f
FRIC=1.1*(1./(1.82*LOG10(REY)-1.64)**2)
DPDZ=FRIC*RHO1*WIN*WIN/(2.*DIN);US=WIN*(FRIC/8.)**0.5
FRIC
DPDZ
REY
YIELDN
    GROUP 2. Transience; time-step specification
CARTES=F
    GROUP 3. X-direction grid specification
    GROUP 4. Y-direction grid specification
YPLS1=30;DELT=2.*YPLS1*ENULA/US;KAPPA=0.41
DELT=DELT/(1.-2.*SQRT(2.)*ENULB*YPLS1*KAPPA/US**1.5/WIN)
NREGY=2; REGEXT(Y,RIN)
IREGY=1;GRDPWR(Y,19,RIN-DELT,0.8);IREGY=2;GRDPWR(Y,1,DELT,1.0)
    GROUP 5. Z-direction grid specification
ZWLAST=0.1
    GROUP 6. Body-fitted coordinates or grid distortion
    GROUP 7. Variables stored, solved & named
SOLVE(W1);STORE(VISL,BTAU,GENK)
TURMOD(KEMODL);STORE(ENUT,LEN1)
    GROUP 8. Terms (in differential equations) & devices
TERMS(W1,N,N,P,P,P,P);TERMS(KE,Y,N,P,P,P,P)
TERMS(EP,Y,N,P,P,P,P)
    GROUP 9. Properties of the medium (or media)
ENUL=BINGHAM;DWDY=T
    GROUP 10. Inter-phase-transfer processes and properties
    GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=WIN;FRIC=0.001;TKEIN=0.25*WIN*WIN*FRIC
MIXL=0.09*0.5*DIN;EPSIN=TKEIN**1.5/MIXL*0.1643
    GROUP 12. Convection and diffusion adjustments
    GROUP 13. Boundary conditions and special sources
PATCH(WALLN,NWALL,1,NX,NY,NY,1,NZ,1,1)
COVAL(WALLN,W1,LOGLAW,0.0);COVAL(WALLN,KE,LOGLAW,LOGLAW)
COVAL(WALLN,EP,LOGLAW,LOGLAW)
  ** activate fully-developed-flow solver
FDFSOL=T;USOURC=T;FLOWIN=RHO1*WIN*AIN
PATCH(FDFW1DP,VOLUME,1,NX,1,NY,1,NZ,1,1)
COVAL(FDFW1DP,W1,FLOWIN,GRND1)
    GROUP 14. Downstream pressure for PARAB=.TRUE.
    GROUP 15. Termination of sweeps
LSWEEP=10;LITHYD=50
    GROUP 16. Termination of iterations
RESREF(W1)=1.E-12*DPDZ*ZWLAST*AIN
RESREF(KE)=RESREF(W1)*TKEIN; RESREF(EP)=RESREF(W1)*EPSIN
    GROUP 17. Under-relaxation devices
REAL(DTF);DTF=ZWLAST/WIN; RELAX(W1,FALSDT,DTF)
RELAX(KE,FALSDT,DTF); RELAX(EP,FALSDT,DTF)
WALPRN=T
    GROUP 18. Limits on variables or increments to them
    GROUP 19. Data communicated by satellite to GROUND
    GROUP 20. Preliminary print-out
    GROUP 21. Print-out of variables
OUTPUT(VISL,Y,N,N,Y,Y,Y)
    GROUP 22. Spot-value print-out
IYMON=NY;TSTSWP=-1
    GROUP 23. Field print-out and plot control
NPLT=2;NYPRIN=1;NZPRIN=1
    GROUP 24. Dumps for restarts