TEXT(2D Weber Inert Furnace
TITLE
DISPLAY
The problem considered is 2-dimensional axisymmetric, steady,
turbulent isothermal swirling flow in the laboratory furnace of
Weber et al (Int.J.Heat and Fluid Flow, Vol.11, No.3, p225
(1990)).
The flow geometry consists of a solid-body vortex generator of
0.19m diameter, a 20-degree conical burner quarl with an expansion
ratio of 2, and a cylindrical furnace of 0.44m diameter. The flow
Reynolds number is about 50,000 with an inlet vortex of 0.75 swirl
number and low turbulence intensity (1%).
The flow is simulated using a 2d axisymmetric staggered BFC system
by means of the recently-developed GROUND attachment for solving
the momentum equations on 2d BFC staggered meshes with swirl.
The turbulence is represented by use of the k-e turbulence model
of Chen and Kim [1987].
The main objective of the calculation is to validate both the
staggered-BFC momentum equations and the turbulence modelling for
swirling flow.
ENDDIS
The calculations are a precursor to applying the PHOENICS extended
SCRS attachment to swirling gaseous combustion in an industrial
furnace.
A mesh of 28 radial cells by 82 axial cells is used for a
computational domain length of 4m.
REAL(PI,RV,RQ,RF,Z1,Z2,Z3,NCZ1,NCZ2,NCZ3,NCY1,NCY2,NCZALL)
REAL(U0,DTF,KEIN,EPIN,WMAX)
PI = 3.1415
* Radius vortex generator
RV = 0.095
* Radius quarl
RQ = 0.190
* Radius furnace
RF = 0.220
* Axial distance from vortex generator to quarl
Z1 = 0.142
* Axial distance over quarl
Z2 = 0.261
* Axial distance over furnace
Z3 = 0.597
Z3=2.097
* Number of cells in radial and axial dir.
NCY1 = 12
NCY2 = 2
NCZ1 = 8
NCZ2 = 8
NCZ3 = 15
NCY1 = 24
NCY2 = 4
NCZ1 = 16
NCZ2 = 16
NCZ3 = 50
NCZALL = NCZ1+NCZ2+NCZ3
* U0 er aksiell hastighet ved innloepet
* Re = U0*RV/ENUL = 4.7*0.095/1.78E-06 = 250 000
U0 = 4.7
* WMAX er tagentiell hastighet ved innloept, r=Rmax
* WMAX = S0*2*U0 hvor S0=0.7 gir WMAX = 6.6
WMAX = 6.6
* KE = U0**2/100 (turb. intensitet paa 1%)
KEIN = 0.22
* EP = CMu**0.75*KE**1.5/0.007*RV
EPIN = 25.5
DTF = 0.1*RF/(NY*WMAX)
************************************************************
Group 1. Run Title
TEXT(ke_rf220_106 )
************************************************************
Group 2. Transience
STEADY = T
************************************************************
Groups 3, 4, 5 Grid Information
* Overall number of cells, RSET(M,NX,NY,NZ,tolerance)
INTEGER(NI);BOOLEAN(SWCORR)
MESG( axisymmetric bfc corrections ? (default=N)
READVDU(ANS,CHAR,N)
IF(:ANS:.EQ.Y) THEN
+ NI=1;SWCORR=T
+ MESG( axisymmetric bfc corrections on!
ELSE
+ NI=3;SWCORR=F
+ MESG( standard bfcs with NX=3!
ENDIF
RSET(M,NI,NCY1+NCY2,NCZ1+NCZ2+NCZ3)
* Set overall domain extent:
* xulast yvlast zwlast name
XSI= 1.000E+00;YSI= RF;ZSI= Z1+Z2+Z3;
RSET(D,CHAM,XSI,YSI,ZSI)
************************************************************
Group 6. Body-Fitted coordinates
BFC=T
* Set points
XPO= 0.0000E+00;YPO= 0.0000E+00;ZPO= 0.0000E+00;
GSET(P,P1,XPO,YPO,ZPO)
XPO= 0.0000E+00;YPO= RV ;ZPO= 0.0000E+00;
GSET(P,P2,XPO,YPO,ZPO)
XPO= 0.0000E+00;YPO= RF ;ZPO= 0.0000E+00;
GSET(P,P3,XPO,YPO,ZPO)
XPO= 0.0000E+00;YPO= 0.0000E+00;ZPO= Z1 ;
GSET(P,P4,XPO,YPO,ZPO)
XPO= 0.0000E+00;YPO= RV ;ZPO= Z1 ;
GSET(P,P5,XPO,YPO,ZPO)
XPO= 0.0000E+00;YPO= RF ;ZPO= Z1 ;
GSET(P,P6,XPO,YPO,ZPO)
XPO= 0.0000E+00;YPO= 0.0000E+00;ZPO= Z1+Z2 ;
GSET(P,P7,XPO,YPO,ZPO)
XPO= 0.0000E+00;YPO= RQ ;ZPO= Z1+Z2 ;
GSET(P,P8,XPO,YPO,ZPO)
XPO= 0.0000E+00;YPO= RF ;ZPO= Z1+Z2 ;
GSET(P,P9,XPO,YPO,ZPO)
XPO= 0.0000E+00;YPO= 0.0000E+00;ZPO= Z1+Z2+Z3 ;
GSET(P,P10,XPO,YPO,ZPO)
XPO= 0.0000E+00;YPO= RQ ;ZPO= Z1+Z2+Z3 ;
GSET(P,P11,XPO,YPO,ZPO)
XPO= 0.0000E+00;YPO= RF ;ZPO= Z1+Z2+Z3 ;
GSET(P,P12,XPO,YPO,ZPO)
* Set lines/arcs
GSET(L,L1,P1,P2,NCY1,1.0)
GSET(L,L2,P2,P3,NCY2,1.0)
GSET(L,L3,P4,P5,NCY1,1.0)
GSET(L,L4,P5,P6,NCY2,1.0)
GSET(L,L5,P7,P8,NCY1,1.0)
GSET(L,L6,P8,P9,NCY2,1.0)
GSET(L,L7,P10,P11,NCY1,1.0)
GSET(L,L8,P11,P12,NCY2,1.0)
GSET(L,L9,P1,P4,NCZ1,1.0)
GSET(L,L10,P4,P7,NCZ2,1.0)
GSET(L,L11,P7,P10,NCZ3,1.2)
GSET(L,L12,P2,P5,NCZ1,1.0)
GSET(L,L13,P5,P8,NCZ2,1.0)
GSET(L,L14,P8,P11,NCZ3,1.2)
GSET(L,L15,P3,P6,NCZ1,1.0)
GSET(L,L16,P6,P9,NCZ2,1.0)
GSET(L,L17,P9,P12,NCZ3,1.2)
* Set frames
GSET(F,F1,P1,-,P2,-,P5,-,P4,-)
GSET(F,F2,P2,-,P3,-,P6,-,P5,-)
GSET(F,F3,P4,-,P5,-,P8,-,P7,-)
GSET(F,F4,P5,-,P6,-,P9,-,P8,-)
GSET(F,F5,P7,-,P8,-,P11,-,P10,-)
GSET(F,F6,P8,-,P9,-,P12,-,P11,-)
* Match a grid mesh
GSET(M,F1,+J+K,1,1,1,TRANS)
GSET(M,F2,+J+K,1,NCY1+1,1,TRANS)
GSET(M,F3,+J+K,1,1,NCZ1+1,TRANS)
GSET(M,F4,+J+K,1,NCY1+1,NCZ1+1,TRANS)
GSET(M,F5,+J+K,1,1,NCZ1+NCZ2+1,TRANS)
GSET(M,F6,+J+K,1,NCY1+1,NCZ1+NCZ2+1,TRANS)
* Copy/Transfer/Block grid planes
* rotasjon
GSET(C,I:NX+1:,F,I1,1,NCY1+NCY2,1,NCZALL,RZ,-1.0000E-01,0,0,INC,1)
* translasjon
GSET(C,I4,F,I1,1,NCY1+NCY2,1,NCZALL,+,1.0000E-01,0,0,INC,1)
**********
NONORT = T
IF(.NOT.SWCORR) THEN
* X-cyclic boundaries switched
DO KK=1,NCZALL
XCYIZ( :KK:, T )
ENDDO
ENDIF
************************************************************
Group 7. Variables: STOREd,SOLVEd,NAMEd
ONEPHS = T
* Non-default variable names
NAME(42) =ENUT ; NAME(43) =HPOR
NAME(44) =NPOR ; NAME(45) =EPOR
NAME(46) =VPOR ; NAME(47) =WCRT
NAME(48) =VCRT ; NAME(49) =DEN1
NAME(50) =UCRT
* Solved variables list
SOLVE(P1 ,U1 ,V1 ,W1)
* Stored variables list
STORE(UCRT,DEN1,VCRT,WCRT,VPOR,EPOR,NPOR,HPOR)
TURMOD(KECHEN);STORE(ENUT)
SOLUTN(P1 ,Y,Y,Y,N,N,Y)
SOLUTN(KE ,Y,Y,N,N,N,N)
SOLUTN(EP ,Y,Y,N,N,N,N)
************************************************************
Group 8. Terms & Devices
DIFCUT = 0.0
************************************************************
Group 9. Properties
RHO1 = 1.000E+03
ENUL = 1.780E-06
************************************************************
Group 10.Inter-Phase Transfer Processes
************************************************************
Group 11.Initialise Var/Porosity Fields
FIINIT(HPOR) = 1.000E+00 ; FIINIT(NPOR) = 1.000E+00
FIINIT(EPOR) = 1.000E+00 ; FIINIT(VPOR) = 1.000E+00
FIINIT(UCRT) = 0.000E+00 ; FIINIT(VCRT) = 0.000E+00
FIINIT(WCRT) = 0.000E+00 ; FIINIT(W1) = U0
FIINIT(KE) = KEIN ; FIINIT(EP) = EPIN
PATCH (ALL ,INIVAL,#1,#1,#1,#2,#1,#3,#1,#1)
CONPOR(QUARL , 0.00,VOLUME,#1,#1,#2,#2,#1,#2)
INIADD = F
************************************************************
Group 12. Convection and diffusion adjustments
************************************************************
Group 13. Boundary & Special Sources
IF(SWCORR) THEN
+ UCONV = T
+ PATCH (SWRC,CELL,1,NX,1,NY,1,NZ,1,1)
+ COVAL (SWRC,U1,FIXFLU,GRND)
+ PATCH (SWRV,VOLUME,1,NX,1,NY,1,NZ,1,1)
+ COVAL (SWRV,V1,FIXFLU,GRND)
+ COVAL (SWRV,W1,FIXFLU,GRND)
ENDIF
DO JJ = 1,NCY1
+ PATCH(VORT:JJ:,LOW,1,NX,JJ,JJ,1,1,1,1)
+ COVAL(VORT:JJ:,P1 , FIXFLU, RHO1*U0)
+ COVAL(VORT:JJ:,U1 , ONLYMS, WMAX*JJ/NCY1)
+ COVAL(VORT:JJ:,V1 , ONLYMS, 0.0)
+ COVAL(VORT:JJ:,W1 , ONLYMS, U0)
+ COVAL(VORT:JJ:,KE , ONLYMS, KEIN)
+ COVAL(VORT:JJ:,EP , ONLYMS, EPIN)
ENDDO
+ COVAL(VORT:JJ:,WCRT, U0)
+ COVAL(VORT:JJ:,UCRT, WMAX*JJ/NCY1)
inloepsbet. slik de settes ved bruk av menyen
INLET (BFCVOR1 ,LOW ,#1,#1,#1,#1,#1,#1,#1,#1)
VALUE (BFCVOR1 ,P1 , GRND1 )
VALUE (BFCVOR1 ,U1 , GRND1 )
VALUE (BFCVOR1 ,V1 , GRND1 )
VALUE (BFCVOR1 ,W1 , GRND1 )
VALUE (BFCVOR1 ,KE , 2.000E-04)
VALUE (BFCVOR1 ,EP , 2.013E-04)
VALUE (BFCVOR1 ,WCRT, 1.000E+00)
VALUE (BFCVOR1 ,UCRT, 1.000E+00)
PATCH (OUTLET ,HIGH ,#1,#1,#1,#2,#3,#3,#1,#1)
COVAL (OUTLET ,P1 , 10.0, 0.000E+00)
patch(outer,nwall,1,nx,ny,ny,#3,#nregz,1,1)
coval(outer,ke,grnd2,grnd2)
coval(outer,ep,grnd2,grnd2)
coval(outer,u1,grnd2,0)
coval(outer,w1,grnd2,0)
patch(quarln,nwall,#1,#1,#1,#1,#1,#2,1,1)
coval(quarln,ke,grnd2,grnd2)
coval(quarln,ep,grnd2,grnd2)
coval(quarln,u1,grnd2,0)
coval(quarln,w1,grnd2,0)
patch(quarll,lwall,#1,#1,#2,#2,#3,#3,1,1)
coval(quarll,ke,grnd2,grnd2)
coval(quarll,ep,grnd2,grnd2)
coval(quarll,u1,grnd2,0)
coval(quarll,v1,grnd2,0)
BFCA = 1.001E+03
************************************************************
Group 14. Downstream Pressure For PARAB
************************************************************
Group 15. Terminate Sweeps
LSWEEP = 500
LITHYD = 1
SELREF = T
RESFAC = 1.000E-03
************************************************************
Group 16. Terminate Iterations
************************************************************
Group 17. Relaxation
RELAX(P1 ,LINRLX, 5.000E-01)
RELAX(U1 ,FALSDT, DTF)
RELAX(V1 ,FALSDT, DTF)
RELAX(W1 ,FALSDT, DTF)
RELAX(KE ,FALSDT, DTF)
RELAX(EP ,FALSDT, DTF)
KELIN = 1
************************************************************
Group 18. Limits
************************************************************
Group 19. EARTH Calls To GROUND Station
* Inkluderer alle gradienter i midelhastighets feltet naar
* produksjonsleddet i k-likningen beregnes
************************************************************
Group 20. Preliminary Printout
ECHO = T
************************************************************
Group 21. Print-out of Variables
************************************************************
Group 22. Monitor Print-Out
IXMON = 1 ;IYMON = 6 ;IZMON = 15
TSTSWP = -1 ;ITABL=3
************************************************************
Group 23.Field Print-Out & Plot Control
No PATCHes used for this Group
************************************************************
Group 24. Dumps For Restarts
************************************************************
MENSAV(S,RELX,DEF,2.5000E-01,1,1.0000E-01)
MENSAV(S,PHSPROP,DEF,200,0,1.0005E+03,1.7880E-06)
MENSAV(S,FLPRP,DEF,K-E,CONSTANT,AIR-CONSTANT)
NAMFI=INPR
SAVE=T ; NSAVE=OUTI
RESTRT(ALL)
ITABL=3;NPLT=5