TALK=T;RUN( 1, 1)
** LOAD(x214) from the x Input Library
GROUP 1. Run title and other preliminaries
TEXT(LRN KW SST-2D TURNAROUND-DUCT FLOW:T214
TITLE
DISPLAY
This case concerns plane, two-dimensional, incompressible flow through
a 180 degree turnaround duct, as studied experimentally by Monson &
Seegmiller (1988). The duct has a width W=0.0381m and an aspect ratio
of 10. The inlet and outlet planes are located 3.5W upstream and downsteam
of the bend, respectively. The inner radius of the bend is 0.01905m, which
corresponds to a curvature ratio of 0.5. The Reynolds number based on duct
width is 1.E5, and the Dean number is 7.071E4. The flow exhibits large
streamline curvature with flow relaminarisation along the inner convex wall
together with the fromation of a separation zone near the bend exit on the
inner (convex) surface of the duct. The turnaround duct is representative
of many flows of engineering interest, such as flow in the turnaround duct
of the Space-Shuttle-Main-Engine powerhead.
Calculations are made with several low-Re forms k-e and k-w model, and the
calculation employs a relatively coarse non-uniform mesh of NY=60 and NZ=80.
Consequently, the numerical integration is taken down to the wall. The Lam-
Bremhorst k-e and Wilcox 1988 k-w models do not predict the occurence of
separation along the inner wall at the exit of the U-bend. However, the
other variants of these models do predict this feature, but with varying
size of the separation bubble. The current solutions remain sensitive to
mesh numbers. Typically, depending on the turbulence model used, 700 to 2700
sweeps are required for complete convergence.
ENDDIS
D.Monson, D. & Seegmiller, H. L., "Comparison of LDV measurements and
Navier-Stokes solutions in a two-dimensional 180 degree turn-around
duct." AIAA Paper AIAA 89-0275. (1988).
D.J.Monson, H.L.Seegmiller, P.K.McConnaughey and Y.S.Chen, 'Comparison
of experiment with calculations using curvature-corrected zero and
two-equation turbulence models for a two-dimensional U-duct', AIAA
90-1484, (1990).
J.L Yin, D.Z Wang, H Cheng & W.G.Gu,"Assessment of RANS to predict
flows with large streamline curvature", IOP Conference Series:
Materials Science and Engineering, Volume 52, Topic 2, (1990).
V.A. Sandborn & J.C.Shin, "Water Flow Measurements in a 180 Degree
Turnaround Rectangular Duct", NASA Contractor Report No: 36354,
June (1989).
PHOTON USE
p
view x
gr ou x 1
msg velocity vectors
vec x 1 sh
msg press to continue
pause
vec off; redr
msg contours of normalised w velocity resolutes
con w1nr x 1 fi;0.1
msg press to continue
pause
con del; redr
msg contours of turbulence intensities
con tint x 1 fi;0.1
msg Press and then to END
pause
con del; redr
msg contours of pressure coefficients
con cp x 1 fi;0.1
msg press to continue
pause
ENDUSE
GROUP 1. Run title
BOOLEAN(KWMOD);KWMOD=F
CHAR(CTURB,TLSC)
REAL(REYNO,WIN,TKEIN,EPSIN,WIDTH,LENGTH,YAXIS)
REAL(KEMAX,EPMAX,WSTAR,FRIC,MASIN,DTF)
REAL(RADBI,RADBO,RADC,CURVRT,DEAN)
** Reynolds number
REYNO=1.E5
** Duct width & other dimensions
WIDTH=.0381;YAXIS=1.5*WIDTH;LENGTH=3.5*WIDTH
** Inlet values
WIN=26.25;TKEIN=(0.05*WIN)**2;EPSIN=TKEIN**1.5*0.1643/(0.09*WIDTH)
** Estimate friction velocity for limiting KE & EP
FRIC=1./(1.82*LOG10(REYNO)-1.64)**2
WSTAR=WIN*(FRIC/8.)**0.5
KEMAX=(2.*WIN)**2;EPMAX=WSTAR**4/ENUL
** Dean Number
RADBO=YAXIS;RADBI=YAXIS-WIDTH;RADC=YAXIS-0.5*WIDTH
CURVRT=0.5*WIDTH/RADC ! Curvature ratio
DEAN =REYNO*(CURVRT)**0.5 ! Dean number
DEAN;CURVRT
GROUP 6. Body-fitted coordinates or grid distortion
BFC=T;NONORT=T;NX=1
NY=60;NZ=80
GSET(D,NX,NY,NZ,1.0,WIDTH,LENGTH)
GSET(P,A,0.0,0.0,LENGTH);GSET(P,B,0.0,WIDTH,LENGTH)
GSET(P,C,1.0,0.0,LENGTH);GSET(P,D,1.0,WIDTH,LENGTH)
GSET(L,LAB,A,B,NY,S2.0);GSET(L,LBD,B,D,NX,1.0)
GSET(L,LCD,C,D,NY,S2.0);GSET(L,LCA,C,A,NX,1.0)
GSET(F,FABCD,A,-,B,-,D,-,C,-)
GSET(M,FABCD,+J+I,1,1,1,TRANS)
+ GSET(C,K81,F,K1,+,0.0,0.0,0.0)
+ GSET(C,K81,F,K81,+,0.0,(YAXIS+0.5*WIDTH),0.0)
** k81-k51 cells in the outlet length
+ GSET(C,K51,F,K81,+,0.0,0.0,-LENGTH,INC,0.8)
** k51-k21 cells in the bend
+ GSET(C,K21,F,K51,RX,-3.14159,YAXIS,0.0,INC,1.0)
** k21-k1 cells in the inlet length
+ GSET(C,K1,F,K21,+,0.0,0.0,LENGTH,INC,1.2)
** Set wup=t to account better for the high curvature of
the w resolute...
WUP=T
GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1);SOLUTN(P1,Y,Y,Y,N,N,N);STORE(ENUT,LEN1,YPLS,STRS)
MESG( Enter the required turbulence model:
MESG( CK - Chen-Kim low-Re k-e model
MESG( LB - Lam-Bremhorst low-Re k-e model
MESG( KW - Wilcox 1988 low-Re k-w model
MESG( KWR - Wilcox 2008 low-Re k-w model
MESG( KWS - Low-Re k-w SST model (default)
MESG(
MESG(
READVDU(CTURB,CHAR,KWS)
CASE :CTURB: OF
WHEN CK,2
+ TEXT(CK LRN KE-2D TURNAROUND-DUCT FLOW:T214
+ MESG(Chen-Kim low-Re k-e model
+ TURMOD(KECHEN-LOWRE);TLSC=EP
+ STORE(FMU)
SOLUTN(V1,Y,Y,Y,P,P,P)
SOLUTN(W1,Y,Y,Y,P,P,P)
WHEN LB,2
+ TEXT(LRN LB KE-2D TURNAROUND-DUCT FLOW:T214
+ MESG(Lam-Bremhorst low-Re k-e model
+ TURMOD(KEMODL-LOWRE);TLSC=EP
+ STORE(FMU)
WHEN KW,2
+ TEXT(LRN KW-2D FLOW IN TURNAROUND DUCT :T214
+ MESG(Wilcox low-Re 1988 k-w model
+ TURMOD(KWMODL-LOWRE);TLSC=OMEG;KWMOD=T
+ STORE(EP);EPSIN=EPSIN/(0.09*TKEIN)
WHEN KWR,3
+ TEXT(LRN KWR-2D TURNAROUND-DUCT FLOW:T214
+ MESG(Wilcox low-Re 2008 k-w model
+ TURMOD(KWMODLR-LOWRE);STORE(FBP);FIINIT(FBP)=1.0
+ KWMOD=T;TLSC=OMEG;EPSIN=EPSIN/(0.09*TKEIN)
+ STORE(DUDY,DUDZ) ! for 2D BFC cases UCRT is stored
WHEN KWS,3
+ TEXT(LRN KW SST-2D TURNAROUND-DUCT FLOW:T214
+ MESG(Menter low-Re k-w SST model
+ TURMOD(KWSST-LOWRE)
+ KWMOD=T;EPSIN=EPSIN/(0.09*TKEIN);TLSC=OMEG
+ STORE(BF1,BF2,GEN1,SIGK,SIGW,CDWS)
+ STORE(CWAL,CWBE)
+ FIINIT(BF1)=1.0;FIINIT(BF2)=1.0
ENDCASE
STORE(CP) ! pressure coefficient
(stored of CP is 2.*P1/(RHO1*WIN*WIN))
STORE(TINT) ! turbulent intensity
(stored of TINT is KE^0.5/WIN)
STORE(W1NR) ! normalised streamwise velocity
(stored of W1NR is W1/WIN)
GROUP 8. Terms (in differential equations) & devices
GROUP 9. Properties of the medium (or media)
ENUL=WIN*WIDTH/REYNO
GROUP 11. Initialization of variable or porosity fields
FIINIT(P1)=1.E-10;FIINIT(W1)=WIN
FIINIT(KE)=TKEIN;FIINIT(:TLSC:)=EPSIN
GROUP 13. Boundary conditions and special sources
INLET(BFCIN,LOW,#1,#1,#1,#NREGY,#1,#1,1,1)
VALUE(BFCIN,P1,GRND1);VALUE(BFCIN,W1,GRND1)
VALUE(BFCIN,WCRT,-WIN);VALUE(BFCIN,KE,TKEIN)
VALUE(BFCIN,:TLSC:,EPSIN)
* Transfer density for GXBFC subroutine
BFCA=RHO1
PATCH(OUTLET,HIGH,#1,#1,#1,#NREGY,#NREGZ,#NREGZ,1,1)
COVAL(OUTLET,P1,1.E4,0.0)
COVAL(OUTLET,V1,ONLYMS,0.0);COVAL(OUTLET,W1,ONLYMS,0.0)
** N-wall
WALL(WFNN,NORTH,1,NX,NY,NY,1,NZ,1,1)
** S2-wall
WALL(WFNS,SOUTH,1,NX,1,1,1,NZ,1,1)
GROUP 15. Termination of sweeps
IF(KWMOD) THEN
+ LSWEEP=1000
ELSE
+ LSWEEP=4000
+ KELIN=1
ENDIF
MASIN=WIDTH*WIN*RHO1
RESREF(P1)=1.E-12*MASIN
RESREF(W1)=RESREF(P1)*WIN; RESREF(V1)=RESREF(W1)
RESREF(KE)=RESREF(P1)*TKEIN; RESREF(:TLSC:)=RESREF(P1)*EPSIN
GROUP 16. Termination of iterations
LITER(P1)=20
GROUP 17. Under-relaxation devices
RELAX(P1,LINRLX,1.0);DTF=ZWLAST/WIN/NZ
IF(KWMOD) THEN
+ RELAX(W1,FALSDT,DTF); RELAX(V1,FALSDT,DTF)
+ RELAX(KE,FALSDT,DTF); RELAX(OMEG,FALSDT,DTF)
ELSE
+ VARMAX(KE)=KEMAX;VARMAX(EP)=10.*EPMAX;VARMIN(ENUT)=1.E-10
ENDIF
CASE :CTURB: OF
WHEN LB,2
+ DTF=ZWLAST/WIN/NZ
+ RELAX(W1,FALSDT,DTF); RELAX(V1,FALSDT,DTF)
+ DTF=0.25*DTF
+ RELAX(KE,FALSDT,DTF); RELAX(EP,FALSDT,DTF)
+ RELAX(ENUT,LINRLX,0.3)
WHEN CK,2
+RELAX(ENUT,LINRLX,1.E-2)
+RELAX(W1,FALSDT,DTF); RELAX(V1,FALSDT,DTF)
+RELAX(KE,FALSDT,DTF); RELAX(EP,FALSDT,DTF)
ENDCASE
GROUP 22. Spot-value print-out
IYMON=2;IZMON=NZ/2;NPRMON=LSWEEP
GROUP 23. Field print-out and plot control
NPRINT=LSWEEP;ITABL=2;NPLT=10;NYPRIN=2;NZPRIN=10
TSTSWP=-1
SPEDAT(SET,GXMONI,PLOTALL,L,T)
SPEDAT(SET,OUTPUT,NOFIELD,L,T)
OUTPUT(ENUT,Y,N,Y,N,Y,Y)
DISTIL=T
CASE :CTURB: OF
WHEN LB,2
+EX(P1 )=1.348E+02;EX(V1 )=5.457E-01
+EX(W1 )=2.422E+01;EX(KE )=1.708E+01
+EX(EP )=2.727E+04
+EX(W1NR)=9.110E-01;EX(TINT)=1.396E-01
+EX(CP )=3.912E-01;EX(FMU )=9.066E-01
+EX(LTLS)=8.591E-05;EX(WDIS)=6.404E-03
+EX(STRS)=9.561E-02;EX(YPLS)=5.749E-02
+EX(LEN1)=2.360E-03;EX(ENUT)=5.323E-03
+EX(WCRT)=2.074E+01;EX(VCRT)=6.440E+00
WHEN CK,2
+EX(P1 )=1.350E+02;EX(V1 )=6.107E-01
+EX(W1 )=2.379E+01;EX(KE )=5.504E+00
+EX(EP )=1.673E+04
+EX(W1NR)=8.951E-01;EX(TINT)=8.275E-02
+EX(CP )=3.917E-01;EX(FMU )=8.870E-01
+EX(LTLS)=8.591E-05;EX(WDIS)=6.404E-03
+EX(STRS)=7.841E-02;EX(YPLS)=4.971E-02
+EX(LEN1)=1.264E-03;EX(ENUT)=1.261E-03
+EX(WCRT)=2.029E+01;EX(VCRT)=6.544E+00
WHEN KW,2
+EX(P1 )=1.362E+02;EX(V1 )=6.481E-01
+EX(W1 )=2.384E+01;EX(KE )=1.386E+01
+EX(EP )=2.661E+04;EX(W1NR)=8.968E-01
+EX(TINT)=1.228E-01;EX(CP )=3.954E-01
+EX(OMEG)=2.702E+05;EX(STRS)=6.532E-02
+EX(YPLS)=4.544E-02;EX(LEN1)=2.149E-03
+EX(ENUT)=4.271E-03;EX(WCRT)=2.037E+01
+EX(VCRT)=6.491E+00
WHEN KWR,3
+EX(P1 )=1.710E+02;EX(V1 )=8.719E-01
+EX(W1 )=2.363E+01;EX(KE )=5.395E+00
+EX(EP )=9.425E+03;EX(W1NR)=8.889E-01
+EX(TINT)=7.857E-02;EX(CP )=4.963E-01
+EX(DWDZ)=1.843E+03;EX(DWDY)=9.801E+03
+EX(DVDZ)=2.883E+03;EX(DVDY)=1.851E+03
+EX(GEN1)=1.905E+09;EX(FBP )=9.371E-01
+EX(XWP )=5.676E-02;EX(OMEG)=2.890E+05
+EX(STRS)=5.693E-02;EX(YPLS)=4.212E-02
EX(LEN1)=1.835E-03;EX(ENUT)=1.506E-03
EX(WCRT)=2.009E+01;EX(VCRT)=6.718E+00
WHEN KWS,3
+EX(P1 )=1.712E+02;EX(V1 )=8.639E-01
+EX(W1 )=2.357E+01;EX(KE )=4.804E+00
+EX(EP )=9.424E+03;EX(W1NR)=8.865E-01
+EX(TINT)=7.128E-02;EX(CP )=4.969E-01
+EX(CWBE)=7.682E-02;EX(CWAL)=5.268E-01
+EX(CDWS)=2.695E+06;EX(SIGW)=1.806E+00
+EX(SIGK)=1.767E+00;EX(LTLS)=8.591E-05
+EX(WDIS)=6.404E-03;EX(GEN1)=1.832E+09
+EX(BF2 )=9.552E-01;EX(BF1 )=7.668E-01
+EX(OMEG)=2.733E+05;EX(STRS)=5.706E-02
+EX(YPLS)=4.217E-02;EX(LEN1)=1.290E-03
+EX(ENUT)=1.037E-03;EX(WCRT)=2.004E+01
+EX(VCRT)=6.686E+00
ENDCASE
restrt(all)
LIBREF = 214
STOP