GROUP 1. Run title and other preliminaries
TEXT(YX LAMINAR WALL-DRIVEN CAVITY
TITLE
mesg( PC486/50 time last reported as 3.0 min
  DISPLAY
  Numerical Schemes validation example:
  2-d x-y, Cartesian, steady, elliptic simulation
  The case considered is that of steady, incompressible, laminar
  recirculating flow inside a lid-driven cavity. The geometry is a
  1m square cavity with no inflow or outflow. The flow is driven
  by as moving wall of -1m/s at the top of cavity. The Reynolds
  number based on cavity height is 1000. The calculation may be
  performed with any of the 16 convection schemes in PHOENICS,
  although here the case is set up to be run with one of 3 linear
  schemes or 2 non-linear schemes.
  ENDDIS
 
  This case is a widely-used test problem for assessing the accuracy
  and stability of various numerical methods. It serves as a useful
  test case owing to the substantial skewness of the flow
  streamlines relative to the Cartesian mesh. The numerical results
  of Ghia et al ( J. Comp. Physics, Vol.48, p387-411, 1982 ) for
  Re=100, 400, 1000, 3200 and 5000 are used by researchers as
  benchmark solutions.
  PHOTON USE
   p
 
 
  0.20443E+04 0.15633E+04 CR
  gr ou z 1;vec z 1 sh
  stream 2d z 1
  -.113 0 10
  stream 2d z 1
  0. .235e-2 10
  msg streamlines and vectors
  msg press  to end
  pause
  ENDUSE
  AUTOPLOT USE
  file
  phi 5
 
  d 1 u1 x 11;plot;swap;scale;level x 0
  msg horizontal velocity profile at x/h=0.5
  msg press  to end
  pause
  ENDUSE
CHAR(SCHM);REAL(RENO,ULID,YCAV,RLXFAC)
MESG(Enter Reynolds number - default 1000
READVDU(RENO,REAL,1000.)
ULID=1.0;YCAV=1.0
    GROUP 2. Transience; time-step specification
    GROUP 3. X-direction grid specification
IREGX=1; GRDPWR(X,-21,YCAV,1.4)
    GROUP 4. Y-direction grid specification
IREGY=1; GRDPWR(Y,-21,YCAV,1.4)
    GROUP 5. Z-direction grid specification
    GROUP 6. Body-fitted coordinates or grid distortion
    GROUP 7. Variables stored, solved & named
SOLVE(P1,U1,V1);SOLUTN(U1,Y,Y,N,N,N,N);SOLUTN(V1,Y,Y,N,N,N,N)
    GROUP 8. Terms (in differential equations) & devices
MESG( Enter required convection scheme
MESG( Default: CUS - Cubic upwind
MESG( The options are:
MESG(  CUS   - Cubic upwind
MESG(  FOU   - 1st order upwind
MESG(  QUI   - QUICK
MESG(  KOR   - KOREN    - bounded QUICK
MESG(  VAN   - MUSCL    - bounded FROMM
READVDU(SCHM,CHAR,CUS)
CASE :SCHM: OF
WHEN CUS,3
+ MESG(Cubic upwind scheme
+ SCHEME(CUS,U1,V1)
WHEN FOU,3
+ MESG(First-order upwind scheme
+ DIFCUT=0
WHEN QUI,3
+ MESG(Quadratic upwind scheme - QUICK
+ SCHEME(QUICK,U1,V1)
WHEN KOR,3
+ MESG(KOREN scheme - bounded QUICK
+ SCHEME(KOREN,U1,V1)
WHEN VAN,3
+ MESG(Van Leer MUSCL scheme
+ SCHEME(MUSCL,U1,V1)
ENDCASE
    GROUP 9. Properties of the medium (or media)
ENUL=ULID*YCAV/RENO
    GROUP 13. Boundary conditions and special sources
  ** South wall, at rest
WALL (SOUTH,SOUTH,#1,#NREGX,#1,#1,#1,#1,1,1)
COVAL(SOUTH,U1,1.0,0.0)
  ** North wall, moving
WALL (MOVE,NORTH,#1,#NREGX,#NREGY,#NREGY,#1,#1,1,1)
COVAL(MOVE,U1,1.0,-ULID)
  ** West wall, at rest
WALL (WEST,WEST,#1,#1,#1,#NREGY,#1,#1,1,1)
COVAL(WEST,V1,1.0,0.0)
  ** East wall, at rest
WALL (EAST,EAST,#NREGX,#NREGX,#1,#NREGY,#1,#1,1,1)
COVAL(EAST,V1,1.0,0.0)
  ** Pressure relief
PATCH(FIXPRESS,CELL,NX/2,NX/2,NY/2,NY/2,1,1,1,1)
COVAL(FIXPRESS,P1,FIXP,0.0)
COVAL(FIXPRESS,U1,ONLYMS,0.0);COVAL(FIXPRESS,V1,ONLYMS,0.0)
    GROUP 15. Termination of sweeps
LSWEEP=3000;TSTSWP=-1
    GROUP 16. Termination of iterations
LITER(U1)=5;LITER(V1)=5
    GROUP 17. Under-relaxation devices
RLXFAC=YVLAST/(NY*1.0);RELAX(P1,LINRLX,1.0)
RELAX(U1,FALSDT,5.0*RLXFAC);RELAX(V1,FALSDT,5.0*RLXFAC)
    GROUP 22. Spot-value print-out
IXMON=NX/2;IYMON=NY-1;ITABL=3;NPLT=10
    GROUP 23. Field print-out and plot control