GROUP 1. Run title and other preliminaries
TEXT(VAN DRIEST_2D PARAB BOUNDARY LAYER :T202
TITLE
  DISPLAY
  The problem considered is steady, incompressible, turbulent plane
  flow along a smooth flat plate with zero pressure gradient. The
  plate is maintained at a constant temperature above that of the
  free stream. The calculations are started 0.487 metres downstream
  of the leading edge, corresponding to a length Reynolds number
  REx of 1.E6. The initial mean- velocity profile is taken from
  published experimental data, and the initial turbulence-energy
  profile is estimated from the local friction velocity by assuming
  a distribution compatible with that measured in the fully-
  developed boundary layer.
  ENDDIS
 
  In case 190, the Prandtl mixing-length turbulence model is used
  and the mixing-length distribution is prescribed according to the
  Escudier formulae, ie Lm=k*y for y/d<<0.09/k, and Lm= 0.09*d for
  y/d>0.09. Here k is the von Karman's constant and y is the normal
  distance from the wall. The turbulent Prandtl number is set equal
  to 0.86 and the molecular Prandtl number to 0.71.
 
  The user may set REYLOW=T to activate van Driest's extension to
  the mixing-length model so as to integrate right down to the wall
  and perform a low-Reynolds-number-model calculation of the
  turbulent boundary. For this purpose 100 cells have been located
  across the boundary layer, rather than with the 20 cells used for
  the standard mixing-length model. A forward step size of 30% of
  the local width of the boundary layer is used together with 100
  forward steps. Consequently, the marching integration is
  terminated at a length Reynolds number of about 2.1E6.
 
  Experimental data indicates that the local skin friction
  coefficient Cf is fairly well described by the Schultz-Grunow
  correlation, i.e. Cf = 0.37*(LOG10(REx))**-2.58 where Cf =
  2.*TAUW/(RHOFRE*WFREE**2). For REx=2.1E6 this correlation yields
  Cf=3.17E-3, while the present PHOENICS van-Driest predictions
  yield Cf=3.23E-3.
 
  AUTOPLOT USE
  file
  phi 5
 
  clear
  da 1 w1;col3;plot 1
  @
   0.10254E+03 0.26250E+04 CR
  W1(m/s)@
  @
   0.18969E+04 0.16284E+03 CR
  Distance across the Boundary Layer(m)@
  msg Press e to END
  ENDUSE
 
REAL(YINLET,WFREE,DELTIN,ZO,AK,CFEXPT,GPOWER,TFREE,TWALL,POW)
YINLET=0.0115;WFREE=33.0;DELTIN=0.009923;ZO=0.487;AK=0.41
CFEXPT=3.381E-3;GPOWER=0.85;TFREE=5.;TWALL=10.;POW=0.2345
    GROUP 4. Y-direction grid specification
BOOLEAN(REYLOW,VARLAM); REYLOW=T;VARLAM=F
IF(REYLOW) THEN
+ NY=100;GRDPWR(Y,NY,YINLET,1.5)
  ** activate van Driest extension to the mixing length
+ IENUTA=5
ELSE
+ NY=22;YVLAST=YINLET
+ YFRAC(1)=5.000E-02;YFRAC(2)=6.200E-02
+ YFRAC(3)=7.400E-02;YFRAC(4)=1.070E-01
+ YFRAC(5)=1.450E-01;YFRAC(6)=1.860E-01
+ YFRAC(7)=2.290E-01;YFRAC(8)=2.750E-01
+ YFRAC(9)=3.220E-01;YFRAC(10)=3.720E-01
+ YFRAC(11)=4.230E-01;YFRAC(12)=4.760E-01
+ YFRAC(13)=5.300E-01;YFRAC(14)=5.850E-01
+ YFRAC(15)=6.410E-01;YFRAC(16)=6.990E-01
+ YFRAC(17)=7.570E-01;YFRAC(18)=8.160E-01
+ YFRAC(19)=8.770E-01;YFRAC(20)=9.380E-01
+ YFRAC(21)=9.690E-01;YFRAC(22)=1.000E+00
ENDIF
AZYV=GPOWER;ZWADD=ZO
    GROUP 5. Z-direction grid specification
PARAB=T;NZ=100;AZDZ=PROPY
    GROUP 7. Variables stored, solved & named
NAME(H1)=TEMP;SOLVE(P1,V1,W1,TEMP);STORE(ENUT,LEN1)
    GROUP 8. Terms (in differential equations) & devices
DIFCUT=0.0;TERMS(TEMP,N,Y,Y,Y,Y,Y)
    GROUP 9. Properties of the medium (or media)
RHO1=1.0;ENUL=1.5E-5
  ** Select Mixing-Length Formula : Group 9/Sect. 5 of GREX3
EL1=MIXLENBL;ENUT=MIXLEN;EL1A=0.0;EL1B=AK
PRT(TEMP)=0.86;PRNDTL(TEMP)=0.7
   ** test for ground-set enul
ENULA=ENUL
IF(VARLAM) THEN
+ TMP1=CONST;TMP1A=0.0;ENUL=LINTEM
ENDIF
    GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=WFREE;FIINIT(TEMP)=TFREE
    GROUP 13. Boundary conditions and special sources
  ** South Wall Boundary
WALL(WFUN,SOUTH,1,1,1,1,1,NZ,1,1);COVAL(WFUN,TEMP,LOGLAW,TWALL)
  **North Free Boundary
PATCH(FREE,NORTH,1,1,NY,NY,1,NZ,1,1)
COVAL(FREE,P1,1.E5,0.0);COVAL(FREE,TEMP,ONLYMS,TFREE)
COVAL(FREE,W1,ONLYMS,WFREE);COVAL(FREE,V1,ONLYMS,0.0)
  ** Inlet Boundary
PATCH(PROF,LOW,1,1,1,NY,1,1,1,1)
COVAL(PROF,P1,FIXFLU,GRND3);COVAL(PROF,W1,ONLYMS,GRND3)
COVAL(PROF,TEMP,ONLYMS,GRND3);COVAL(PROF,V1,ONLYMS,0.0)
    GROUP 14. Downstream pressure for PARAB=T
IPARAB=1
    GROUP 16. Termination of iterations
LITHYD=8
    GROUP 19. Data communicated by SATELLITE to GROUND
TEMP0=TWALL;PROFA=CFEXPT;PROFB=DELTIN;PROFC=POW;PROFD=WFREE
DWDY=T;DZW1=0.3
     EL1C = velocity fraction for layer-width calculation
     EL1D = free stream velocity for layer-width calculation
     EL1E = 0.0 for layer-width calculation
EL1C=0.005;EL1D=WFREE;EL1E=0.0
    GROUP 22. Monitor print-out
NPRMON=4;IYMON=3;NPLT=1;IPLTL=LITHYD;TSTSWP=-1
    GROUP 23. Field print-out and plot control
PATCH(IZEQNZ,PROFIL,1,1,1,NY,NZ,NZ,1,1);PLOT(IZEQNZ,W1,0.0,0.0)
PLOT(IZEQNZ,TEMP,0.0,0.0);PLOT(IZEQNZ,LEN1,0.0,0.0)
NYPRIN=2;NZPRIN=NZ;ORSIZ=0.4
    GROUP 24. Dumps for restarts
NYPRIN=1