TEXT(CHEN KIM K-E MODEL_PARAB PLANE JET :T104
TITLE
DISPLAY
The problem considered is the submerged free heated turbulent
plane jet in essentially stagnant surroundings. The calculations
are started at the jet discharge, and the parabolic marching
integration is carried out until both the mean flow and turbulence
profiles become self similar.
The calculations are made with 80 grid cells across the jet and
a forward step size of 2%(DZW1) of the local jet width. The y-
extent of the grid is set equal to the slot width at z = 0,
thereafter being caused to increase linearly with downstream
distance so as to accommodate the lateral spread of the jet. The
number of forward steps NZ is set equal to 560, so that the
marching integration is terminated at an axial distance of about
60 slot width's from the jet discharge.
ENDDIS
Calculations may be performed with the standard, Chen-Kim, RNG and
Realisable k-e models, and also with the Wilcox 1988 & 2008 k-w
models. The turbulent Prandtl number is set equal to 0.65.
The experimental data indicate velocity and temperature half-
width spreading rates of dyw/dz=0.11 and dyt/dz=0.14 in the
self-similar region of the jet. The present calculations predict
the following spreading rates:
data k-e ck RNG W-k-w WR k-w R.k-e M-k-w k-w-SST
dyw/dz 0.11 0.104 0.095 0.122 0.116 ? ? 0.157 0.161
dytdz 0.14 0.128 0.123 0.157 0.161 ? ? ? 0.215
The standard k-e and 1988 k-w models produce particularly good agreement
with the measured spreading rates, although the k-w solution is known
to be fairly sensitive to the free-stream value of w. The Chen-Kim
model and RNG models fare less well but are in reasonable agreement
with the measured values. The Realisable k-e model predicts no jet
spreading due to low eddy viscosities, and the Menter k-w and
k-w-SST models produced excessive spreading rates. The Wilcox 2008
model underestimates the spreading rate and predicts strange-looking
turbulence profiles. These cases need further investigation.
AUTOPLOT USE
file
iy1.csv 2
d 1 z yhlf;d 1 z yhlt;col3 1;colf 2
redr
msg half-width spreading rates
msg Press e to END
ENDUSE
PHOTON USE
P
PARADA
0.20443E+04 0.15633E+04 CR
GR OU X 1;VEC X 1 SH;
PAUSE
CL;GR OU X 1;CON ENUT X 1 FI;1
PAUSE
ENDUSE
CHAR(CTURB,TLSC)
REAL(WJET,REYNO,HSLOT,TJET,TFREE,TKEIN,EPSIN,EPSFRE,ENULAM)
REAL(TKEFRE,WFREE)
REYNO=5.E5;HSLOT=0.1;WJET=10.;TJET=1.0;TFREE=0.0
ENULAM=WJET*2.*HSLOT/REYNO
WFREE=1.E-4*WJET
TKEFRE=(0.01*WFREE)**2;EPSFRE=0.09*TKEFRE**2/ENULAM
TKEIN=(0.01*WJET)**2;EPSIN=TKEIN**1.5/(0.035*HSLOT*.1643)
GROUP 4. Y-direction grid specification
NY=80;YVLAST=HSLOT;YFRAC(1)=-80.;YFRAC(2)=1.0/80.
*** Linear grid expansion with slope DYGDZ
REAL(DYGDZ);DYGDZ=0.24;AZYV=1.0;ZWADD=HSLOT/DYGDZ
GROUP 5. Z-direction grid specification
PARAB=T;NZ=560;AZDZ=PROPY
** set DZW1=DZ/YVLAST value for AZDZ option
DZW1=0.02
GROUP 7. Variables stored, solved & named
NAME(H1)=TEMP;STORE(ENUT,LEN1);SOLVE(P1,V1,W1,TEMP)
SOLUTN(V1,P,P,P,P,P,N);SOLUTN(W1,P,P,P,P,P,N)
MESG( Enter the required turbulence model:
MESG( CHEN - Chen-Kim k-e model (default)
MESG( KE - Standard k-e model
MESG( KOW - Wilcox k-w model
MESG( RNG - RNG k-e model
MESG( RKE - Realisable k-e model
MESG( KOM - Menter 1992 k-w model
MESG( KOS - k-w SST model
MESG( KWR - Wilcox 2008 k-w model
MESG(
READVDU(CTURB,CHAR,CHEN)
CASE :CTURB: OF
WHEN CHEN,4
+ MESG(Chen-Kim k-e model
+ TURMOD(KECHEN);TLSC=EP
WHEN KE,2
+ TEXT(K-E MODEL_PARAB PLANE JET :T104
+ MESG(Standard k-e model
+ TURMOD(KEMODL);TLSC=EP
WHEN KOW,3
+ TEXT(Wilcox 1988 k-w_PARAB PLANE JET :T104
+ MESG(Wilcox 1988 k-w model
+ TURMOD(KWMODL);TLSC=OMEG
+ STORE(EP)
+ EPSIN=EPSIN/(0.09*TKEIN);EPSFRE=EPSFRE/(0.09*TKEFRE)
WHEN KWR,3
+ TEXT(Wilcox 2008 k-w_PARAB PLANE JET :T104
+ MESG(Wilcox 2008 k-w model
+ TURMOD(KWMODLR);TLSC=OMEG
+EPSIN=EPSIN/(0.09*TKEIN);EPSFRE=EPSFRE/(0.09*TKEFRE)
WHEN RNG,3
TEXT(RNG K-E MODEL_PARAB PLANE JET :T104
+ MESG(RNG k-e model
+ TURMOD(KERNG);TLSC=EP
WHEN RKE,3
TEXT(Realisable K-E_PARAB PLANE JET :T104
+ MESG(Realisable k-e model
+ TURMOD(KEREAL);TLSC=EP
+ STORE(C1E);OUTPUT(CMU,Y,Y,Y,Y,Y,Y)
+ OUTPUT(C1E,Y,Y,Y,Y,Y,Y)
+ VARMAX(CMU)=0.09
WHEN KOM,3
TEXT(Menter k-w_PARAB PLANE JET :T104
+ MESG(Menter 1992 k-w model
+ TURMOD(KWMENTER);TLSC=OMEG
+ EPSIN=EPSIN/(0.09*TKEIN);EPSFRE=EPSFRE/(0.09*TKEFRE)
+ STORE(BF1,ASOF)
WHEN KOS,3
TEXT(SST k-w_PARAB PLANE JET :T104
+ MESG(Menter 1992 k-w SST model
+ TURMOD(KWSST);TLSC=OMEG
+ EPSIN=EPSIN/(0.09*TKEIN);EPSFRE=EPSFRE/(0.09*TKEFRE)
+ STORE(BF1,BF2,GEN1,ASOF)
ENDCASE
STORE(YHLF,YHLT)
GROUP 8. Terms (in differential equations) & devices
DIFCUT=0.0;TERMS(TEMP,N,Y,Y,Y,Y,Y)
GROUP 9. Properties of the medium (or media)
ENUL=ENULAM;PRT(TEMP)=0.65
GROUP 13. Boundary conditions and special sources
1. Outer Boundary-- free stream
PATCH(HIGHY,NORTH,1,1,NY,NY,1,NZ,1,1);COVAL(HIGHY,P1,1.E4,0.0)
COVAL(HIGHY,W1,ONLYMS,0.0);COVAL(HIGHY,V1,ONLYMS,0.0)
COVAL(HIGHY,TEMP,ONLYMS,TFREE);COVAL(HIGHY,W1,ONLYMS,0.0)
COVAL(HIGHY,KE,ONLYMS,TKEFRE);COVAL(HIGHY,:TLSC:,ONLYMS,EPSFRE)
2. Inlet Boundary-- uniform velocity and temperature at slot
PATCH(SLOT,LOW,1,1,1,NY/2,1,1,1,1);COVAL(SLOT,P1,FIXFLU,RHO1*WJET)
COVAL(SLOT,W1,ONLYMS,WJET);COVAL(SLOT,TEMP,ONLYMS,TJET)
COVAL(SLOT,KE,ONLYMS,TKEIN);COVAL(SLOT,:TLSC:,ONLYMS,EPSIN)
3. Inlet Boundary-- uniform velocity and temperature
PATCH(OUTSIDE,LOW,1,1,NY/2+1,NY,1,1,1,1)
COVAL(OUTSIDE,P1,FIXFLU,RHO1*WFREE)
COVAL(OUTSIDE,W1,ONLYMS,WFREE)
COVAL(OUTSIDE,TEMP,ONLYMS,TFREE);COVAL(OUTSIDE,KE,ONLYMS,TKEFRE)
COVAL(OUTSIDE,:TLSC:,ONLYMS,EPSFRE)
GROUP 14. Downstream pressure for PARAB=T
IPARAB=1
GROUP 16. Termination of iterations
LITHYD=50; RESREF(P1)=1.E-6; RESREF(V1)=1.E-6; RESREF(W1)=1.E-6
RESREF(TEMP)=1.E-6; RESREF(KE)=1.E-6; RESREF(:TLSC:)=1.E-6
GROUP 17. Under-relaxation devices
RELAX(V1,FALSDT,10.0); RELAX(W1,FALSDT,10.0);
RELAX(TEMP,FALSDT,10.0)
RELAX(KE,FALSDT,10.0); RELAX(:TLSC:,FALSDT,10.0)
GROUP 19. Data communicated by SATELLITE to GROUND
DWDY=T
GROUP 21. Print-out of variables
OUTPUT(P1,Y,Y,Y,Y,Y,Y);OUTPUT(V1,Y,Y,Y,Y,Y,Y)
OUTPUT(W1,Y,Y,Y,Y,Y,Y);OUTPUT(TEMP,Y,Y,Y,Y,Y,Y)
GROUP 22. Monitor print-out
IZMON=NZ/2;IYMON=NY/2;ITABL=1;NPLT=1;IPLTL=LITHYD;TSTSWP=-1
** parabolic file dumping
IDISPA=1;IDISPB=1;IDISPC=NZ
** compute half-width velocity spreading rate
(stored of wh is 0.5*W1[&1&] )
(stored of th is 0.5*TEMP[&1&] )
(stored of ygp is YG)
PATCH(HWIDTH,CELL,1,NX,2,NY-1,1,NZ,1,LSTEP)
(stored of YH is 0.0)
(stored of YH at HWIDTH is YGP with IF(W1.GT.WH.AND.W1[,+1,].LT.WH))
(make1 YH1)
(store1 of YH1 at HWIDTH is MAX(YH,1.1E-10))
(print YH1 is YH1)
(stored of YHLF is YH1)
** compute half-width temperature spreading rate
(stored of YHT is 0.0)
(stored of YHT at HWIDTH is YGP with IF(TEMP.GT.TH.AND.TEMP[,+1,].LT.TH))
(make1 YHT1)
(store1 of YHT1 at HWIDTH is MAX(YHT,1.1E-10))
(print YHT1 IS YHT1)
(stored of YHLT is YHT1)
GROUP 23. Field print-out and plot control
** generate profile .csv file named IZNZ.csv
ORSIZ=0.4;PATCH(IZNZ,PROFIL,1,1,1,NY,NZ,NZ,1,1)
PLOT(IZNZ,W1,0.0,0.0);PLOT(IZNZ,TEMP,0.0,0.0)
PLOT(IZNZ,ENUT,0.0,0.0);NZPRIN=NZ
** generate axial .csv file named IY1.csv
PATCH(IY1,PROFIL,1,1,1,1,1,NZ,1,1)
PLOT(IY1,W1,0.0,0.0);PLOT(IY1,TEMP,0.0,0.0)
PLOT(IY1,YHLF,0.0,0.0);PLOT(IY1,YHLT,0.0,0.0)
NZPRIN=NZ
NZPRIN=1;NYPRIN=1
NPLT=1;ITABL=2
DISTIL=T
CASE :CTURB: OF
WHEN CHEN,4
+EX(P1 )=3.413E-02;EX(V1 )=1.386E-01
+EX(W1 )=1.290E+00;EX(KE )=4.839E-01
+EX(EP )=6.581E-01;EX(TEMP)=1.452E-01
+EX(YHT )=6.961E-03;EX(YH )=5.364E-03
+EX(YGP )=7.304E-01;EX(TH )=1.750E-01
+EX(WH )=1.949E+00;EX(YHLT)=5.569E-01
+EX(YHLF)=4.291E-01;EX(LEN1)= 1.269E-01
+EX(ENUT)= 3.850E-02
WHEN KE,2
+EX(P1 )=3.166E-02;EX(V1 )=1.329E-01
+EX(W1 )=1.378E+00;EX(KE )=4.989E-01
+EX(EP )=5.658E-01;EX(TEMP)=1.508E-01
+EX(YHT )=8.331E-03;EX(YH )=6.505E-03
+EX(YGP )=7.304E-01;EX(TH )=1.603E-01
+EX(WH )=1.777E+00;EX(YHLT)=6.665E-01
+EX(YHLF)=5.204E-01;EX(LEN1)=1.065E-01
+EX(ENUT)=4.207E-02
WHEN KOW,3
+EX(P1 )=3.933E-02;EX(V1 )=1.323E-01
+EX(W1 )=1.548E+00;EX(KE )=6.106E-01
+EX(EP )=5.702E-01;EX(TEMP)=1.723E-01
+EX(YHT )=9.016E-03;EX(YH )=6.277E-03
+EX(YGP )=7.304E-01;EX(TH )=1.556E-01
+EX(WH )=1.803E+00;EX(YHLT)=7.213E-01
+EX(YHLF)=5.021E-01;EX(OMEG)=8.140E+00
+EX(LEN1)=2.819E-01;EX(ENUT)=9.902E-02
WHEN KWR,3
+EX(P1 )=2.985E-02;EX(V1 )=1.325E-01
+EX(W1 )=1.385E+00;EX(KE )=4.897E-01
+EX(EP )=5.871E-01;EX(TEMP)=1.519E-01
+EX(YHT )=7.874E-03;EX(YH )=5.592E-03
+EX(YGP )=7.304E-01;EX(TH )=1.679E-01
+EX(WH )=1.917E+00;EX(YHLT)=6.300E-01
+EX(YHLF)=4.474E-01;EX(DWDY)=2.631E+00
+EX(FBP )=1.000E+00;EX(OMEG)=9.028E+00
+EX(LEN1)=2.195E-01;EX(ENUT)=4.302E-02
WHEN RNG,3
+EX(P1 )=4.475E-02;EX(V1 )=1.417E-01
+EX(W1 )=1.400E+00;EX(KE )=6.371E-01
+EX(EP )=6.475E-01;EX(TEMP)=1.522E-01
+EX(YHT )=8.787E-03;EX(YH )=6.961E-03
+EX(YGP )=7.304E-01;EX(TH )=1.560E-01
+EX(WH )=1.723E+00;EX(YHLT)=7.030E-01
+EX(YHLF)=5.569E-01;EX(LEN1)=1.165E-01
+EX(ENUT)=5.415E-02
WHEN RKE,3
+EX(P1 )=2.636E-04;EX(V1 )=1.538E-02
+EX(W1 )=4.574E-01;EX(KE )=1.000E-10
+EX(EP )=1.273E-04;EX(TEMP)=4.574E-02
+EX(YHT )=7.989E-04;EX(YH )=7.989E-04
+EX(YGP )=7.304E-01;EX(TH )=4.867E-01
+EX(WH )=4.867E+00;EX(YHLT)=6.720E-02
+EX(YHLF)=6.720E-02;EX(C1E )=4.300E-01
+EX(DWDY)=6.946E+00;EX(DVDY)=1.000E-10
+EX(EPKE)=1.273E+06;EX(CMU )=2.475E-01
+EX(LEN1)=1.440E-06;EX(ENUT)=2.169E-11
WHEN KOM,3
+EX(P1 )=4.070E-02;EX(V1 )=1.253E-01
+EX(W1 )=1.706E+00;EX(KE )=7.663E-01
+EX(EP )=4.543E-01;EX(YHT )=1.449E-02
+EX(YH )=1.061E-02;EX(TH )=1.266E-01
+EX(WH )=1.415E+00;EX(YHLT)=1.159E+00
+EX(YHLF)=8.491E-01;EX(ASOF)=7.435E-01
+EX(OMEG)=6.200E+00;EX(TEMP)=1.798E-01
+EX(YGP )=7.304E-01
+EX(LEN1)=2.820E-01;EX(ENUT)=1.307E-01
WHEN KOS,3
+EX(P1 )=4.325E-02;EX(V1 )=1.236E-01
+EX(W1 )=1.753E+00;EX(EP )=4.156E-01
+EX(TEMP)=1.817E-01;EX(YHT )=1.700E-02
+EX(YH )=1.244E-02;EX(TH )=1.192E-01
+EX(WH )=1.316E+00;EX(YHLT)=1.360E+00
+EX(YHLF)=9.951E-01;EX(ASOF)=5.167E-01
+EX(GEN1)=1.694E+00;EX(OMEG)=5.453E+00
+EX(LEN1)=3.232E-01;EX(ENUT)=1.564E-01
+EX(KE )=8.137E-01;EX(YGP )=7.304E-01
+EX(BF2 )=1.464E-15
ENDCASE
LIBREF = 104
STOP