PHOTON USE
  p
 
 
 
 
  gr ou y 1
  MSG Velocity vectors
  vec y 1 sh
  msg
  msg Press return to plot pressure contours
  pause
  cont p1 y 1 fil;.01
  msg
  msg Type e to End
  ENDUSE
 
    GROUP 1. Run title
TEXT(SUPERSONIC FLOW THRU WEDGE CASCADE: B523
TITLE
 
  DISPLAY
   The flow considered is supersonic flow through a cascade of
  wedges with inlet Mach number 3.0 and completely supersonic
  flow. A leading-edge shock reflects off the pressure surface
  and should be exactly cancelled at the upstream corner giving
  a uniform parallel flow through the two surfaces. The flow
  then expands off the downstream corner and exits through the
  blade row where two compression waves are formed at the trailing
  edge. Cyclic boundary conditions are applied upstream and
  downstream of the cascade. The geometry is as follows:
 
                                 wall
      //////////////////////////////////////////////////////
      ------------------------------------------------------
 
                              --------->                    zero
      --->                    --------->              ---> pressure
                         ____________________
                       .'////////////////////`.
      --->           .'|        wall          -`.     --->
                   .'| wall                wall -`.
      ___________.'|                              -`._______
      ///////////                                    ///////
    ^    wall                                          wall
   x|
    |--->
      z
CHAR(ANSW)
mesg(Press return to continue
readvdu(answ,char,y)
 
    For simplicity, the flow is treated as isentropic. However,
  shock theory indicates that there is a significant entropy
  change across the shocks for the given approach Mach number
  and wedge angle. Therefore, in future work the isentropic
  treatment will be replaced with one which allows for entropy
  changes across shock fronts.
   The exit boundary condition is one of fixed pressure according
  to the post-expansion pressure calculated from gas-dynamic
  theory; this neglects the presence of trailing-edge shocks.
  Strictly, the flow is hyperbolic and so the exit boundary
  condition   should be modified accordingly.
  The system of units used are the same as those used in case 522.
  ENDDIS
REAL(GASCON,GAMMA,PTOTAL,TTOTAL,RHOTOT,MACHI,PEXRAT,AGAM1,RGAM)
REAL(PIN,TIN,POWER,WIN,RHOIN,PEXIT,CHORD)
REAL(ANGLE1,GZLE,GZBACK,GZFCOR,GZSCOR,GZTE)
INTEGER(IZLE,IZTE,KASE)
GASCON=1.0;GAMMA=1.4;PTOTAL=1.0;TTOTAL=1.0;RHOTOT=1.0;MACHI=3.0
CHORD=4.0;PEXRAT=0.0377
IZLE=4;IZTE=24;ANGLE1=18.5;GZLE=0.8;GZTE=GZLE+CHORD;GZBACK=0.8
GZFCOR=GZLE+2.0;GZSCOR=GZLE+3.0
KASE=2
   ** Calculation of inlet velocity
AGAM1=GAMMA-1.; RGAM=1./GAMMA;POWER=GAMMA/AGAM1
PIN=PTOTAL/(1.+AGAM1*MACHI*MACHI/2.)**POWER
RHOIN=RHOTOT/(PTOTAL/PIN)**RGAM
WIN=MACHI*(GAMMA*PIN/RHOIN)**0.5
   ** Calculation of Inlet Temperature
TIN=PIN/(GASCON*RHOIN)
   ** Calculation of exit pressure
PEXIT=PEXRAT*PTOTAL
    GROUP 6. Body-fitted coordinates or grid distortion
BFC=T;NONORT=T
GSET(D,10,1,28,1.0,1.0,5.6)
INTEGER(K1,K2,K3,K4);K1=5;K2=15;K3=20;K4=25
   ** Centre portion
GSET(C,I1,F,I:NX+1:,1,NY,K2,K3-1,+,-0.3308,0.0,0.0,INC,1.0)
   ** Front Ramp
GSET(T,K:K2:,F,K:K1:,1.0)
   ** Rear Ramp
GSET(T,K:K4:,F,K:K3:,1.0)
    GROUP 7. Variables stored, solved & named
SOLVE(P1,U1,W1);STORE(RHO1)
SOLUTN(P1,Y,Y,Y,N,N,N)
    GROUP 9. Properties of the medium (or media)
ENUL=0.0;ENUT=0.0
   ** Use Isentropic Density Law
RHO1=COMPRESS; RHO1A=RHOTOT/PTOTAL**RGAM; RHO1B=RGAM
RHO1C=0.;PRESS0=0.;DRH1DP=COMPRESS
    GROUP 11. Initialization of variable or porosity fields
FIINIT(P1)=PIN;FIINIT(W1)=WIN;FIINIT(RHO1)=RHOIN
    GROUP 13. Boundary conditions and special sources
INLET(INLET,LOW,1,NX,1,1,1,1,1,1)
VALUE(INLET,P1,RHOIN*WIN)
VALUE(INLET,W1,WIN)
PATCH(OUTLET,HIGH,1,NX,1,1,NZ,NZ,1,1)
COVAL(OUTLET,P1,5.E4,PEXIT)
COVAL(OUTLET,U1,ONLYMS,0.0);COVAL(OUTLET,W1,ONLYMS,0.0)
   ** Cyclic boundary upstream and downstream of cascade.
XCYIZ(1,K1-1,T);XCYIZ(K4,NZ,T)
    GROUP 15. Termination of sweeps
LSWEEP=100
    GROUP 16. Termination of iterations
LITER(P1)=15
    GROUP 17. Under-relaxation devices
RELAX(P1,LINRLX,0.8); RELAX(RHO1,LINRLX,1.0)
RELAX(U1,FALSDT,0.5); RELAX(W1,FALSDT,0.5)
    GROUP 18. Limits on variables or increments to them
VARMIN(U1)=-50.;VARMIN(W1)=-50.;VARMAX(U1)=50.;VARMAX(W1)=50.
VARMIN(RHO1)=0.1*RHOIN;VARMAX(RHO1)=RHOTOT
VARMIN(P1)=0.01*PIN;VARMAX(P1)=PTOTAL
    GROUP 22. Spot-value print-out
IXMON=2;IZMON=9;NPRMON=LSWEEP
SELREF=T; RESFAC=0.01
    GROUP 23. Field print-out and plot control
NPRINT=LSWEEP;TSTSWP=-1
PATCH(PLOT1,PROFIL,NX/2,NX/2,1,1,1,NZ,1,1)
PLOT(PLOT1,P1,0.0,0.0)
PATCH(CASCADE,CONTUR,1,NX,1,1,1,NZ,1,1)
PLOT(CASCADE,P1,0.0,20.0);PLOT(CASCADE,W1,0.0,20.0)