#$r002
   PHOTON USE
   AUTOPLOT
   file
   phi 5
 
   cl
   da 1 tem1
   col 3; blb2 1
   sca y 965 1000                                                                  
   le y 968
   k                                                                               
   13                                                                             
   0.61593E+03 0.28080E+04  a
   0.38113E+04 0.63161E+03 CR
   0.38113E+04 0.63161E+03  x
   r
   msg Temperature profile
   msg Analytical solution shows that Tw=968K (distance 1.0)
   msg orange line - analytical solution
   msg blue squares - PHOENICS solution
   ENDUSE
   *  GROUP 1.  Run identifiers and other preliminaries.
TEXT(1-D Y-DIRECTION SHELL SURFACE: R105
TITLE
  DISPLAY
   The features in this case are:
   * Internal surface-to-surface radiation
   * External linear heat transfer from a surface
     The external linear transfer coefficient is 10 W/m2/K
   * Heat conduction
        __________________________
      /|                         |/<---TW
      /|                         |/     Te=293K
      /|       AIR               |/
      /|       PRPS=0            |/
      /|<---Radiative zone 1     |/<---Radiative zone 2
      /|                         |/
      /|<---TL=1000K             |/
       |________________________ |
        ----------> Y
        length of domain = 1.0 m, height of domain = 1.0m
 
   The problem is steady, one-dimensional and convection is absent.
   The surface temperature at the left side is 1000K.
   The surface at the right side has a heat-transfer coefficient of
   10W/m^2/K to an external temperature of 293K. The surface
   temperature of the right side, Tw, is calculated.

   The PHOENICS solution can be compared with the analytical
   solution which shows that TS=968K  , and the external heat
   transfer rate=6.750kW
  ENDDIS
   ************************************************************
   *  User declared Real variables
   *  GROUP 4.  y-direction grid specification.
NREGY=1;REGEXT(Y,5.0000E-01)
IREGY=1;GRDPWR(Y,4,1.,-1.60)
   *  GROUP 7.  Variables (including porosities) named,
   *            stored & solved.
SOLVE(TEM1);SOLUTN(TEM1,Y,Y,Y,N,N,Y)
STORE(PRPS)
   *  GROUP 9.  Properties of the medium (or media).
SETPRPS(1,0)
PRESS0=1.0000E+05; TEMP0=0
   *  GROUP 11. Initialization of fields of variables,
   *            porosities, etc.
FIINIT(TEM1)=293.
   *  GROUP 13. Boundary conditions and special sources
   * WALL boundary condition, name TFIXR to set the fixed TL
     for the conductive boundary condition
PATCH(TFIXR,SWALL,1,1,1,1,1,1,#1,#NREGT)
COVAL(TFIXR,TEM1,1.,1000.)
   * Radiative zones have PATCH name of the form @RI###, ###
     are digits indicating the zone number. @RI indicates that
     the PATCH is for an internal radiating zone.
   * Radiation zone 1. This zone is located at the left wall
     and has a fixed temperature boundary condition.
     The COefficient is set to 0.0 and VALue to the required
     temperature.
PATCH(@RI001,SOUTH,1,1,1,1,1,1,#1,#NREGT)
COVAL(@RI001,TEM1,0.0,1000.)
   * Radiation zone 2. This zone is located at the right wall
     and has a calculated temperature.
     The COefficient is set to GRND2 and VALue set to the
     imposed heat flux.
PATCH(@RI002,NORTH,1,2,4,4,1,1,#1,#nregt)
COVAL(@RI002,TEM1,GRND2,0)
   * Radiation zone 2 also loses heat convectively to an external
     temperature.
     The PATCH name for the external radiation heat transfer
     must start with @EL, and has to be of type area. CO is set
     to the heat transfer coefficient, and VAL to the external
     temperature.
PATCH(@EL001,NORTH,1,2,4,4,1,1,#1,#1)
COVAL(@EL001,TEM1,10.,293)
   *  GROUP 15. Termination criteria for sweeps and
LSWEEP=10;TSTSWP=-1
   *  GROUP 16. Termination criteria for inner iterations.
RESREF(TEM1)=1.E-12*55000.
S2SR=T
 LIBREF  =       105
 spedat(set,cvd,radcvd,l,t)
STOP