DISPLAY
   This simple CHEMKIN test problem concerns the 1d flow of H2 into
   a duct and its subsequent dissociation into H. For demonstration
   purposes, species diffusion is absent and the calculation is
   performed at a constant temperature of 300K. The operating
   pressure is 1 atmosphere. As with all CHEMKIN calculations, cgs
   units are used. A linear reaction rate is defined for H2=>2H in
   the file REAC.CKM, i.e. SH2=-WH2*Kf*XH2 and SH=+WH*2.*Kf*XH2
   where: Kf=10.0 s^-1, Wk is the molecular mass of species k, and
   Xk is the molar concentration of species k in mol/cm^3. Note
   Xk=RHO*Yk/Wk where RHO is the mixture density in g/cm^3 and Yk is
   the mass fraction of species k. The run is set up so that the
   default calculation is performed with the CHEMKIN TWOPNT point-
   by-point (PBP) solver, although for testing purposes the option
   exists to select the PHOENICS PBP solver.
  ENDDIS
    GROUP 1. Run title and other preliminaries
TEXT(1DX Simple H2=>2H Reaction Test Case
TITLE
BOOLEAN(TWOPNT);CHAR(CHSO)
MESG( Enter required method of solution for chemistry
MESG( Default: CHEMKIN Point-by-Point solver
MESG( The alternative is:
MESG(  Enter PBP for PHOENICS Point-by-Point solver
READVDU(CHSO,CHAR,CHS)
CASE :CHSO: OF
WHEN PBP,3
+ TWOPNT=F
+ MESG(PHOENICS Point-by-point Solver
WHEN CHS,3
+ TWOPNT=T
+ MESG(CHEMKIN Point-by-Point Solver
ENDCASE
    GROUP 3. X-direction grid specification
GRDPWR(X,10,1.,1.)
    GROUP 7. Variables stored, solved & named
  ** The mass fraction of N2 is zero, but it is present so that
     both H and H2 may solved in order to test the correctness
     of the CHEMKIN implementation.
SOLVE(P1,U1)
CHEMKIN(SPECIES,H2,H,N2);STORE(DEN1,ELH,ELN)
    GROUP 8. Terms (in differential equations) & devices
  ** Diffusion terms removed from mass-fraction equations
TERMS(H2,P,P,N,P,P,P);TERMS(H,P,P,N,P,P,P)
    GROUP 9. Properties of the medium (or media)
RHO1=CHEMIST
    GROUP 11. Initialization of variable or porosity fields
  ** Specify uniform temperature field
TEMP0=300.
INIADD=F; FIINIT(H2)=1.0; FIINIT(H)=0.0; FIINIT(N2)=0.
FIINIT(U1)=1.0
    GROUP 13. Boundary conditions and special sources
  ** mass inflow of H2
INLET(NOCPCKIN,WEST,1,1,1,NY,1,NZ,1,LSTEP)
VALUE(NOCPCKIN,U1,1.0); VALUE(NOCPCKIN,P1,GRND9)
VALUE(NOCPCKIN,H2,1.0)
OUTLET(OUTFLOW,EAST,NX,NX,1,NY,1,NZ,1,LSTEP)
  ** Reaction-rate source terms using PHOENICS solver
IF(TWOPNT) THEN
+ CHSOA=GRND9
ELSE
+ PATCH(CHEMK1,VOLUME,1,NX,1,NY,1,NZ,1,LSTEP)
+ COVAL(CHEMK1,H2,GRND9,GRND9);COVAL(CHEMK1,H,GRND9,GRND9)
ENDIF
    GROUP 15. Termination of sweeps
ENDIT(H2)=1.E-10; ENDIT(H)=1.E-10
    GROUP 19. Data communicated by satellite to GROUND
  ** reference pressure in atmospheres
CHSOC=1.
  ** CSG4 identifies the CHEMKIN link file: reacckln; and the
     transport-properties link file: reacmcln.
CSG4='reac'
  ** The link files reacckln & reacmcln were created from the
     mechanism link file REAC.CKM, which has the form:
        ELEMENTS H N END
     SPECIES H2 H N2 END
     REACTIONS
     H2 => 2H                  10. 0. 0.
     END
  **
  ** The link files reacckln, reacmcln & reac.ckm reside in the
     directory: d_earth\d_opt\d_chem.
IF(TWOPNT) THEN
+ LSWEEP=15;NPLT=3
+ CHEMKIN(RELAX,1.0); RESREF(P1)=1.E-3; RESREF(U1)=1.E-4
+ RESREF(H2)=-1.E-3; RESREF(H)=-1.E-3
ELSE
+ LSWEEP=60;NPLT=5
+ CHEMKIN(RELAX,1.0);SELREF=T; RESFAC=1.E-6
ENDIF
    GROUP 21. Print-out of variables
NXPRIN=1;NYPRIN=1;NZPRIN=1
OUTPUT(N2,P,P,P,N,N,N)
    GROUP 22. Spot-value print-out
ITABL=3;IXMON=NX-1;TSTSWP=-1
    GROUP 24. Dumps for restarts
  
  **Instruct CHEMKIN Interface that the temperature is constant
    everywhere
SPEDAT(SET,CHEM,CONTEM,L,T)