#$r002
 
   PHOTON USE
   AUTOPLOT
   file
   PHI 5
 
   cl
   da 1 tem1
   col3 1
   blb2 1
   sca x 0 1                                                                       
   sca y 400 1000                                                                  
   le y 418                                                                        
   k                                                                               
   13                                                                              
   0.61220E+03 0.28080E+04  a
   0.38113E+04 0.49844E+03  a
   0.37516E+04 0.49844E+03  x
   r                                                                               
   msg Temperature profile
   msg Analytical solution shows that TW=1000K (left side)
   msg orange line  - analytical solution
   msg blue squares - PHOENICS solution
   ENDUSE
 
   *  GROUP 1.  Run identifiers and other preliminaries.
TEXT(1-D FIXED-FLUX FLUID SURFACE : R113
TITLE
  DISPLAY
   The test case considers combined radiation and conduction in the
   domain indicated below.
        __________________________
      /|                         |/
      /|-->qflxwl=55kW/m2        |/<---TS=418K
      /|                         |/
      /|       AIR               |/
      /|       PRPS=0            |/
      /|                         |/
      /|<---Radiative zone 1     |/
      /|                         |/
      /|<---TW                   |/
       |________________________ |
        ----------> Y
        length of domain = 1.0 m, height of domain = 1.0m
 
   The problem is steady, one-dimensional and convection is absent.
   The PHOENICS solution can be compared with the analytical
   solution which shows that TW=1000.K, and the net radiative
   flux at zone 2 =54.97kW/m2
  ENDDIS
 
   ************************************************************
   *  GROUP 4.  y-direction grid specification.
GRDPWR(Y,5,1.0,1.0)
   ************************************************************
   *  GROUP 7.  Variables (including porosities) named,
   *            stored & solved.
SOLVE(TEM1);SOLUTN(TEM1,Y,Y,Y,N,N,Y)
STORE(PRPS)
   ************************************************************
   *  GROUP 9.  Properties of the medium (or media).
   *  Fluid/medium is Air-ideal_gas
   *  Reference pressure (N/m^2)
SETPRPS(1,0)
PRESS0=1.0000E+05; TEMP0=0
 
   ************************************************************
   *  GROUP 11. Initialization of fields of variables,
   *            porosities, etc.
FIINIT(TEM1)=1000
   ************************************************************
   *  GROUP 13. Boundary conditions and special sources
   * WALL boundary condition, name TFIXR to set the fixed TR
     for the conductive boundary condition
PATCH(TFIXR,NWALL,#1,#1,#1,#1,#1,#1,#1,#NREGT)
COVAL(TFIXR,TEM1,1.,418.)
   * Radiative zones have PATCH name of the form @RI###, ###
     are digits indicating the zone number. @RI indicates that
     the PATCH is for an internal radiating zone.
   * Radiation zone 1. This zone is located at the left
     wall and has a fixed fluxed boundary condition. The
     surface temperature is calculated in GXS2SR.
     The COefficient is set to GRND2 and VALue to the require
     heat flux.
PATCH(@RI001,SOUTH,#1,#1,1,1,#1,#1,#1,#NREGT)
COVAL(@RI001,TEM1,GRND2,55000.)
   * Radiation zone 2. This sone is located at the right
     wall and has a fixed temperature.
     The COefficient is set to zero and VALue set to the
     temperature.
PATCH(@RI002,NORTH,#1,#1,#1,#1,#1,#1,#1,#nregt)
COVAL(@RI002,TEM1,0.0,418.)
   ************************************************************
   *  GROUP 15. Termination criteria for sweeps and
   *            outer iterations.
LSWEEP=4;TSTSWP=-1
   ************************************************************
   *  GROUP 16. Termination criteria for inner iterations.
   ************************************************************
   *  GROUP 19. Data communicated by SATELLITE to GROUND
S2SR=T
   ************************************************************
   *  GROUP 24. Preparation for continuation runs.
 LIBREF  =       113
spedat(set,cvd,radcvd,l,t)
STOP