TALK=T;RUN( 1, 1)
TEXT(2D BLUFF-BODY STABILISED METHANE JET: T301
TITLE
DISPLAY
The case considered is 2d steady, axisymmetric, turbulent
non-reacting flow behind a bluff-body flame holder. The flow
configuration consists of a 5.4mm diameter methane jet seperated
from an outer, annular air flow by a 50mm diameter bluff body.
The flow is characterised by reverse flow in the annular air
stream and exhibits well-defined fuel and annular air stagnation
points along the centre-line. This case has been studied
experimentally by Schefer et al (Comb.Sci.&Tech., Vol.56, p101,
1987]) and was the subject of an ASCF Ercoftac CFD Workshop
(Org: D.Garreton & O.Simonin, EDF, Chatou, France, 1994).
ENDDIS
The problem requires very high computational resolution for
numerical accuracy, and like other disk-related predictions
(e.g.McGuirk et al[1985] & Durao et al[1991]) in the literature,
the standard k-e model underestimates the size of the recirculation
zone, and hence the location of the first stagnation point. The near
field of these flows are also known to be sensitive to the inlet
conditions, and no assessment has been made here of the influence
of inlet values, and no grid refinement studies have been carried out.
The measured fuel stagnation point is located 38.7mm downstream of
the body while the air stagnation point occurs at about 63mm. The
table below compares these experimental values with those computed
from the various turbulence models.
KE CK RNG RKE KWR KWS DATA
Fuel Xstag 25.8 35.0 34.2 13.1 33.7 22.1 38.7
Air Xstag 57.5 64.6 62.6 62.9 51.5 51.2 63.0
1) R.W.Schefer, M.Namazian and J.Kelly, ‘Velocity measurements in
a turbulent non-premixed bluff-body stabilised flame’,
Comb.Sci.&Tech., Vol.56, p101, (1987).
2) J.J.McGuirk, C.Papadimitriou and A.M.K.P.Taylor, ‘Reynolds
stress model calculations of two-dimensional plane and
axisymmetric recirculating flows’, Proc. 5th Turbulent Shear
Flows Conference, Cornell Univ., USA, (1985).
3) D.F.G.Durao, G.Knittel, J.C.F.Pereira and J.M.P.Rocha,
‘Measurements and modelling of the turbulent near wake
flow of a disk with a central jet, Proc. 8th Turbulent
Shear Flows Conference, Technical University of Munich,
17.5, (1991).
* GROUP 1. Run title and other preliminaries *
TEXT(2D BLUFF-BODY STABILISED METHANE JET
AUTOPLOT USE
FILE
phida 3
D 1 W1 Y 1
PLOT;SCALE X 0 .15;LEVEL X .0441;LEVEL X .0684
LEVEL Y 0.
ENDUSE
PHOTON USE
p
0.20443E+04 0.15633E+04 CR
gr ou x 1;vec x 1 sh
con w1 x 1
val 1
0.
mag gr 2
0.29927E+04 0.90539E+03 CR
ENDUSE
BOOLEAN(KWMOD);KWMOD=F
CHAR(CTURB)
REAL(RHOAIR,TIN,RAIR,RCON,RHOGAS,DGAS,DBODY,DANN,DTF,ENUAIR)
REAL(WGAS,KEGAS,EPGAS,WAIR,KEAIR,EPAIR,WARP,KEARP,EPARP)
REAL(GYM,GYP,GYDR,GY,GYDR2,GYDR3,GYDR4,GLM,GWI,GEPI,GKI,GOMI)
REAL(Y1,Y2,Y3,Y4,Z1,Z2,RGAS,FRIC,REY,US,US2,OMGAS,OMAIR,OMARP)
INTEGER(NY1,NY2,NY3,NY4,NZ1,NZ2,NYI);CHAR(SCHM)
PRESS0=1.01325E5;RAIR=8314.43/29.;TIN=298.;RCON=8314.43/16.
ENUAIR=1.58E-5
DGAS=5.4E-3;DBODY=0.05;DANN=0.1;RGAS=0.5*DGAS
** Axial geometry
Z1=2.*DANN;NZ1=85
** Central-jet radial geometry
Y1=RGAS;NY1=12
** Bluff-body radial geometry
Y2=0.5*DBODY;NY2=26
** Annular-jet radial geometry
Y3=0.5*DANN;NY3=15
** External air-stream radial geometry
Y4=0.5*(2.*DANN);NY4=12
NYI=NY1+NY2+NY3
** gas central-jet injection
WGAS=21.
KEGAS=1.6;EPGAS=1100.
RHOGAS=PRESS0/(RCON*TIN)
** air annular-jet injection
RHOAIR=PRESS0/(RAIR*TIN)
WAIR=25.
KEAIR=(0.007*WAIR)**2;EPAIR=0.1643*(KEAIR**1.5)/(0.09*(Y3-Y2))
OMAIR=EPAIR/(0.09*KEAIR)
** external air stream
WARP=0.1;KEARP=0.012;EPARP=0.019;OMARP=EPARP/(0.09*KEARP)
KEARP=(0.01*WARP)**2;EPARP=0.09*KEARP*KEARP/ENUL
OMARP=EPARP/(0.09*KEARP)
REY=WGAS*DGAS/ENUAIR;FRIC=1.0/(1.82*LOG10(REY)-1.64)**2
US=WGAS*(FRIC/8.0)**0.5;US2=US*US
KEGAS=2.*US2;EPGAS=0.1643*(KEGAS**1.5)/(0.09*Y1)
OMGAS=EPGAS/(0.09*KEGAS)
REY
GROUP 3. X-direction grid specification
CARTES=F;XULAST=0.1
GROUP 4. Y-direction grid specification
NREGY=4;REGEXT(Y,1)
fuel jet
IREGY=1;GRDPWR(Y,NY1,Y1,1.0)
bluff body
IREGY=2;GRDPWR(Y,-NY2,Y2-Y1,1.1)
air jet
IREGY=3;GRDPWR(Y,-NY3,Y3-Y2,1.1)
free stream
IREGY=4;GRDPWR(Y,NY4,Y4-Y3,1.4)
GROUP 5. Z-direction grid specification
GRDPWR(Z,NZ1,Z1,1.3)
GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,C1);SOLUTN(P1,Y,Y,Y,P,P,P)
SOLUTN(V1,P,P,P,P,P,N);SOLUTN(W1,P,P,P,P,P,N)
SOLUTN(C1,Y,Y,Y,P,P,N);STORE(ENUT,RHO1)
SOLVE(P1,W1,V1);SOLUTN(P1,Y,Y,Y,N,N,N);STORE(ENUT)
SOLUTN(W1,P,P,P,P,P,N);SOLUTN(V1,P,P,P,P,P,N)
MESG( Enter the required turbulence model:
MESG( KE - Standard k-e model (default)
MESG( CK - Chen-Kim k-e model
MESG( RNG - RNG k-e model
MESG( RKE - Realisable k-e model
MESG( KWR - Wilcox 2008 k-w model
MESG( KWS - k-w SST model
MESG(
READVDU(CTURB,CHAR,KE)
CASE :CTURB: OF
WHEN KE,2
+TEXT(KE-2D BLUFF-BODY STABILISED METHANE JET
+ MESG(Standard k-e model
+ TURMOD(KEMODL)
WHEN CK,2
+TEXT(CK-2D BLUFF-BODY STABILISED METHANE JET
+ MESG(Chen-Kim k-e model
+ TURMOD(KECHEN)
WHEN RNG,3
+ TEXT(RNG-2D BLUFF-BODY STABILISED METHANE JET
+ MESG(RNG k-e model
+ TURMOD(KERNG)
+ STORE(ETA,ALF,GEN1)
+ OUTPUT(ALF,Y,N,P,Y,Y,Y);OUTPUT(ETA,Y,N,P,Y,Y,Y)
WHEN RKE,3
+ TEXT(RKE-2D BLUFF-BODY STABILISED METHANE JET
+ MESG(Realisable k-e model
+ TURMOD(KEREAL);STORE(C1E)
+ OUTPUT(CMU,P,P,P,P,Y,Y);OUTPUT(C1E,P,P,P,P,Y,Y)
WHEN KWR,3
+ TEXT(KWR-2D BLUFF-BODY STABILISED METHANE JET
+ MESG(Wilcox 2008 k-w model
+ TURMOD(KWMODLR);STORE(FBP);FIINIT(FBP)=1.0
+ KWMOD=T
WHEN KWS,3
+ TEXT(KW SST-2D BLUFF-BODY STABILISED METHANE JET
+ MESG(Menter k-w SST model
+ TURMOD(KWSST)
+ KWMOD=T
+ STORE(BF1,BF2,GEN1,SIGK,SIGW,CDWS)
+ STORE(CWAL,CWBE)
+ FIINIT(BF1)=1.0;FIINIT(BF2)=1.0
ENDCASE
GROUP 8. Terms (in differential equations) & devices
DENPCO=T
GROUP 9. Properties of the medium (or media)
TMP1=298.
RHO1=LINSCAL;RHO1A=RHOAIR;RHO1B=RHOGAS-RHOAIR;RHO1C=16
RHO1=RECSCAL;RHO1A=1./RHOAIR;RHO1B=1./RHOGAS-1./RHOAIR;RHO1C=16
ENUL=ENUAIR;PRT(C1)=0.7
GROUP 10. Inter-phase-transfer processes and properties
GROUP 11. Initialization of variable or porosity fields *
** Bluff-body (this could be removed)
WALLCO=GRND3
FIINIT(RHO1)=RHOAIR;FIINIT(KE)=KEAIR;FIINIT(EP)=EPAIR
IF(KWMOD) THEN
+ FIINIT(OMEG)=OMAIR
ENDIF
GROUP 13. Boundary conditions and special sources *
** Central fuel injection
(stored of WIN at FUEL is WGAS*(1.2342-0.2916*YG/RGAS+0.4809*(YG/RGAS)^2-0.629*(YG/RGAS)^3)!ZSLSTR)
(stored of KEIN at FUEL is US2*(1.+(2./3.)*(YG/RGAS)+(10./3.)*(YG/RGAS)^3)!ZSLSTR)
(stored of MIXL at FUEL is RGAS*(0.14-0.08*(YG/RGAS)^2-0.06*(YG/RGAS)^4)!ZSLSTR)
(stored of EPIN at FUEL is 0.1643*KEIN^1.5/MIXL!ZSLSTR)
(stored of OMIN at FUEL is EPIN/(0.09*KEIN)!ZSLSTR)
PATCH(FUEL,LOW,1,NX,1,NY1,1,1,1,1)
(source of P1 at FUEL is COVAL(FIXFLU,RHOGAS*WIN))
(source of W1 at FUEL is COVAL(ONLYMS,WIN))
(source of KE at FUEL is COVAL(ONLYMS,KEIN))
IF(KWMOD) THEN
(source of OMEG at FUEL is COVAL(ONLYMS,OMIN))
ELSE
(source of EP at FUEL is COVAL(ONLYMS,EPIN))
ENDIF
COVAL(FUEL,C1,ONLYMS,1.0)
** Annular air injection
PATCH(AIR,LOW,1,NX,#3,#3,1,1,1,LSTEP)
COVAL(AIR,P1,FIXFLU,RHOAIR*WAIR)
COVAL(AIR,W1,ONLYMS,WAIR);COVAL(AIR,V1,ONLYMS,0.)
COVAL(AIR,KE,ONLYMS,KEAIR);COVAL(AIR,EP,ONLYMS,EPAIR)
IF(KWMOD) THEN
+ COVAL(AIR,OMEG,ONLYMS,OMAIR)
ENDIF
** Free stream inlet
PATCH(FREEIN,LOW,1,1,#4,#4,1,1,1,LSTEP)
COVAL(FREEIN,V1,ONLYMS,0.);COVAL(FREEIN,W1,ONLYMS,WARP)
COVAL(FREEIN,P1,FIXFLU,WARP*RHOAIR)
COVAL(FREEIN,KE,ONLYMS,KEARP);COVAL(FREEIN,EP,ONLYMS,EPARP)
IF(KWMOD) THEN
+ COVAL(FREEIN,OMEG,ONLYMS,OMARP)
ENDIF
** Exit boundary
OUTLET(EXIT,HIGH,1,NX,1,NY,NZ,NZ,1,LSTEP);COVAL(EXIT,P1,10.,0.0)
** Free stream outer boundary
PATCH(FREES,NORTH,1,NX,NY,NY,1,NZ,1,LSTEP)
COVAL(FREES,P1,10.0,0.0);COVAL(FREES,W1,ONLYMS,WARP)
COVAL(FREES,KE,ONLYMS,KEARP);COVAL(FREES,EP,ONLYMS,EPARP)
IF(KWMOD) THEN
+ COVAL(FREES,OMEG,ONLYMS,OMARP)
ENDIF
** Low wall boundary on bluff body
WALL(BLUFF,LOW,1,NX,#2,#2,1,1,1,LSTEP)
GROUP 15. Termination of sweeps
LSWEEP=1500
CASE :CTURB: OF
WHEN RKE,3
+ LSWEEP=2500
ENDCASE
GROUP 17. Under-relaxation devices
DTF=0.1*ZWLAST/WGAS
RELAX(P1,LINRLX,1.0)
RELAX(V1,FALSDT,DTF);RELAX(W1,FALSDT,DTF)
RELAX(C1,LINRLX,0.5);RELAX(RHO1,LINRLX,0.3)
IF(KWMOD) THEN
+ RELAX(KE,LINRLX,0.3);RELAX(OMEG,LINRLX,0.3)
ELSE
+ RELAX(KE,LINRLX,0.3);RELAX(EP,LINRLX,0.3)
+ KELIN=3
ENDIF
GROUP 18. Limits on variables or increments to them
VARMIN(C1)=1.E-10;VARMAX(C1)=1.0
GROUP 21. Print-out of variables
GROUP 22. Spot-value print-out
IXMON=1;IYMON=NY/2;IZMON=NZ-3
GROUP 23. Field print-out and plot control
ITABL=3;NPRINT=LSWEEP;TSTSWP=-1;NYPRIN=1
WALPRN=F;NAMGRD=CONV;UCONV=T
SPEDAT(SET,GXMONI,PLOTALL,L,T)
SPEDAT(SET,OUTPUT,NOFIELD,L,T)
OUTPUT(ENUT,Y,N,Y,N,Y,Y)
DISTIL=T
CASE :CTURB: OF
WHEN KE,2
+EX(P1 )=1.834E+01;EX(V1 )=7.568E-01
+EX(W1 )=1.283E+01;EX(KE )=9.551E+00
+EX(EP )=4.140E+03;EX(C1 )=5.194E-02
+EX(EPKE)=2.912E+02;EX(OMIN)=5.132E+01
+EX(EPIN)=3.029E+01;EX(MIXL)=5.950E-07
+EX(KEIN)=8.958E-03;EX(WIN )=4.979E-02
+EX(RHO1)=1.150E+00;EX(ENUT)=3.238E-03
WHEN CK,2
+EX(P1 )=1.882E+01;EX(V1 )=7.377E-01
+EX(W1 )=1.293E+01;EX(KE )=7.044E+00
+EX(EP )=3.513E+03;EX(C1 )=6.410E-02
+EX(EPKE)=3.243E+02;EX(OMIN)=5.132E+01
+EX(EPIN)=3.029E+01;EX(MIXL)=5.950E-07
+EX(KEIN)=8.958E-03;EX(WIN )=4.979E-02
+EX(RHO1)=1.142E+00;EX(ENUT)=2.262E-03
WHEN RNG,3
+EX(P1 )=1.890E+01;EX(V1 )=7.450E-01
+EX(W1 )=1.302E+01;EX(KE )=8.535E+00
+EX(EP )=3.675E+03;EX(C1 )=6.257E-02
+EX(EPKE)=3.110E+02;EX(OMIN)=5.132E+01
+EX(EPIN)=3.029E+01;EX(MIXL)=5.950E-07
+EX(KEIN)=8.958E-03;EX(WIN )=4.979E-02
+EX(GEN1)=4.066E+06;EX(RHO1)=1.143E+00
+EX(ENUT)=2.810E-03;EX(ALF )=3.010E+00
+EX(ETA )=4.570E+00
WHEN RKE,3
+EX(P1 )=1.915E+01;EX(V1 )=8.003E-01
+EX(W1 )=1.284E+01;EX(KE )=1.000E+01
+EX(EP )=3.509E+03;EX(C1 )=3.914E-02
+EX(OMIN)=5.132E+01;EX(EPIN)=3.029E+01
+EX(MIXL)=5.950E-07;EX(KEIN)=8.958E-03
+EX(WIN )=4.979E-02;EX(C1E )=4.510E-01
+EX(DWDZ)=1.532E+02;EX(DWDY)=6.598E+02
+EX(DVDZ)=4.564E+01;EX(DVDY)=9.406E+01
+EX(DUDX)=8.139E+01;EX(EPKE)=2.931E+02
+EX(CMU )=1.307E-01;EX(RHO1)=1.157E+00
+EX(ENUT)=7.337E-03
WHEN KWR,3
+EX(P1 )=2.015E+01;EX(V1 )=8.150E-01
+EX(W1 )=1.315E+01;EX(KE )=1.818E+01
+EX(EP )=5.288E+03;EX(C1 )=5.650E-02
+EX(OMIN)=5.132E+01;EX(EPIN)=3.029E+01
+EX(MIXL)=5.950E-07;EX(KEIN)=8.958E-03
+EX(WIN )=4.979E-02;EX(DWDZ)=1.530E+02
+EX(DWDY)=8.305E+02;EX(DVDZ)=4.655E+01
+EX(DVDY)=1.037E+02;EX(DUDX)=6.987E+01
+EX(GEN1)=4.184E+06;EX(FBP )=8.719E-01
+EX(XWP )=2.393E+03;EX(OMEG)=2.960E+03
+EX(RHO1)=1.148E+00;EX(ENUT)=1.110E-02
WHEN KWS,3
+EX(P1 )=1.845E+01;EX(V1 )=7.901E-01
+EX(W1 )=1.301E+01;EX(KE )=1.337E+01
+EX(EP )=5.154E+03;EX(C1 )=4.632E-02
+EX(OMIN)=5.132E+01;EX(EPIN)=3.029E+01
+EX(MIXL)=5.950E-07;EX(KEIN)=8.958E-03
+EX(WIN )=4.979E-02;EX(CWBE)=8.247E-02
+EX(CWAL)=4.451E-01;EX(CDWS)=6.142E+05
+EX(SIGW)=1.204E+00;EX(SIGK)=1.043E+00
+EX(LTLS)=2.342E-02;EX(WDIS)=1.464E-01
+EX(GEN1)=3.108E+06;EX(OMEG)=2.913E+03
+EX(RHO1)=1.154E+00;EX(ENUT)=4.841E-03
+EX(BF2 )=1.447E-01;EX(BF1 )=4.155E-02
ENDCASE
STOP