TEXT(2D BLUFF-BODY STABILISED METHANE JET
TITLE
  DISPLAY
  The case considered is 2d steady, axisymmetric, turbulent
  non-reacting flow behind a bluff-body flame holder. The flow
  configuration consists of a 5.4mm diameter methane jet seperated
  from an outer, annular air flow by a 50mm diameter bluff body.
  The flow is characterised by reverse flow in the annular air
  stream and exhibits well-defined fuel and annular air stagnation
  points along the centre-line. This case has been studied
  experimentally by Schefer et al (Comb.Sci.&Tech., Vol.56, p101,
  1987]) and was the subject of an ASCF Ercoftac CFD Workshop
  (Org: D.Garreton & O.Simonin, EDF, Chatou, France, 1994).
  ENDDIS
  The problem requires very high computational resolution for
  numerical accuracy, and like other disk-related predictions
  (e.g.McGuirk et al[ 5th TSF, 1985] & Durao et al[ 7thTSF, 1991])
  in the literature, the standard k-e model underestimates the
  size of the recirculation zone, and hence the location of the
  first stagnation point. The near field of these flows are also
  known to be sensitive to the inlet conditions.
 
  The fuel stagnation point is located 38.7mm downstream of the
  body while the air stagnation point occurs at about 63mm.
     * GROUP 1. Run title and other preliminaries *
TEXT(2D BLUFF-BODY STABILISED METHANE JET
  AUTOPLOT USE
  FILE
  PHI 5
  GDFW.DAT 2
 
  D 1 W1 Y 1;D 2
  PLOT;BLB2 2;SCALE X 0 .15;LEVEL X .0441;LEVEL X .0684
  LEVEL Y 0.
  ENDUSE
  PHOTON USE
    p
 
 
    0.20443E+04 0.15633E+04 CR
    gr ou x 1;vec x 1 sh
    con w1 x 1
    val 1
    0.
    mag gr 2
    0.29927E+04 0.90539E+03 CR
  ENDUSE
REAL(RHOAIR,TIN,RAIR,RCON,RHOGAS,DGAS,DBODY,DANN,DTF,ENUAIR)
REAL(WGAS,KEGAS,EPGAS,WAIR,KEAIR,EPAIR,WARP,KARP,EPARP)
REAL(GYM,GYP,GYDR,GY,GYDR2,GYDR3,GYDR4,GLM,GWI,GEPI,GKI)
REAL(Y1,Y2,Y3,Y4,Z1,Z2,RGAS,FRIC,REY,US,US2)
INTEGER(NY1,NY2,NY3,NY4,NZ1,NZ2,NYI);CHAR(SCHM)
PRESS0=1.01325E5;RAIR=8314.43/29.;TIN=298.;RCON=8314.43/16.
ENUAIR=1.58E-5
DGAS=5.4E-3;DBODY=0.05;DANN=0.1;RGAS=0.5*DGAS
 
  **  Axial geometry
Z1=2.*DANN;NZ1=85
  **  Central-jet radial geometry
Y1=RGAS;NY1=12
  **  Bluff-body radial geometry
Y2=0.5*DBODY;NY2=26
  **  Annular-jet radial geometry
Y3=0.5*DANN;NY3=15
  **  External air-stream radial geometry
Y4=0.5*(2.*DANN);NY4=12
 
NYI=NY1+NY2+NY3
  ** gas central-jet injection
WGAS=21.
    KEGAS=1.6;EPGAS=1100.
RHOGAS=PRESS0/(RCON*TIN)
  ** air annular-jet injection
RHOAIR=PRESS0/(RAIR*TIN)
WAIR=25.
KEAIR=(0.007*WAIR)**2;EPAIR=0.1643*(KEAIR**1.5)/(0.09*(Y3-Y2))
  ** external air stream
WARP=0.1;KARP=0.012;EPARP=0.019
 
REY=WGAS*DGAS/ENUAIR;FRIC=1.0/(1.82*LOG10(REY)-1.64)**2
US=WGAS*(FRIC/8.0)**0.5;US2=US*US
KEGAS=2.*US2;EPGAS=0.1643*(KEGAS**1.5)/(0.09*Y1)
     GROUP 3. X-direction grid specification
CARTES=F;XULAST=0.1
     GROUP 4. Y-direction grid specification
NREGY=4;REGEXT(Y,1)
  fuel jet
IREGY=1;GRDPWR(Y,NY1,Y1,1.0)
  bluff body
IREGY=2;GRDPWR(Y,-NY2,Y2-Y1,1.1)
  air jet
IREGY=3;GRDPWR(Y,-NY3,Y3-Y2,1.1)
  free stream
IREGY=4;GRDPWR(Y,NY4,Y4-Y3,1.4)
    GROUP 5. Z-direction grid specification
GRDPWR(Z,NZ1,Z1,1.3)
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,C1);SOLUTN(P1,Y,Y,Y,P,P,P)
SOLUTN(V1,P,P,P,P,P,N);SOLUTN(W1,P,P,P,P,P,N)
TURMOD(KEMODL);SOLUTN(C1,Y,Y,Y,P,P,N);STORE(ENUT,RHO1)
    GROUP 8. Terms (in differential equations) & devices
MESG( Enter required convection scheme
MESG(  Default: OSPRE for all variables
MESG( The alternative is:
MESG(  HYB - Hybrid differencing for all variables
READVDU(SCHM,CHAR,HOC)
CASE :SCHM: OF
WHEN HYB,3
+ MESG(Hybrid-differencing scheme
+ DTF=0.1*ZWLAST/WGAS
WHEN HOC,3
+ MESG(OSPRE for all variables
+ SCHEME(OSPRE,V1,W1,KE,EP)
+ DTF=0.01*ZWLAST/WGAS
ENDCASE
DENPCO=T
     GROUP 9. Properties of the medium (or media)
TMP1=298.
   RHO1=LINSCAL;RHO1A=RHOAIR;RHO1B=RHOGAS-RHOAIR;RHO1C=16
RHO1=RECSCAL;RHO1A=1./RHOAIR;RHO1B=1./RHOGAS-1./RHOAIR;RHO1C=16
ENUL=ENUAIR;PRT(C1)=0.7
     GROUP 10. Inter-phase-transfer processes and properties
     GROUP 11. Initialization of variable or porosity fields *
  ** Bluff-body (this could be removed)
WALLCO=GRND3
FIINIT(RHO1)=RHOAIR;FIINIT(KE)=KEAIR;FIINIT(EP)=EPAIR
     GROUP 13. Boundary conditions and special sources *
 ** Central fuel injection
GYM=0.
DO JJ=1,NY1
+ GYP=YFRAC(JJ)*YVLAST;GY=.5*(GYP+GYM);GYDR=GY/RGAS
+ GYDR2=GYDR*GYDR;GYDR3=GYDR2*GYDR;GYDR4=GYDR2*GYDR2
  + GWI=WGASM*(1.-GYDR)**AN
+ GWI=WGAS*(1.2342-0.2916*GYDR+0.4809*GYDR2-0.629*GYDR3)
+ GLM=0.14-0.08*GYDR2-0.06*GYDR4
+ GLM=0.5*GLM*DGAS
+ GKI=1.+2.*GYDR/3.+10.*GYDR3/3.;GKI=GKI*US2
+ GEPI=0.1643*GKI**1.5/GLM
+ PATCH(FU:JJ:,LOW,1,NX,JJ,JJ,1,1,1,1)
+ COVAL(FU:JJ:,P1,FIXFLU,RHOGAS*GWI)
+ COVAL(FU:JJ:,V1,ONLYMS,0.0);COVAL(FU:JJ:,W1,ONLYMS,GWI)
+ COVAL(FU:JJ:,KE,ONLYMS,GKI);COVAL(FU:JJ:,EP,ONLYMS,GEPI)
+ COVAL(FU:JJ:,C1,ONLYMS,1.0);GYM=GYP
ENDDO
  ** Annular air injection
PATCH(AIR,LOW,1,NX,#3,#3,1,1,1,LSTEP)
COVAL(AIR,P1,FIXFLU,RHOAIR*WAIR)
COVAL(AIR,W1,ONLYMS,WAIR);COVAL(AIR,V1,ONLYMS,0.)
COVAL(AIR,KE,ONLYMS,KEAIR);COVAL(AIR,EP,ONLYMS,EPAIR)
  ** Free stream inlet
PATCH(FREEIN,LOW,1,1,#4,#4,1,1,1,LSTEP)
COVAL(FREEIN,V1,ONLYMS,0.);COVAL(FREEIN,W1,ONLYMS,WARP)
COVAL(FREEIN,P1,FIXFLU,WARP*RHOAIR)
COVAL(FREEIN,KE,ONLYMS,KARP);COVAL(FREEIN,EP,ONLYMS,EPARP)
  ** Exit boundary
OUTLET(EXIT,HIGH,1,NX,1,NY,NZ,NZ,1,LSTEP);COVAL(EXIT,P1,10.,0.0)
  ** Free stream outer boundary
PATCH(FREES,NORTH,1,NX,NY,NY,1,NZ,1,LSTEP)
COVAL(FREES,P1,10.0,0.0);COVAL(FREES,W1,ONLYMS,WARP)
COVAL(FREES,KE,ONLYMS,KARP);COVAL(FREES,EP,ONLYMS,EPARP)
  ** Low wall boundary on bluff body
WALL(BLUFF,LOW,1,NX,#2,#2,1,1,1,LSTEP)
    GROUP 15. Termination of sweeps
LSWEEP=1200
    GROUP 17. Under-relaxation devices
RELAX(P1,LINRLX,1.0);RELAX(V1,FALSDT,DTF)
RELAX(W1,FALSDT,DTF);RELAX(KE,FALSDT,DTF)
RELAX(EP,FALSDT,DTF);RELAX(C1,LINRLX,0.5);KELIN=1
    GROUP 18. Limits on variables or increments to them
VARMIN(C1)=1.E-10;VARMAX(C1)=1.0
    GROUP 21. Print-out of variables
    GROUP 22. Spot-value print-out
IXMON=1;IYMON=NY/2;IZMON=NZ-3
    GROUP 23. Field print-out and plot control
ITABL=3;NPRINT=LSWEEP;TSTSWP=-1;NYPRIN=1
WALPRN=T;NAMGRD=CONV;UCONV=T