TALK=T;RUN( 1, 1)
TEXT(CHEN-KIM K-E DEVELOPED CHANNEL FLOW:T101
TITLE
DISPLAY
The case considered is the 1d solution of fully-developed
turbulent flow in a plane closed channel at a Re=1.E5. The
solution is performed by use of the single-slab solver which
computes the pressure drop for the specified mass flow rate.
Calculations are made with the high-Re forms of the k-e model,
the Chen-Kim k-e model (the default run), the RNG k-e model,
the Wilcox 1988 & 2008 k-W modelS, and the Menter Baseline
& SST k-w models. For this case all models produce very similar
results, and the comparison between measured and computed
friction factors f and velocity-defect parameters vdp are
given below:
f vdp
Data 0.0156 2.32
Standard k-e 0.0160 2.25
Chen-Kim k-e 0.0157 2.27
RNG k-e model 0.0154 2.5
Wilcox 1988 k-w model 0.0166 2.0
Wilcox 2008 k-w model 0.0161 2.09
Menter k-w model 0.0166 2.0
k-w SST model 0.0158 2.05
where f=8.*(wstar/wbulk)**2 and and vdp=(wcl-wbulk)/wstar.
ENDDIS
The following AUTOPLOT use file produces two plots;
the first is the axial velocity profile; and the
second is the turbulent viscosity profile.
AUTOPLOT USE
file; phi 5
cl; da 1 w1; col9 1
msg Velocity (W1) profile. Press RETURN to continue
pause
clear;da 1 enut; col9 1
msg Effective-viscosity profile. Press RETURN; e to end
pause
ENDUSE
GROUP 1. Run title and other preliminaries
CHAR(TMOD); REAL(DHYDR,DELT,US,REYH,HGHT,WIN)
REAL(REY,TKEIN,EPSIN,OMEGIN,MIXL,FRIC,DPDZ,MASIN,DTF)
BOOLEAN(KWMOD);KWMOD=F
** NB: The the hydraulic diameter is equal to 2.*duct height,
so that pipe-flow correlations still apply
with diameter replaced by 2.*height
HGHT=0.1;WIN=1.0; REY=1.E5;DHYDR=2.*HGHT; REYH=2.*REY
FRIC=1./(1.82*LOG10(REYH)-1.64)**2;US=WIN*(FRIC/8.)**0.5
DPDZ=0.5*RHO1*WIN*WIN*FRIC/DHYDR;TKEIN=0.25*WIN*WIN*FRIC
MIXL=0.09*0.5*HGHT;EPSIN=TKEIN**1.5/MIXL*0.1643
GROUP 4. Y-direction grid specification
ENUL=WIN*HGHT/REY;DELT=2.*40.*ENUL/US
NREGY=2; REGEXT(Y,0.5*HGHT)
IREGY=1;GRDPWR(Y,29,0.5*HGHT-DELT,0.8);IREGY=2;GRDPWR(Y,1,DELT,1.0)
GROUP 5. Z-direction grid specification
ZWLAST=0.1*HGHT
GROUP 7. Variables stored, solved & named
SOLVE(W1);STORE(ENUT,LEN1);SOLUTN(W1,P,P,P,P,P,N)
MESG( Enter required turbulence model
MESG( Default: Chen-Kim k-e model
MESG( The options are:
MESG( CK - Chen-Kim k-e model (default)
MESG( KE - Standard k-e model
MESG( RNG - RNG k-e model
MESG( KW - Wilcox 1988 k-w model
MESG( KWR - Wilcox 2008 k-w model
MESG( KWM - Menter 1992 k-w model
MESG( KWS - k-w SST model
READVDU(TMOD,CHAR,CK)
CASE :TMOD: OF
WHEN CK,2
+ MESG(Chen-Kim k-e model
+ TURMOD(KECHEN);KELIN=1
WHEN KE,2
TEXT(STANDARD K-E DEVELOPED CHANNEL FLOW:T101
+ MESG(Standard k-e model
+ TURMOD(KEMODL);KELIN=1
WHEN RNG,3
TEXT(RNG K-E DEVELOPED CHANNEL FLOW:T101
+ MESG(RNG k-e model
+ TURMOD(KERNG);KELIN=1
+ STORE(ETA,ALF,GEN1)
+ OUTPUT(ALF,Y,N,P,Y,Y,Y);OUTPUT(ETA,Y,N,P,Y,Y,Y)
WHEN KW,2
TEXT(WILCOX K-W DEVELOPED CHANNEL FLOW:T101
+ MESG(Wilcox 1988 k-w model
+ TURMOD(KWMODL);KWMOD=T
EPSIN=EPSIN/(0.09*TKEIN)
WHEN KWR,3
+ TEXT(WilcoxR k-w_1D PLANE COUETTE FLOW :T100
+ MESG(Wilcox 2008 k-w model
+ TURMOD(KWMODLR);KWMOD=T
+ STORE(XWP,FBP,CDWS)
+ OMEGIN=EPSIN/(0.09*TKEIN)
WHEN KWM,3
TEXT(MENTER K-W DEVELOPED CHANNEL FLOW:T101
+ MESG(Menter 1992 k-w model
+ TURMOD(KWMENTER);KWMOD=T
+ OMEGIN=EPSIN/(0.09*TKEIN)
+ STORE(BF1);FIINIT(BF1)=1.0
WHEN KWS,3
TEXT(SST K-W DEVELOPED CHANNEL FLOW:T101
+ MESG(Menter 1992 k-w SST model
+ TURMOD(KWSST);KWMOD=T
+ OMEGIN=EPSIN/(0.09*TKEIN)
+ STORE(BF1,BF2);;FIINIT(BF1)=1.0;;FIINIT(BF2)=1.0
ENDCASE
REY;FRIC;US;DPDZ
GROUP 8. Terms (in differential equations) & devices
GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=WIN;FIINIT(KE)=TKEIN
IF(KWMOD) THEN
+ FIINIT(OMEG)=OMEGIN
ELSE
+ FIINIT(EP)=EPSIN
ENDIF
GROUP 13. Boundary conditions and special sources
WALL(WALLN,NORTH,1,1,NY,NY,1,NZ,1,1)
** re-instate OMEG wall coval for Menter k-w & SST k-w
IF(IENUTA.EQ.17.OR.IENUTA.EQ.19) THEN
+ COVAL(WALLN,EP,0.0,0.0)
+ COVAL(WALLN,OMEG,GRND2,GRND2)
ENDIF
** activate single-slab solver and specify mass flow rate
FDSOLV(FLOW,RHO1*WIN*0.5*HGHT)
GROUP 15. Termination of sweeps
LSWEEP=30;LITHYD=10
GROUP 16. Termination of iterations
GROUP 17. Under-relaxation devices
DTF=15.*ZWLAST/WIN;VARMIN(W1)=1.E-10;WALPRN=T
RELAX(W1,FALSDT,DTF); RELAX(KE,FALSDT,DTF)
IF(KWMOD) THEN
+ RELAX(OMEG,FALSDT,DTF)
ELSE
+ RELAX(EP,FALSDT,DTF)
ENDIF
GROUP 22. Spot-value print-out
IYMON=2;NPLT=2;NZPRIN=1;NYPRIN=1;IYPRF=1;ITABL=2;TSTSWP=-1
** compute flow output parameters
STORE(STRS)
(stored of FRIC is 8.*STRS/(:WIN:*:WIN:))
(stored of UTAU is STRS^0.5)
(stored of VDP is (W1[&1&]-WIN)/UTAU[&NY&])
(make ffac is 0.0)
(make ustar is 0.0)
(make vdus is 0.0)
(store1 of ffac at walln is fric)
(store1 of ustar at walln is utau)
(store1 of vdus at walln is vdp)
** print to inforout file
(print of f is ffac)
(print of u* is ustar)
(print of (ucl-ub)/u* is vdus)
DISTIL=T
CASE :TMOD: OF
WHEN CK,2
+ EX(W1 )=9.870E-01;EX(KE )=3.875E-03
+ EX(EP )=2.227E-02;EX(VDP )=2.265E+00
+ EX(UTAU)=1.484E-03;EX(FRIC)=5.219E-04
+ EX(STRS)=6.523E-05;EX(LEN1)=5.546E-03
+ EX(ENUT)=1.682E-04
WHEN KE,2
+ EX(W1 )=9.871E-01;EX(KE )=3.911E-03
+ EX(EP )=2.253E-02;EX(VDP )=2.253E+00
+ EX(UTAU)=1.502E-03;EX(FRIC)=5.344E-04
+ EX(STRS)=6.680E-05;EX(LEN1)=5.482E-03
+ EX(ENUT)=1.661E-04
WHEN RNG,3
+ EX(W1 )=9.860E-01;EX(KE )=3.875E-03
+ EX(EP )=2.209E-02;EX(VDP )=2.500E+00
+ EX(UTAU)=1.472E-03;EX(FRIC)=5.134E-04
+ EX(STRS)=6.418E-05;EX(GEN1)=1.585E+03
+ EX(ALF )=4.900E-01;EX(ETA )=3.124E+00
+ EX(LEN1)=4.754E-03;EX(ENUT)=1.429E-04
WHEN KW,2
+ EX(W1 )=9.885E-01;EX(KE )=3.995E-03
+ EX(EP )=2.285E-02;EX(OMEG)=4.340E+01
+ EX(LEN1)=6.394E-03;EX(ENUT)=1.927E-04
+ EX(VDP )=1.999E+00;EX(UTAU)=1.528E-03
+ EX(FRIC)=5.531E-04;EX(STRS)=6.914E-05
WHEN KWR,3
+ EX(KE )=3.982E-03;EX(EP )=2.281E-02
+ EX(W1 )=9.887E-01;EX(VDP )=2.087E+00
+ EX(UTAU)=1.514E-03;EX(FRIC)=5.432E-04
+ EX(STRS)=6.790E-05;EX(DWDY)=1.135E+01
+ EX(FBP )=1.000E+00;EX(OMEG)=4.329E+01
+ EX(CDWS)=1.513E+01;EX(GEN1)=3.414E+03
+ EX(LEN1)=6.087E-03;EX(ENUT)=1.815E-04
WHEN KWM,3
+ EX(W1 )=9.885E-01;EX(KE )=3.995E-03
+ EX(EP )=2.285E-02;EX(OMEG)=4.340E+01
+ EX(LEN1)=6.394E-03;EX(ENUT)=1.927E-04
+ EX(VDP )=1.978E+00;EX(UTAU)=1.529E-03
+ EX(FRIC)=5.537E-04;EX(STRS)=6.922E-05
+ EX(BF1 )=9.936E-01
+ EX(LTLS)=7.787E-04;EX(WDIS)=2.250E-02
WHEN KWS,3
+ EX(OMEG)=4.333E+01;EX(LEN1)=6.428E-03
+ EX(W1 )=9.887E-01;EX(LTLS)=7.787E-04
+ EX(WDIS)=2.250E-02;EX(GEN1)=4.443E+03
+ EX(BF2 )=1.000E+00;EX(BF1 )=9.945E-01
+ EX(KE )=3.879E-03;EX(EP )=2.216E-02
+ EX(VDP )=2.050E+00;EX(UTAU)=1.490E-03
+ EX(FRIC)=5.258E-04;EX(STRS)=6.573E-05
+ EX(GEN1)=4.301E+03;EX(ENUT)=1.844E-04
ENDCASE
LIBREF = 101
STOP