PHOTON USE
  p
  phi
 
 
 
  msg         CONJUGATE HEAT TRANSFER IN A CURVED DUCT
  msg
  cl
  set ref vec 2
  msg   Velocity vectors:
  gr ou x 1;vec x 1 sh
  con blok x 1;int 1
  msg
  msg Press  to continue
  pause
  con off;red
  msg        Temperature distribution:
  con tem1 x 1 fi;.001
  con blok x 1;int 1
  msg            -
  msg Press  to continue
  pause
  con off;red
  msg        Streamlines:
  str 2d x 1 sh;int 30
  con blok x 1;int 1
  msg
  msg Press e to END
  enduse
 
    GROUP 1. Run title
TEXT(CONJ.HEAT TRANS.IN A CURVED DUCT: B459
TITLE
mesg(PC486/50 time last reported as 1.5 min
  DISPLAY
    This case deals with conjugate heat transfer between a metal
    solid which stands in the middle of a curved 2-D duct, and a
    cold air stream which flows through the duct,passing the
    'obstacle'. The geometry is represented by means of body-fitted
    coordinates
  ENDDIS
    GROUP 4. Y-direction grid specification
NY=10;YVLAST=.05
    GROUP 5. Z-direction grid specification
NZ=10;ZWLAST=.20
    GROUP 6. Body-fitted coordinates or grid distortion
REAL(PI,YY0,ZZ0,ARC)
PI=3.14159;ARC=PI/3.
YY0=0.05*(3.0)**0.5
ZZ0=0.05
BFC=T
DOMAIN(1,2,1,1,1,NZ+1)
SETLIN(YC,.1*SIN(ARC+ARC*LNK)-YY0)
SETLIN(ZC,ZZ0-.1*COS(ARC+ARC*LNK))
DOMAIN(1,2,NY+1,NY+1,1,NZ+1)
SETLIN(YC,.15*SIN(ARC+ARC*LNK)-YY0)
SETLIN(ZC,ZZ0-.15*COS(ARC+ARC*LNK))
DOMAIN(1,2,1,NY+1,1,1)
SETLIN(YC,LNJ*(YL-YF)+YF)
SETLIN(ZC,LNJ*(ZL-ZF)+ZF)
DOMAIN(1,2,1,NY+1,NZ+1,NZ+1)
SETLIN(YC,LNJ*(YL-YF)+YF)
SETLIN(ZC,LNJ*(ZL-ZF)+ZF)
DOMAIN(1,NX+1,1,NY+1,1,NZ+1)
MAGIC(T)
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,TEM1)
SOLUTN(P1,Y,Y,Y,N,N,N)
SOLUTN(TEM1,Y,Y,Y,N,N,Y)
STORE(PRPS,BLOK,DEN1,VISL,VCRT,WCRT)
    GROUP 8. Terms (in differential equations) & devices
    STOVAR puts the index number for TEM1 which has been
    assigned by the Satellite into the variable IVARBK
STOVAR(TEM1,IVARBK);ISOLBK=1
TERMS(TEM1,N,Y,Y,Y,P,P)
    GROUP 9. Properties of the medium (or media)
;ENUL=FILE;PRNDTL(TEM1)=CONDFILE
    GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=1.0;FIINIT(PRPS)=0.0;FIINIT(BLOK)=1.0
PATCH(SOLID,INIVAL,1,1,5,6,4,5,1,1)
   material 103 is copper
COVAL(SOLID,PRPS,0.0,103)
COVAL(SOLID,BLOK,0.0,2.0)
COVAL(SOLID,TEM1,0.0,5.0)
CONPOR(SOLID,-1,CELL,1,1,-5,-6,-4,-5)
    GROUP 13. Boundary conditions and special sources
INLET(INLET,LOW,1,NX,1,NY,1,1,1,1)
VALUE(INLET,P1  ,1.29)
VALUE(INLET,W1  ,1.00)
VALUE(INLET,TEM1,5.00)
PATCH(HOTHOT,CELL,1,NX,5,6,4,5,1,1)
COVAL(HOTHOT,TEM1,FIXFLU,10.0)
PATCH(OUTLET,HIGH,1,NX,1,NY,NZ,NZ,1,1)
COVAL(OUTLET,P1,1.0E5,0.0)
WALL (WALL1,NORTH,1,NX,NY,NY,1,NZ,1,1)
COVAL(WALL1,W1,1.0,0.0)
WALL (WALL2,SOUTH,1,NX, 1, 1,1,NZ,1,1)
COVAL(WALL2,W1,1.0,0.0)
    GROUP 15. Termination of sweeps
LSWEEP=50; LITER(TEM1)=100
RELAX(P1,LINRLX,0.7)
RELAX(V1,FALSDT,0.01)
RELAX(W1,FALSDT,0.01)
    GROUP 22. Spot-value print-out
IYMON=6;IZMON=5;IZMON=6
selref=t;resfac=1.e-2
    GROUP 23. Field print-out and plot control
TSTSWP=-1