MB-FGE Test: Laminar flow between two cylinders.
  **************************************************************
  DISPLAY
   This  case  concerns  laminar  flow  between two rotating
   cylinders.
 
   The grid in this case is similar to that in the  200-case
   in a sense that it has only one link to itself. But  link
   is natural one, which enables to calculate fluid flow.
 
   The link is very simple  and can be reproduced by  XCYCLE
   option of PHOENICS. Note, that using links it is possible
   to introduce as YCYCLE-, as ZCYCLE-linked grids.
 
   Q1-file contains Photon Use information.
   ---------------------------------------------------------
  ENDDIS
L(PAUSE
  **************************************************************
  PHOTON USE
  p ; ; ; ; ;
 
  g k 1
  msg This is the Grid. Press return...
  pause
  vec k 1 sh
  msg These are the velocity vectors. Press return...
  pause
  con p1 k 1 fi;0.001
  msg This is the pressure field
  ENDUSE
    GROUP 1. Run title and other preliminaries
TEXT(MB-FGE: Laminar flow between two cylinders.
TITLE
REAL(REYNO,UINT,UEXT,RINT,REXT,PI)
INTEGER(NX1,NY1,NZ1,IC)
  ** Problem definition:
PI   = 3.14159
REYNO= 300;  UINT= 1.0;  UEXT= -1.0;  RINT= 0.5;  REXT= 1.0
NX1  = 30;   NY1 = 15;   NZ1 = 1
    GROUP 6. Body-fitted coordinates or grid distortion
BFC= T; GSET(D,NX1,NY1,NZ1,REXT,REXT-RINT,0.1)
GSET(T,J:NY1+1:,F,J1,1,NX1,1,NZ1,S1.8); IC = NX1+1
GSET(C,I:NX1+1:,F,I1,RZ,2*PI,0.0,REXT,INC,1.0)
GSET(C,K:NZ1+1:,F,K1,1,NX1,1,NY1,+,0.0,0.0,0.1,INC,1.0)
DUMPC(MBGR1)
  ** Assemble blocks:
NUMBLK= 1; READCO(MBGR+L)
GVIEW(Z); VIEW
  ** Set links:
  ** The following command can be used instead of READCO(...+L).
    MBLINK(1,WEST,1,EAST)
    GROUP 7. Variables stored, solved & named
STORE(VPOR); SOLVE(P1,U1,V1)
L($F150)
    GROUP 9. Properties of the medium (or media)
ENUL= UINT*(REXT-RINT)/REYNO
    GROUP 13. Boundary conditions and special sources
    ** Walls.
MPATCH(1,WS,SWALL,1,NX1,1,1,1,NZ1,1,LSTEP)
COVAL(WS,UC1,1.0,UEXT); COVAL(WS,VC1,1.0,0.0)
MPATCH(1,WN,NWALL,1,NX1,NY1,NY1,1,NZ1,1,LSTEP)
COVAL(WN,UC1,1.0,UINT); COVAL(WN,VC1,1.0,0.0)
    ** Pressure relief
MPATCH(1,FIXPRS,CELL,NX1/4,NX1/4,NY1/2,NY1/2,1,NZ1,1,LSTEP)
COVAL(FIXPRS,P1,FIXP,1.0)
    GROUP 15. Termination of sweeps
LSWEEP = 100; TSTSWP = -1
    GROUP 16. Termination of iterations
SELREF = T; RESFAC = 1.E-3
    GROUP 17. Under-relaxation devices
RELAX(P1,LINRLX,0.5)
    GROUP 19. Data communicated by satellite to GROUND
    * LSG3 = T, activates curvilinearity treatment;
CSG3= LCRU;  LSG3= T
    GROUP 22. Spot-value print-out
IXMON = NX1/2+1; IYMON = NY1/2+1; IZMON = 1