TEXT(Premixed CO And H2 Combustion
TITLE
  DISPLAY
  The problem considered is turbulent reacting flow in a
  cylindrical combustion chamber with central and annular
  coaxial feed injectors supplying premixed hydrogen, air
  and carbon monoxide. The geometry is axisymmetric with
  an outer radius of 0.21m and an axial length of 2.75m.
  The reactants are supplied at a temperature of 300K, and
  the composition of each inlet stream is identical. The
  default fuel/air equivalence ratio is 1.15, and the
  operating pressure is 1 bar.
  ENDDIS
    GROUP 1. Run title and other preliminaries
REAL(WINF,WINO,KEL,EPL,KEINIT,TWAL,TEMFU,TEMOX)
REAL(YCOIN,YH2IN,YOXIN,YN2IN);CHAR(CTUR)
INTEGER(ICOMB,ICASE);BOOLEAN(HSOLV,THRAD);HSOLV=T;THRAD=F
WINF=27.18;WINO=6.418
TWAL=100.+273.;TEMFU=27.+273.;TEMOX=TEMFU
MESG( Enter required inlet stoichometry: default O2 excess
MESG( The options are:
MESG(  O2  - Excess oxygen supply
MESG(  ST  - Stoichometric supply
MESG(  FU  - Excess fuel supply
READVDU(CTUR,CHAR,O2)
CASE :CTUR: OF
WHEN O2,2
+ MESG(Excess Oxygen supply : Equivalence Ratio = 1.15
+ YCOIN=0.14844;YH2IN=0.01061;YOXIN=0.1951
+ ICASE=1
WHEN ST,2
+ MESG(Stoichometric supply : Equivalence Ratio = 1.0
+ YCOIN=0.16673;YH2IN=0.01191;YOXIN=0.19055
+ ICASE=2
WHEN FU,2
+ MESG(Excess Fuel supply   : Equivalence Ratio = 0.8
+ YCOIN=0.1995;YH2IN=0.01425;YOXIN=0.18241
+ ICASE=3
ENDCASE
YN2IN=1.-YCOIN-YH2IN-YOXIN
    GROUP 2.  Time-dependence and related parameters.
STEADY=T
CARTES=F;XULAST=0.1
    GROUP 3. X-direction grid specification
CARTES=F;XULAST=0.1
    GROUP 4. Y-direction grid specification
NREGY=4;NY=8
IREGY=1;GRDPWR(Y,2,0.0191,1.0);IREGY=2;GRDPWR(Y,2,0.0286,1.0)
IREGY=3;GRDPWR(Y,2,0.0548,1.0);IREGY=4;GRDPWR(Y,2,0.1048,1.0)
    GROUP 5. Z-direction grid specification
NREGZ=2;NZ=10
IREGZ=1;GRDPWR(Z,4,0.381,1.0);IREGZ=2;GRDPWR(Z,6,2.362,1.3)
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1);STORE(VIST,DEN1,TMP1,SPH1,YSUM)
SOLUTN(P1,P,P,Y,P,P,P);SOLUTN(V1,P,P,P,P,P,N)
SOLUTN(W1,P,P,P,P,P,N);TURMOD(KEMODL)
IF(HSOLV) THEN
+ SOLVE(H1);TERMS(H1,N,P,P,P,P,P)
+ SOLUTN(H1,P,P,Y,P,P,P)
ELSE
+ STORE(H1)
ENDIF
IF(THRAD) THEN
+ REAL(ABSORB,SCAT,SIGMA,EMPW,EMISW,EMISG,EMPG)
+ ABSORB=1.45;SCAT=0.; EMISG=0.07
+ SIGMA=5.6697E-8; EMISW=1.0
+ EMPW=SIGMA*TWAL**4; EMPG=SIGMA*EMISG
+ RADIAT(RADI,ABSORB,SCAT,H1)
+ SOLUTN(SRAD,P,P,Y,P,P,P);SOLUTN(H1,P,P,Y,P,P,P)
ENDIF
    GROUP 8. Terms (in differential equations) & devices
    GROUP 9.  Properties of the medium (or media).
ENUL=4.2E-5
  *** START OF EXTENDED SCRS MODEL SETTINGS
PRESS0=1.0000E+05
INTEGER(NSPEC,NELEM);NSPEC=7;NELEM=4
INTEGER(NCSTEP,NCREAC);NCSTEP=1;NCREAC=2
SCRS(SYSTEM,NCSTEP,NCREAC,NELEM,FRATE*)
SCRS(SPECIES,CH4,O2,H2,CO,H2O,CO2,N2)
STORE(S1RS,S2RS,MMWT)
   ** Define fuel & oxidiser composition & temperatures
SCRS(FUIN,0.0,YOXIN,YH2IN,YCOIN,0.0,0.0,YN2IN,TEMFU)
SCRS(OXIN,0.0,YOXIN,YH2IN,YCOIN,0.0,0.0,YN2IN,TEMOX)
SCRS(PROP,CHEMKIN,SCRS)
MESG(1 step 2 reactions finite-rate EBU model
MESG(2CO  +  O2 > 2CO2
MESG(2H2  +  O2 > 2H2O
  *** END OF EXTENDED SCRS MODEL SETTINGS
    GROUP 11. Initialization of variable or porosity fields
INIADD=F; FIINIT(W1)=WINO
KEINIT=((2.E-2*5.)**2)/2.; FIINIT(EP)=65.*(KEINIT**1.5)
IF(THRAD) THEN
+ REAL(TGUESS);TGUESS=300.
+ FIINIT(SRAD)=0.07*SIGMA*TGUESS**4
ENDIF
IF(HSOLV) THEN
+ FIINIT(H1)=-1.39E5
ENDIF
FIINIT(KE)=KEINIT; FIINIT(CO)=YCOIN; FIINIT(H2)=YH2IN
    GROUP 13. Boundary conditions and special sources
   * WALL boundary condition, name WALL3
PATCH(NWALL3,NWALL,1,NX,#NREGY,#NREGY,#2,NZ,#1,#NREGT)
COVAL(NWALL3,W1,GRND2,0.0);COVAL(NWALL3,V1,GRND2,0.0)
COVAL(NWALL3,KE,GRND2,GRND2);COVAL(NWALL3,EP,GRND2,GRND2)
 
IF(THRAD) THEN
+ PATCH(NWALL3R,NORTH,1,NX,#NREGY,#NREGY,1,NZ,#1,#NREGT)
+ COVAL(NWALL3R,SRAD,EMISW/(2.0-EMISW),EMPW)
ENDIF
   * INLET boundary condition for centre burner
KEL=0.5*(0.2*WINF)**2; EPL=1.643*((KEL)**1.5)/0.0095
INLET(SCRSF,LOW,1,NX,#2,#2,1,1,#1,#NREGT)
VALUE(SCRSF,P1,GRND1); VALUE(SCRSF,W1,WINF)
VALUE(SCRSF,EP,EPL); VALUE(SCRSF,KE,KEL)
VALUE(SCRSF,F,1.); VALUE(SCRSF,CO,YCOIN)
VALUE(SCRSF,H2,YH2IN)
IF(HSOLV) THEN
+ VALUE(SCRSF,H1,GRND3)
ENDIF
   * INLET boundary condition for outer burner
KEL=0.5*(0.2*WINO)**2; EPL=1.643*((KEL)**1.5)/0.05
INLET(SCRSO,LOW,1,NX,#4,#4,1,1,#1,#NREGT)
VALUE(SCRSO,P1,GRND1); VALUE(SCRSO,W1,WINO)
VALUE(SCRSO,EP,EPL); VALUE(SCRSO,KE,KEL)
VALUE(SCRSO,F,0.); VALUE(SCRSO,CO,YCOIN)
VALUE(SCRSO,H2,YH2IN)
IF(HSOLV) THEN
+ VALUE(SCRSO,H1,GRND3)
ENDIF
   * OUTLET boundary condition, name OUT
PATCH(OUT,HIGH,1,NX,1,NY,#NREGZ,#NREGZ,#1,#NREGT)
COVAL(OUT,P1,1.E2,0.);COVAL(OUT,F,ONLYMS,SAME)
IF(HSOLV) THEN
+ COVAL(OUT,H1,ONLYMS,SAME)
ENDIF
    GROUP 15. Termination of sweeps
LSWEEP=200
    GROUP 16. Termination of iterations
    GROUP 17. Under-relaxation devices
RELAX(P1,LINRLX,1.0); RELAX(V1,FALSDT,5.E-3)
RELAX(W1,FALSDT,5.E-3); RELAX(KE,FALSDT,5.E-3)
RELAX(EP,FALSDT,5.E-3); RELAX(DEN1,LINRLX,0.5)
RELAX(F,LINRLX,0.8)
RELAX(CO,FALSDT,2.E-3); RELAX(H2,FALSDT,2.E-3)
IF(HSOLV) THEN
+ RELAX(H1,FALSDT,1.0)
ENDIF
IF(THRAD) THEN
+ RELAX(SRAD,FALSDT,1.0)
ENDIF
    GROUP 18. Limits on variables or increments to them
VARMIN(TMP1)=1.E-10; VARMIN(DEN1)=1.E-10
OUTPUT(TMP1,P,P,P,P,Y,Y); OUTPUT(DEN1,P,P,P,P,Y,Y)
    GROUP 20. Preliminary print-out
ECHO=T
    GROUP 21. Print-out of variables
    GROUP 22. Spot-value print-out
IXMON=1;IYMON=NY/2;IZMON=6
    GROUP 23. Field print-out and plot control
IXMON=1;IYMON=NY/2;IZMON=6
TSTSWP=-1;ITABL=3;NPLT=1
    GROUP 24. Dumps for restarts