GROUP 1. Run title and other preliminaries
TEXT(2D 2-PHASE BUBBLE-STIRRED GAS LADLE
TITLE
  DISPLAY
    The case considered is 2-phase turbulent air-water flow in the
    bubble-stirred ladle described by Johansen et al ( Metall.
    Trans. B, Vol.19B, p755, 1988 ). The ladle is 1.237m high and
    1.016m in diameter. Air is supplied through a centrally located
    0.05m diameter plug at a flow rate of Q=610cm**3/s. The bubble
    diameter is taken as 0.25{0.35*(Q**2/g)**0.2}, and air is
    allowed to leave through the free surface at the top of the
    ladle. The calculation is performed with the k-e model, with the
    option to use of of two alternative modifications for bubble-
    induced turbulence production. The interphase drag is calculated
    by using the 'dirty-water' bubble-drag correlation of Kuo and
    Wallis, and virtual-mass, lift and interfacial pressure effects
    are neglected. The task is to calculate liquid-phase vertical
    velocity profiles at various heights for comparison with the
    measured profiles.
  ENDDIS
REAL(DIAMA,DIAMC,RADA,RADC,ZLENT,PI,GRAVAC,DTT,STEN,AREA)
REAL(DIAMB,DTF,QGAS,FLOWG,VSLIPM,EMULIQ,RGAS,RLIQ,RGINIT)
REAL(WGAS,TKEIN,EPIN);INTEGER(KMOD)
DIAMC=1.016;RADC=0.5*DIAMC;ZLENT=1.237;RGAS=1.E-3;RLIQ=1.-RGAS
PI=3.14159;GRAVAC=-9.81;EMULIQ=1.E-3;RGINIT=1.E-4;STEN=0.072
DIAMA=0.05;RADA=0.5*DIAMA;QGAS=6.1E-4;AREA=PI*RADA*RADA
WGAS=QGAS/AREA;DIAMB=0.25*0.35*(-QGAS*QGAS/GRAVAC)**0.2
TKEIN=(0.1*WGAS)**2;EPIN=0.1643*TKEIN**1.5/(0.1*RADA)
    GROUP 2. Transience; time-step specification
    GROUP 3. X-direction grid specification
CARTES=F;XULAST=0.1;AREA=XULAST*0.5*RADC*RADC
    GROUP 4. Y-direction grid specification
NREGY=2
IREGY=1;GRDPWR(Y,4,RADA,1.0)
IREGY=2;GRDPWR(Y,-16,RADC-RADA,1.5)
    GROUP 5. Z-direction grid specification
NZ=30;GRDPWR(Z,-NZ,ZLENT,1.4)
    GROUP 6. Body-fitted coordinates or grid distortion
    GROUP 7. Variables stored, solved & named
ONEPHS=F;SOLVE(P1,V1,V2,W1,W2,R1,R2)
SOLUTN(P1,Y,Y,Y,P,P,P);TURMOD(KEMODL)
  ** deactivate harmonic averaging
SOLUTN(V1,P,P,P,P,P,N);SOLUTN(V2,P,P,P,P,P,N)
SOLUTN(W1,P,P,P,P,P,N);SOLUTN(W2,P,P,P,P,P,N)
SOLUTN(R1,P,P,P,P,P,N);SOLUTN(R2,P,P,P,P,P,N)
STORE(VREL,CFIP,ENUT,LEN1,CD,REYN,PRKB)
    GROUP 8. Terms (in differential equations) & devices
DIFCUT=0.5
    GROUP 9. Properties of the medium (or media)
RHO1=1.E3;RHO2=1.21;ENUL=EMULIQ/RHO1
    GROUP 10. Inter-phase-transfer processes and properties
CFIPS=GRND7;CFIPD=5.0;VSLIPM=1.E-4;CFIPA=VSLIPM;CFIPB=DIAMB
CFIPC=STEN;RLOLIM=1.E-3
    GROUP 11. Initialization of variable or porosity fields
FIINIT(R1)=RLIQ;FIINIT(R2)=RGAS;FIINIT(W1)=1.E-3
FIINIT(W2)=1.E-3;FIINIT(KE)=TKEIN;FIINIT(EP)=EPIN
    GROUP 12. Patchwise adjustment of terms
    GROUP 13. Boundary conditions and special sources
   KEY: $ 1st cell in a region     % Last cell in a region
        # all cells in that region
  ** Gas-phase mass-inflow boundary
FLOWG=RHO2*WGAS
PATCH(IN,LOW,1,NX,#1,#1,1,1,1,LSTEP)
COVAL(IN,P2,FIXFLU,FLOWG);COVAL(IN,W2,ONLYMS,WGAS)
  ** Gas-phase outflow boundary
PATCH(OUTG,HIGH,1,NX,1,NY,NZ,NZ,1,LSTEP)
COVAL(OUTG,P2,RHO2*1.E6,0.0)
  ** Liquid-phase 'pressure-relief' outflow cell
PATCH(OUTL,HIGH,1,NX,NY,NY,NZ,NZ,1,LSTEP)
COVAL(OUTL,P1,RHO1,0.0)
  ** Gravititional force relative to liquid phase
PATCH(GRAVITY,PHASEM,1,NX,1,NY,1,NZ,1,LSTEP)
COVAL(GRAVITY,W2,FIXFLU,GRAVAC*(1.-RHO1/RHO2))
  ** Wall friction
WALL(NWALL,NORTH,1,NX,NY,NY,1,NZ,1,LSTEP)
MESG( Enter the required k-e modification option:
MESG(  1  - No modifications (default)
MESG(  2  - Additional KE & EP sources due to bubbles ( these
MESG(       sources should be activated only after the solution
MESG(       fields have evolved, say after 800 sweeps ).
MESG(  3  - Enhanced ENUT due to bubbles
MESG(
READVDU(KMOD,INT,1)
KELIN=1
IF(KMOD.EQ.2) THEN
+ MESG(  KE & EP bubble-induced turbulence sources active.
+ PATCH(KEDI,CELL,1,NX,1,NY,1,NZ,1,LSTEP);EL1A=0.01
+ COVAL(KEDI,KE,FIXFLU,GRND3);COVAL(KEDI,EP,FIXFLU,GRND3)
+ TEXT(BUBBLE-STIRRED GAS LADLE- KE & EP sources
ENDIF
IF(KMOD.EQ.3) THEN
+ MESG(  ENUT enhancement due to bubbles is active
+ ENUTB=1.0;ENUTC=0.3;KELIN=3
+ TEXT(BUBBLE-STIRRED GAS LADLE- Enhanced ENUT
ENDIF
    GROUP 15. Termination of sweeps
  ** The calculation requires 3500 sweeps for convergence.
LSWEEP=3500;TSTSWP=-10
    GROUP 16. Termination of iterations
SELREF=T;RESFAC=0.01
    GROUP 17. Under-relaxation devices
DTF=0.3*ZWLAST/WGAS/NZ
RELAX(P1,LINRLX,0.5)
RELAX(V1,FALSDT,DTF);RELAX(V2,FALSDT,DTF)
RELAX(W1,FALSDT,DTF);RELAX(W2,FALSDT,DTF)
RELAX(R1,LINRLX,0.3);RELAX(R2,LINRLX,0.3)
RELAX(CFIP,LINRLX,0.3);KELIN=3
RELAX(KE,LINRLX,0.2);RELAX(EP,LINRLX,0.2)
    GROUP 18. Limits on variables or increments to them
VARMIN(R1)=1.E-8;VARMIN(R2)=1.E-8
    GROUP 19. Data communicated by satellite to GROUND
    GROUP 20. Preliminary print-out
    GROUP 21. Print-out of variables
OUTPUT(CD,Y,N,N,N,N,N);OUTPUT(REYN,N,N,N,N,N,N)
OUTPUT(CFIP,Y,N,N,N,N,N);OUTPUT(LEN1,N,N,N,N,N,N)
    GROUP 22. Spot-value print-out
IYMON=2;IZMON=28;WALPRN=T
    GROUP 23. Field print-out and plot control
NPRINT=LSWEEP;NZPRIN=1;NYPRIN=1;NPLT=50