#$r002
   PHOTON USE
   AUTOPLOT
   file
   phi 5
 
   cl
   msg Temperature profile
   msg Analytical solution shows that
   msg TS=868K (middle location) and TR=813K (right side)
   da 1 tem1
   col3 1
   le y 868
   le y 813
   le x 0.5
   ENDUSE
 
   *  GROUP 1.  Run identifiers and other preliminaries.
TEXT(1-D Y-DIRECTION SOLID SURFACE : R107
TITLE
  DISPLAY
   The features simulated are:
   * Internal surface-to-surface radiation
   * Heat conduction including conjugate heat transfer
   * External radiative heat transfer
        ___________________________________________________
      /|                        |/                         |/
      /|<---TL=1000K            |/<---TS                   |/
      /|                        |/                  TR=293K|/
      /|                        |/    SOLID                |/
      /|       AIR              |/    ALUMINUM             |/
      /|       PRPS=0           |/    PRPS=100             |/
      /|                        |/                         |/
      /|<---Radiative zone 1    |/<---Radiative zone 2     |/
      /|                        |/                         |/
       |________________________|__________________________|
        ----------> Y
        length of domain = 1.0 m, height of domain = 1.0m
 
   The PHOENICS solution can be compared with the analytical
   solution which shows that TS=868K, and that of the right-hand
   boundary wall is 813K.
  ENDDIS
   ************************************************************
   *  User declared Real variables
   * NYG - the Y gas cell at solid/fluid interface used in
           Group 12
   * NYG set in Group 4
INTEGER(NYG)
   *  GROUP 4.  y-direction grid specification.
NREGY=2;REGEXT(Y,5.0000E-01)
   * Region 1 for fluid
IREGY=1;GRDPWR(Y,4,5.0000E-01,-1.9)
NYG=4
   * Region 2 for solid
IREGY=2;GRDPWR(Y,-6,5.0000E-01,1.9)
   *  GROUP 7.  Variables (including porosities) named,
   *            stored & solved.
SOLVE(TEM1);SOLUTN(TEM1,Y,Y,Y,N,N,Y)
STORE(PRPS)
   *  GROUP 9.  Properties of the medium (or media).
SETPRPS(1,0)
PRESS0=1.0000E+05; TEMP0=0
 
   *  GROUP 11. Initialization of fields of variables,
   *            porosities, etc.
INIADD=F
   * SOLID boundary condition, name SLD
CONPOR(SLD,-1,CELL,-#1,-#1,-#2,-#2,-#1,-#1)
COVAL(SLD,PRPS,0.0,100)
FIINIT(TEM1)=1000
   *  GROUP 13. Boundary conditions and special sources
   * WALL boundary condition, name TFIXL to set the fixed TL
     for the conductive boundary condition
PATCH(TFIXL,SWALL,#1,#1,#1,#1,#1,#1,#1,#NREGT)
COVAL(TFIXL,TEM1,1.0,1000)
   * Patch defining external heat transfer. Because the
     surface participating in external radiative heat
     transfer is a surface of the solid, the PHOENICS
     PATCH name starts with *RAD. The COefficient is the
     exchange factor for the  surface. For this simulation
     this is the product of the Stefan-Boltzman constant
     and the emissivity. The later is taken to be unity.
     The VALue is the external temperature in K.
PATCH(*RAD1,NORTH,#1,#1,#2,#2,#1,#1,#1,#1)
COVAL(*RAD1,TEM1,SIGMA,293.)
   * Radiative zones have PATCH name of the form RI###, ###
     are digits indicating the zone number. RI indicates that
     the PATCH is for an internal radiating zone.
   * Radiation zone 1. This zone is located at the left
     wall and has a fixed temperature
PATCH(@RI001,SOUTH,#1,#1,1,1,#1,#1,#1,#NREGT)
COVAL(@RI001,TEM1,0.0,1000.)
   * Radiation zone 2. The surface temperature of this zone
     is calculated in GXS2SR
PATCH(@RI002,SOUTH,#1,#1,#2,#2,#1,#1,#1,#nregt)
COVAL(@RI002,TEM1,GRND1,GRND1)
   *  GROUP 15. Termination criteria for sweeps and
   *            outer iterations.
LSWEEP=100;TSTSWP=-1
RESFAC=1E-6
   *  GROUP 16. Termination criteria for inner iterations.
S2SR=T
SPEDAT(SET,CVD,RADCVD,L,T)
 LIBREF  =       107
STOP