PHOTON USE
p
gr ou z 1;vec z 1
msg VELOCITY VECTORS
msg Press Enter to continue
pause
red
con c1 z 1 sh;in 30
msg NEAR GROUND CONCENTRATION OF 40 mcm AEROSOL
msg Press Enter to continue
pause;con off
red
con c2 z 1 sh;in 30
msg NEAR GROUND CONCENTRATION OF 120 mcm AEROSOL
msg Press E to end
ENDUSE
GROUP 1. Run title and other preliminaries
TEXT(Polysized heavy aerosol dispersion:127
DISPLAY
In this case the PLANT option allows to predict the
sedimentation of the different size particles from
the cloud driven by the wind. It is done by the model
involving the drift-flux principles. The dependent
variables include the staedy sedimentation velocities
and the concentration of two group of particles with
40 mcm and 120 mcm. The wind is directed SOUTH-WEST
with the velocity equaled 5 m/s.
ENDDIS
REAL(DP1,DP2,WG1EX,WG2EX)
REAL(RHOP1,RHOP2,NOM,DENOM)
REAL(AGRAV,EMUG,RHOG,ENUG,HEIGHT)
REAL(UIN,C1IN,C2IN,C1FIX,C2FIX)
UIN=5.;C1IN=0.0;C2IN=0.0
C1FIX=0.12;C2FIX=0.12
AGRAV=9.81;RHOG=1.2;ENUG=1.5e-05;EMUG=ENUG*RHOG
RHOP1=1000.;RHOP2=500.
DP1=40.e-06;DP2=120.e-06
* Height of antropogenic activity layer
HEIGHT=300.;RG(1)=HEIGHT
* Stokes particles group 1 sedimentation velocity
Cd = 24./Re
WG1EX=DP1*DP1*RHOP1*AGRAV/18./ENUG/RHOG
* Oseen's particles group 2 sedimentation velocity
Cd = 24./Re*(1.+3/16*Re)
NOM=RHOP2*RHOG*AGRAV*DP2**3
DENOM=24.*EMUG*EMUG
WG2EX=8./3.*((1.+NOM/DENOM)**0.5-1.0)*ENUG/DP2
mesg( **************************************************
mesgm( Exact steady sedimentation velocities
mesg( **************************************************
mesg(For particle of :DP1:, m. the velocity =:WG1EX:, m/s
mesg(For particle of :DP2:, m. the velocity =:WG2EX:, m/s
GROUP 3. X-direction grid specification
GRDPWR(X,11,110000.0,1.0)
GROUP 4. Y-direction grid specification
GRDPWR(Y,11,110000.0,1.0)
GROUP 7. Variables stored, solved & named
SOLVE(C1,C2,C4,C5);STORE(U1,V1)
NAME(C4)=WG1;NAME(C5)=WG2
GROUP 8. Terms (in differential equations) & devices
TERMS(C1,N,Y,Y,N,Y,N);TERMS(C2,N,Y,Y,N,Y,N)
TERMS(WG1,N,N,N,N,Y,N);TERMS(WG2,N,N,N,N,Y,N)
GROUP 9. Properties of the medium (or media)
ENUL=1.;RHO1=RHOG
GROUP 11. Initialization of variable or porosity fields
FIINIT(C1)=C1IN;FIINIT(C2)=C1IN
FIINIT(U1)=UIN/1.41
FIINIT(V1)=UIN/1.41
GROUP 13. Boundary conditions and special sources
PATCH(INLETW,WEST,1,1,1,NY,1,NZ,1,LSTEP)
COVAL(INLETW,C1,RHO1*UIN/1.41,C1IN)
COVAL(INLETW,C2,RHO1*UIN/1.41,C2IN)
PATCH(INLETS,SOUTH,1,NX,1,1,1,NZ,1,LSTEP)
COVAL(INLETS,C1,RHO1*UIN/1.41,C1IN)
COVAL(INLETS,C2,RHO1*UIN/1.41,C2IN)
PATCH(SPIL,CELL,2,2,2,2,1,NZ,1,LSTEP)
COVAL(SPIL,C1,FIXVAL,C1FIX)
COVAL(SPIL,C2,FIXVAL,C2FIX)
REAL(COFA1,COFA2,COFA3)
COFA1=18.*EMUG/(RHOP1*DP1**2)
RG(3)=AGRAV;RG(4)=DP2
RG(5)=ENUG
COFA2=18.*EMUG/(RHOP2*DP2**2);RG(2)=COFA2
COFA3=54./16.*RHOG/RHOP2/DP2;RG(6)=COFA3
* Sedimentation velocity of particle 1
PATCH(VELG1,VOLUME,1,NX,1,NY,1,NZ,1,LSTEP)
COVAL(VELG1,WG1,COFA1,AGRAV/COFA1)
PLANTBEGIN
* Concentration of particle 1
PATCH(CONG1,VOLUME,1,NX,1,NY,1,NZ,1,LSTEP)
CO=WG1/RG(1)
COVAL(CONG1,C1,GRND,0.0)
* Particle 2 of sedimentation velocity
PATCH(VELG2,VOLUME,1,NX,1,NY,1,NZ,1,LSTEP)
CO=RG(2)+RG(6)*WG2
VAL=RG(3)/(RG(2)+RG(6)*WG2)
COVAL(VELG2,WG2,GRND,GRND)
* Concentration of particle 2
PATCH(CONG2,VOLUME,1,NX,1,NY,1,NZ,1,LSTEP)
CO=WG2/RG(1)
COVAL(CONG2,C2,GRND,0.0)
PLANTEND
GROUP 15. Termination of sweeps
LSWEEP=22
GROUP 17. Under-relaxation devices.
RELAX(C2,FALSDT,1000.)
RELAX(WG1,FALSDT,0.01);RELAX(WG2,FALSDT,0.01)
GROUP 18. Limits on variables or increments to them
VARMIN(C1)=0.0;VARMAX(C1)=C1FIX
VARMIN(C2)=0.0;VARMAX(C2)=C2FIX
GROUP 19. Data communicated by satellite to GROUND
NAMSAT=MOSG
GROUP 20. Preliminary print-out
GROUP 21. Print-out of variables
OUTPUT(WG1,Y,N,N,N,N,N);OUTPUT(WG2,Y,N,N,N,N,N)
GROUP 22. Spot-value print-out
IXMON=5;IYMON=5
GROUP 23. Field print-out and plot control
tstswp=-1
dmpstk=t
DISTIL=T
EX(U1)=3.546E+00; EX(V1)=3.546E+00; EX(C1)=5.840E-03
EX(C2)=2.455E-03; EX(WG1)=4.844E-02; EX(WG2)=1.731E-01
LIBREF=127
STOP