**  CHEMKIN - 2D Thermal Diffusion Demo. YZ-plane
 
  DISPLAY
    A simple case to demonstrate the effect of thermal
    diffusion on the fields of H2 (in C1) and N2 (in C2).
    The when the temperature gradients are positive, the
    thermal diffusion acts against the bulk mass-flux and
    acts to establish a negative gradient in H2 in the
    cross-flow direction. When the temperature gradient
    is reversed, the thermal diffusion acts with the bulk
    mass-flux causing the overall values of H2 to be smaller
    and a positive gradient to be established in the cross-
    flow direction.
  ENDDISPLAY
 
  PHOTON USE
  p
  phi
 
 
 
 
  view x
  norm
  gr ou x 1
  msg Contours of the temperature
  cont tem1 x 1 fil;.001
  msg
  msg Press  to continue
  pause
  gr ou x 1
  msg Contours of the light species (H2)
  cont h2 x 1 fil;.001
  msg
  msg Press  to continue
  pause
  msg
  msg Press e to END
  enduse
 
    GROUP 1. Run title and other preliminaries
TEXT(Thermal Diffusion Demo.: YZ-plane
TITLE
    GROUP 5. Z-direction grid specification
NZ=5
GRDPWR(Z,NZ,1.,1.)
    GROUP 4. Y-direction grid specification
NY=5
GRDPWR(Y,NY,1.,1.)
    GROUP 7. Variables stored, solved & named
SOLVE(P1,W1,V1,C1,C2)
SOLUTN(P1,P,P,Y,P,P,P)
SOLUTN(C1,P,P,Y,P,P,P)
STORE(TEM1,ELH)
    GROUP 9. Properties of the medium (or media)
PRNDTL(C1)=-GRND9;PRNDTL(C2)=-GRND9
    GROUP 11. Initialization of variable or porosity fields
TEMP0=300.
INIADD=T;INIFLD=T
FIINIT(C1)=0.5; FIINIT(C2)=0.5
REAL(TAT1,TATNX);TAT1=0.;TATNX=TAT1+100.
PATCH(WHOLEZ,LINVLZ,1,NX,1,NY,1,NZ,1,LSTEP)
INIT(WHOLEZ,TEM1,TATNX-TAT1,TAT1)
PATCH(WHOLEY,LINVLY,1,NX,1,NY,1,NZ,1,LSTEP)
INIT(WHOLEY,TEM1,TATNX-TAT1,TAT1)
    GROUP 13. Boundary conditions and special sources
INLET(IN1,LOW,1,NX,1,NY,1,1,1,LSTEP)
VALUE(IN1,P1,0.5); VALUE(IN1,W1,0.5)
OUTLET(OUT1,HIGH,1,NX,1,NY,NZ,NZ,1,LSTEP)
PATCH(H2SO,CELL,1,NX,1,NY,NZ,NZ,1,LSTEP)
COVAL(H2SO,C1,FIXFLU,0.002)
    GROUP 15. Termination of sweeps
LSWEEP=80
    GROUP 16. Termination of iterations
LITER(C1)=20
    GROUP 19. Data communicated by satellite to GROUND
LSG61=T
ENULA=GRND9
ENULB=GRND9
CHSOC=1.
CSG4='tdif'
    GROUP 21. Print-out of variables
NXPRIN=1;NYPRIN=1;NZPRIN=1
    GROUP 22. Spot-value print-out
IZMON=NZ/2+1;IYMON=NY/2+1
    GROUP 24. Dumps for restarts
TSTSWP=-1