GROUP 1. Run title and other preliminaries
TEXT(LAM-BRE K-E_2D PARAB BNDRY LAYER   :T212
TITLE
  DISPLAY
  The case considered concerns steady, incompressible, turbulent
  plane flow along a smooth flat plate with zero pressure gradient
  ( see PHOENICS input Library case 192 for a complete problem
  description ). The plate is maintained at a constant temperature
  above that of the free stream. The calculations are started 0.487
  metres downstream of the leading edge, corresponding to a length
  Reynolds number REx =1E6. The turbulent Prandtl number is set
  equal to 0.86 and the molecular Prandtl number to 0.71.
 
  The turbulence is simulated by use of the Lam-Bremhorst k-eps low-
  Reynolds-number turbulence model. The calculation integrates down
  to the wall with a non-uniform radial grid so as to concentrate
  cells very close to the wall. For this purpose a grid is generated
  which is a geometric progression with the property that the ratio
  of any two adjacent cell lengths is a constant. A forward step
  size of 30% of the local width of the boundary layer is used
  together with 100 forward steps. Consequently, the marching
  integration is terminated at a length Reynolds number of about
  2.1E6.
  ENDDIS
 
  Experimental data indicates that the local skin friction
  coefficient Cf is fairly well described by the Schultz-Grunow
  correlation, i.e. Cf = 0.37*(LOG10(REx))**-2.58 where Cf =
  2.*TAUW/(RHOFRE*WFREE**2). For REx=2.1E6 this correlation yields
  Cf=3.17E-3, while the present predictions yield Cf=3.87E-3. No
  grid optimisation studies have been conducted to discover the
  sensitivity of the solution to different mesh sizes.In order to
  resolve the streamwise changes in the viscous sublayer, it is
  advised that the maximum forward step size be restricted to a
  sublayer thickness, i.e. DZ=ENUL/US where US is the friction
  velocity.
 
  AUTOPLOT USE
  file
  phi 5
 
  clear
  da 1 w1;col3;plot 1
  @
   0.10254E+03 0.26250E+04 CR
  W1(m/s)@
  @
   0.18969E+04 0.16284E+03 CR
  Distance from the Flat Plate (m)@
  msg Press e to END
  ENDUSE
REAL(YINLET,WFREE,ZO,CFEXPT,GPOWER,TFREE,TWALL,US)
REAL(TKEIN,EPSIN,DELT1,DELY,KFAC,AA);INTEGER(JJM,JJJ)
YINLET=0.0115;WFREE=33.0;ZO=0.487;GPOWER=0.85;TFREE=5.;TWALL=10.
CFEXPT=3.381E-3;US=WFREE*(0.5*CFEXPT)**0.5
    GROUP 3. X-direction grid specification
CARTES=T
    GROUP 4. Y-direction grid specification
  ** define first dely from wall and the grid-expansion
     factor Kfac which defines a constant ratio of lengths of
     two adjacent cells.
ENUL=1.5E-5;DELT1=0.5*ENUL/US;KFAC=1.08;DELY=DELT1/YINLET
  ** calculate NY from dely & Kfac
AA=(1.0/DELY)*(KFAC-1.0)+1.0;AA=LOG(AA)/LOG(KFAC)+1.0001
NY=AA
  ** define uniform grid initially
IREGY=1;GRDPWR(Y,NY,YINLET,1.0)
  ** compute expanding grid from south boundary over one
     half of the channel width
YFRAC(1)=DELY
DO JJ=2,NY
+ JJM=JJ-1
+ DELY=KFAC*DELY
+ YFRAC(JJ)=YFRAC(JJM)+DELY
ENDDO
YFRAC(NY)=1.0;YVLAST=YINLET;AZYV=GPOWER;ZWADD=ZO;DZW1=0.3
    GROUP 5. Z-direction grid specification
PARAB=T;NZ=100;AZDZ=PROPY
    GROUP 7. Variables stored, solved & named
SOLVE(P1,W1,V1,H1);STORE(ENUT);NAME(H1)=TEMP
STORE(LEN1);TURMOD(KEMODL-LOWRE);KELIN=1
    GROUP 8. Terms (in differential equations) & devices
DIFCUT=0.0;TERMS(TEMP,N,Y,Y,Y,Y,Y)
    GROUP 9. Properties of the medium (or media)
RHO1=1.0;ENUL=1.5E-5;PRT(TEMP)=0.86;PRNDTL(TEMP)=0.71
    GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=0.01*WFREE;FIINIT(TEMP)=TFREE
TKEIN=WFREE**2*0.01;EPSIN=TKEIN**1.5/YVLAST
FIINIT(KE)=TKEIN;FIINIT(EP)=EPSIN
    GROUP 13. Boundary conditions and special sources
  ** South wall boundary
WALL(WFUN,SOUTH,1,1,1,1,1,NZ,1,100)
COVAL(WFUN,TEMP,1.0/PRNDTL(TEMP),TWALL)
  **North Free Boundary
PATCH(FREE,NORTH,1,1,NY,NY,1,NZ,1,1)
COVAL(FREE,P1,1.E5,0.0);COVAL(FREE,TEMP,ONLYMS,TFREE)
COVAL(FREE,W1,ONLYMS,WFREE);COVAL(FREE,V1,ONLYMS,0.0)
COVAL(FREE,KE,ONLYMS,1.E-10);COVAL(FREE,EP,ONLYMS,1.E-10)
 
  ** Inlet Boundary: uniform profiles assumed
PATCH(LOWIN,LOW,1,1,1,NY,1,1,1,1)
COVAL(LOWIN,P1,FIXFLU,WFREE);COVAL(LOWIN,W1,ONLYMS,WFREE)
COVAL(LOWIN,TEMP,ONLYMS,TFREE);COVAL(LOWIN,V1,ONLYMS,0.0)
COVAL(LOWIN,KE,ONLYMS,TKEIN);COVAL(LOWIN,EP,ONLYMS,EPSIN)
    GROUP 14. Downstream pressure for PARAB=T
IPARAB=1
    GROUP 16. Termination of iterations
LITHYD=20; RELAX(W1,FALSDT,1.E-3)
RELAX(KE,FALSDT,1.E-3); RELAX(EP,FALSDT,1.E-3)
RESREF(P1)=1.E-10*WFREE*YINLET
RESREF(W1)=RESREF(P1)*WFREE; RESREF(V1)=RESREF(W1)
RESREF(KE)=RESREF(P1)*TKEIN; RESREF(EP)=RESREF(P1)*EPSIN
RESREF(TEMP)=RESREF(P1)*TFREE
    GROUP 18. Limits on variables or increments to them
VARMIN(W1)=1.E-10;VARMIN(ENUT)=1.E-30
VARMIN(KE)=1.E-20;VARMIN(EP)=1.E-20;VARMAX(EP)=1.E6
    GROUP 21. Print-out of variables
OUTPUT(LEN1,Y,N,N,Y,Y,Y);OUTPUT(ENUT,Y,N,N,Y,Y,Y)
    GROUP 22. Monitor print-out
NPRMON=20;IYMON=3;NPLT=5;IPLTL=LITHYD;TSTSWP=-1;ITABL=2
    GROUP 23. Field print-out and plot control
    GROUP 24. Dumps for restarts