TALK=F;RUN(1,1)
DISPLAY
2D (x,y) beam is free for Time <= 0.
//// <- fixed (DisX=DisY=0)
****
* *
* **********************
* : ZV :
* : :
* **********************
* *
****
//// <- fixed (DisX=DisY=0)
Initial condition :
Time = 0: in ZV VDSY = 0.1
ENDDIS
PHOTON USE
p;parphi
1 1 700
clear
set prop off
view y
gr ou y 16
con disy y 16 fi;0.0001
msg DISY (X,Z=Time) on axes of beam
pause
clear
view 1 1 1
gr ou z 10 x 11 m y 11 22
gr ou z 10 x 1 10 y 1 m
SET VEC COMP - - -
SET VEC COMP DISX DISY -
VECT IZ 10 SH DASH 0
gr ou z 40 x 11 m y 11 22
gr ou z 40 x 1 10 y 1 m
SET VEC COMP - - -
SET VEC COMP DISX DISY -
VECT IZ 40 SH DASH 0
gr ou z 70 x 11 m y 11 22
gr ou z 70 x 1 10 y 1 m
SET VEC COMP - - -
SET VEC COMP DISX DISY -
VECT IZ 70 SH DASH 0
msg Displacement vector (Z=Time=10, 40, 70)
pause
autoplot
FILE
parphi 5
clear
data 1
DISY X m Y 14 Z 1 m
col1 1
scale
plot 1
msg DISY(Time) on end of beam
pause
ENDUSE
************************************************************
Group 1. Run Title and Number
************************************************************
TEXT(2D wave in "T" beam; S672
libref=672
TITLE
Declarations and settings
REAL(FX,LZ,LX,LY,POISSON,YOUNG)
FX = 40.e4
LX = 120.e-3
LY = 60.e-3
LZ = 10.e-3
YOUNG = 1/0.5E-11 ! Young's modulus used for exact solutions
POISSON=0.3 ! Poisson's ratio used for exact solutions
! The above must correspond to the data
! below MATFLG
INTEGER(NYBODY,NXBODY)
************************************************************
Group 2. Time dependence
STEADY = F
RSET(U,0,6.e-4,100)
************************************************************
Group 3. X-Direction Grid Spacing
CARTES = T
NXBODY = 32
GRDPWR(X,NXBODY,LX,1)
************************************************************
Group 4. Y-Direction Grid Spacing
NYBODY = 32
GRDPWR(Y,NYBODY,LY,1)
************************************************************
Group 5. Z-Direction Grid Spacing
NZ=1
ZWLAST = LZ
************************************************************
Group 7. Variables: STOREd,SOLVEd,NAMEd
ONEPHS = T
SOLVE(DISX,DISY)
SOLUTN(DISY ,Y,Y,Y,N,N,Y)
SOLUTN(DISX ,Y,Y,Y,N,N,Y)
TERMS (DISY,N,N,Y,Y,Y,N)
TERMS (DISX,N,N,Y,Y,Y,N)
STORE(PRPS,DEN1,VISL,DVO1,DRH1)
STORE(STRX,STRY)
STORE(EPSY,EPSX,EPSZ)
STORE(VDSY,VDSX)
************************************************************
GROUP 8. ITERATION NUMBERS ETC
************************************************************
GROUP 9. PROPERTIES
CSG10='Q1' ! materials with various POISSON ratios
MATFLG=T;NMAT=1
160 7800.0 0.3 473.0 43.0 1.0e-5 0.5e-11
************************************************************
GROUP 11. INITIAL VALUES
**** CALCULATE initial conditions ***
FIINIT(disx)=0.0
FIINIT(disy)=0.0
FIINIT(PRPS)=160
FIINIT(VDSX)=0.0
FIINIT(VDSY)=0.0
PATCH(FLUID1,INIVAL,10,NX,1,10,1,1,1,1)
INIT(FLUID1,PRPS,FIXVAL,0)
INIT(FLUID1,DISX,FIXVAL,0)
INIT(FLUID1,DISY,FIXVAL,0)
PATCH(FLUID2,INIVAL,10,NX,23,NY,1,1,1,1)
INIT(FLUID2,PRPS,FIXVAL,0)
INIT(FLUID2,DISX,FIXVAL,0)
INIT(FLUID2,DISY,FIXVAL,0)
RELAX(DISY,LINRLX, 1.000000E+00)
RELAX(DISX,LINRLX, 1.000000E+00)
************************************************************
GROUP 13. BOUNDARY & SPECIAL SOURCES
PATCH(TOP,NWALL,1,10,ny,ny,1,1,1,LSTEP)
COVAL(TOP,DISY,1,0.0)
COVAL(TOP,DISX,1,0.0)
PATCH(BOTTOM,SWALL,1,10,1,1,1,1,1,LSTEP)
COVAL(BOTTOM,DISY,1,0.0)
COVAL(BOTTOM,DISX,1,0.0)
**** Initial Velocity ---
PATCH(INITVEL,INIVAL,20,NX,11,22,1,1,1,1)
INIT(INITVEL,VDSY,FIXVAL,0.1)
************************************************************
GROUP 15. TERMINATE SWEEPS
LSWEEP = 60
ISG21=LSWEEP
************************************************************
GROUP 17. RELAXATION
RELAX(P1 ,LINRLX, 1.000000E+00)
************************************************************
GROUP 19. DATA TRANSMITTED TO GROUND
STRA = T
PARSOL = F
ISG52 = 3 ! probe & res
************************************************************
GROUP 23.FIELD PRINT-OUT & PLOT CONTROL
TSTSWP = - 1 ! graphic-mode
NYPRIN = 1
NXPRIN = 1
IXMON = NX
IYMON = NY/2
IZMON = 1
IDISPA = 1
inform7begin
inform7end
************************************************************
STOP