TEXT(Premixed 2Step CH4 Combustion
TITLE
  DISPLAY
  The problem considered is turbulent reacting flow in a
  cylindrical combustion chamber with central and annular
  coaxial feed injectors supplying premixed methane and
  air. The geometry is axisymmetric with an outer radius
  of 0.2m and an axial length of 2m. The reactants are
  supplied at a temperature of 300K, and the composition of
  each inlet stream is identical. The default fuel/air
  equivalence ratio is 1.15, and the operating pressure
  is 1 bar.
  ENDDIS
    GROUP 1. Run title and other preliminaries
REAL(WINF,WINO,KEL,EPL,KEINIT,TWAL,TEMFU,TEMOX)
CHAR(ANS2);INTEGER(NYG);BOOLEAN(HSOLV,THRAD,BLOCK)
REAL(RTUBE,ZLEN)
REAL(YFU1IN,YOX1IN,YN21IN,YH2O1I,YCO21I)
REAL(YFU2IN,YOX2IN,YN22IN,YH2O2I,YCO22I)
HSOLV=T;THRAD=T
WINF=115.0;WINO=10.0; RTUBE=0.2;ZLEN=2.743
TWAL=100.+273.;TEMFU=470.;TEMOX=503.
MESG( porosity test ? (default=N)
READVDU(ANS,CHAR,N)
IF(:ANS:.EQ.Y) THEN
+ BLOCK=T
+ MESG( Porosities present
ELSE
+ BLOCK=F
+ MESG( No porosities
ENDIF
  ** fuel-rich stream
YFU1IN=0.07;YOX1IN=0.1764;YH2O1I=0.02118;YCO21I=0.0263
YN21IN=1.-YFU1IN-YOX1IN-YH2O1I-YCO21I
  ** fuel-lean stream
YFU2IN=0.0275;YOX2IN=0.1914;YH2O2I=0.01862;YCO22I=0.02353
YN22IN=1.-YFU2IN-YOX2IN-YH2O2I-YCO22I
    GROUP 2. Transience; time-step specification
STEADY=T
    GROUP 3. X-direction grid specification
CARTES=F;XULAST=0.1
    GROUP 4. Y-direction grid specification
NYG=8
IF(BLOCK) THEN
+ NREGY=5;NY=12
ELSE
+ NREGY=4;NY=8
ENDIF
IREGY=1;GRDPWR(Y,2,0.0191,1.0);IREGY=2;GRDPWR(Y,2,0.0286,1.0)
IREGY=3;GRDPWR(Y,2,0.0548,1.0);IREGY=4;GRDPWR(Y,2,0.1048,1.0)
IF(BLOCK) THEN
+ IREGY=5;GRDPWR(Y,4,0.1048,1.0)
ENDIF
    GROUP 5. Z-direction grid specification
NREGZ=2;NZ=10
IREGZ=1;GRDPWR(Z,4,0.381,1.0);IREGZ=2;GRDPWR(Z,6,2.362,1.3)
    GROUP 6.  Body-fitting and other grid distortions.
MESG( BFC test ? (default=N)
READVDU(ANS,CHAR,N)
IF(:ANS2:.EQ.Y) THEN
+ BFC=T;NONORT=T
+ MESG( BFCs present
ELSE
+ BFC=F
+ MESG( No BFCs
ENDIF
IF(BLOCK) THEN
+ CONPOR(BLK1,0.0,CELL,1,NX,NYG+1,NY,1,NZ)
+ OUTPUT(VPOR,P,P,Y,P,P,P)
ENDIF
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1);STORE(VIST,DEN1,TMP1,SPH1,YSUM)
SOLUTN(P1,P,P,Y,P,P,P);SOLUTN(V1,P,P,P,P,P,N)
SOLUTN(W1,P,P,P,P,P,N);TURMOD(KEMODL)
IF(HSOLV) THEN
+ SOLVE(H1);TERMS(H1,N,P,P,P,P,P)
+ SOLUTN(H1,P,P,Y,P,P,P)
ELSE
+ STORE(H1)
ENDIF
IF(THRAD) THEN
+ REAL(ABSORB,SCAT,SIGMA,EMPW,EMISW,EMISG,EMPG)
+ ABSORB=1.45;SCAT=0.; EMISG=0.07
+ SIGMA=5.6697E-8; EMISW=1.0
+ EMPW=SIGMA*TWAL**4; EMPG=SIGMA*EMISG
+ RADIAT(RADI,ABSORB,SCAT,H1)
+ SOLUTN(H1,P,P,Y,P,P,P);SOLUTN(SRAD,P,P,Y,P,P,P)
ENDIF
    GROUP 8. Terms (in differential equations) & devices
    GROUP 9.  Properties of the medium (or media).
ENUL=4.2E-5
  *** START OF EXTENDED SCRS MODEL SETTINGS
PRESS0=1.0000E+05
INTEGER(NSPEC,NELEM);NSPEC=7;NELEM=4
INTEGER(NCSTEP,NCREAC);NCSTEP=2;NCREAC=3
SCRS(SYSTEM,NCSTEP,NCREAC,NELEM,FRATE)
SCRS(SPECIES,CH4,O2,H2,CO,H2O,CO2,N2)
STORE(P1RS,S1RS,S2RS,MMWT,ELC,ELN,ELO,ELH)
   ** Define fuel & oxidiser composition & temperatures
SCRS(FUIN,YFU1IN,YOX1IN,0.0,0.0,YH2O1I,YCO21I,YN21IN,TEMFU)
SCRS(OXIN,YFU2IN,YOX2IN,0.0,0.0,YH2O2I,YCO22I,YN22IN,TEMOX)
SCRS(PROP,CHEMKIN,SCRS)
MESG(2 step 3 reactions finite-rate EBU model
MESG(2CH4 +  O2 > 2CO + 4H2
MESG(2CO  +  O2 > 2CO2
MESG(2H2  +  O2 > 2H2O
  *** END OF EXTENDED SCRS MODEL SETTINGS
    GROUP 11. Initialization of variable or porosity fields
INIADD=F; FIINIT(W1)=20.
KEINIT=((2.E-2*5.)**2)/2.; FIINIT(EP)=65.*(KEINIT**1.5)
IF(THRAD) THEN
+ REAL(TGUESS);TGUESS=500.
+ FIINIT(SRAD)=0.07*SIGMA*TGUESS**4
ENDIF
IF(HSOLV) THEN
+ FIINIT(H1)=-1.39E5
ENDIF
FIINIT(KE)=KEINIT; FIINIT(CH4)=YFU1IN
    GROUP 13. Boundary conditions and special sources
   * INLET boundary condition for centre burner
KEL=0.5*(0.2*27.18)**2; EPL=1.643*((KEL)**1.5)/0.0095
INLET(SCRSF,LOW,1,NX,#2,#2,1,1,#1,#NREGT)
VALUE(SCRSF,EP,EPL); VALUE(SCRSF,KE,KEL)
VALUE(SCRSF,F,1.); VALUE(SCRSF,CH4,YFU1IN)
IF(HSOLV) THEN
+ VALUE(SCRSF,H1,GRND3)
ENDIF
IF(BFC) THEN
+ VALUE(SCRSF,P1,GRND3)
+ VALUE(SCRSF,V1,GRND3); VALUE(SCRSF,W1,GRND3)
+ VALUE(SCRSF,VCRT,ZERO); VALUE(SCRSF,WCRT,115.0)
ELSE
+ VALUE(SCRSF,P1,GRND1); VALUE(SCRSF,W1,115.0)
ENDIF
   * INLET boundary condition, name OUTER "Oxidiser" BURNER
KEL=0.5*(0.2*6.18)**2; EPL=1.643*((KEL)**1.5)/0.05
INLET(SCRSO,LOW,1,NX,#4,#4,1,1,#1,#NREGT)
VALUE(SCRSO,P1,GRND3)
VALUE(SCRSO,EP,EPL); VALUE(SCRSO,KE,KEL)
VALUE(SCRSO,F,0.); VALUE(SCRSO,CH4,YFU2IN)
IF(HSOLV) THEN
+ VALUE(SCRSO,H1,GRND3)
ENDIF
IF(BFC) THEN
+ VALUE(SCRSO,P1,GRND3)
+ VALUE(SCRSO,V1,GRND3); VALUE(SCRSO,W1,GRND3)
+ VALUE(SCRSO,VCRT,ZERO); VALUE(SCRSO,WCRT,10.0)
ELSE
+ VALUE(SCRSO,P1,GRND1); VALUE(SCRSO,W1,10.0)
ENDIF
   * OUTLET boundary condition, name OUT
PATCH(OUT,HIGH,1,NX,1,NYG,#NREGZ,#NREGZ,#1,#NREGT)
COVAL(OUT,P1,10.0,0.);COVAL(OUT,F,ONLYMS,SAME)
IF(HSOLV) THEN
+ COVAL(OUT,H1,ONLYMS,SAME)
ENDIF
   * WALL boundary condition, name WALL3
PATCH(NWALL3,NWALL,1,NX,NYG,NYG,1,NZ,#1,#NREGT)
COVAL(NWALL3,W1,GRND2,0.0)
COVAL(NWALL3,KE,GRND2,GRND2);COVAL(NWALL3,EP,GRND2,GRND2)
 
IF(THRAD) THEN
+ PATCH(NWALL3R,NORTH,1,NX,NYG,NYG,1,NZ,#1,#NREGT)
+ COVAL(NWALL3R,SRAD,EMISW/(2.0-EMISW),EMPW)
ENDIF
    GROUP 15. Termination of sweeps
LSWEEP=250
    GROUP 16. Termination of iterations
    GROUP 17. Under-relaxation devices
RELAX(P1,LINRLX,1.0); RELAX(V1,FALSDT,5.E-3)
RELAX(W1,FALSDT,5.E-3); RELAX(KE,FALSDT,5.E-3)
RELAX(EP,FALSDT,5.E-3); RELAX(DEN1,LINRLX,0.5)
RELAX(F,LINRLX,0.8)
RELAX(CH4,FALSDT,1.E-3); RELAX(CO,FALSDT,1.E-3)
RELAX(H2,FALSDT,1.E-3)
IF(HSOLV) THEN
+ RELAX(H1,FALSDT,1.0)
ENDIF
IF(THRAD) THEN
+ RELAX(SRAD,FALSDT,1.0)
ENDIF
    GROUP 18. Limits on variables or increments to them
VARMIN(TMP1)=1.E-10; VARMIN(DEN1)=1.E-10
OUTPUT(TMP1,P,P,P,P,Y,Y); OUTPUT(DEN1,P,P,P,P,Y,Y)
    GROUP 20. Preliminary print-out
ECHO=T
    GROUP 21. Print-out of variables
TSTSWP=-1
    GROUP 22. Spot-value print-out
IXMON=1;IYMON=NYG/2;IZMON=6
    GROUP 23. Field print-out and plot control
ITABL=3;NPLT=10;NYPRIN=1
    GROUP 24. Dumps for restarts