TEXT(1D VERTICAL PNEUMATIC CONVEYING
TITLE
DISPLAY
The problem considered is 1D vertical pneumatic conveying of
solid particles in a pipe, as considered experimentally by
Hariu and Molstad ( Ind.Eng.Chem, Vol.41,No.6, pp1148,1949 ).
The solids mass inflow rate is 2.39g/s and the inlet gas
superficial velocity is 5.2m/s. The pipe diameter is 13.5mm and
the height of the riser is 1.368m. The particles are 503 microns
in diameter and the solids density is 2643kg/m**3. The inlet
solids volume fraction is estimated from the measured solids
holdup of 0.0256g. The calculations employ the built-in particle-
fluidisation drag model (CFIPD=7.), which for these void
fractions ( i.e. > 0.8 ) uses a modified spherical-particle drag
correlation suitable for pneumatic conveying.
The task is to predict the gas and solids velocities, the voidage,
the pressure drop and the solids hold-up. The PHOENICS predictions
show fairly good agreement with the experimental data, as follows:
pressure drop ( PHOENICS = 217 N/m**2 Data = 200 N/m**2 );
solids hold-up ( PHOENICS = 2.36g Data = 2.56g ).
ENDDIS
The solids holdup is calculated by summing the total mass of
solids in the riser; this is achieved from the Q1 by solving for
C2 and then introducing a PHASEM patch named HOLDUP for which
CO=FIXFLU & VAL=1.0. The net-source printout near the end of the
RESULT file will then print the solids holdup in kg.
* CFIPD=7. selects the particle-fluidisation drag correlation
REAL(CD,REYD,XLEN,UING,UINP,REYP,DIAMP,AREAD,MSOLID,FRIC)
REAL(DIAMD,PI,UTERM,RING,RINP,FLOWG,FLOWP,dens,RHOG,DELRHO)
XLEN=1.368;RHOG=1.23;dens=2643.0;PI=3.14159;DIAMD=0.0135;
FLOWP=2.39E-3;UING=5.2;DELRHO=dens-RHOG;DIAMP=503.E-6
ENULA=1.8E-5/RHOG;AREAD=PI*DIAMD*DIAMD/4.
** estimate terminal velocity of particles
REYP=UING*DIAMP/ENULA
CD=24.*(1.+.15*REYP**.687)/REYP+.42/(1.+4.25E4/(REYP**1.16))
UTERM=(4.*9.81*DELRHO*DIAMP/(3.*RHOG*CD))**0.5
uterm
** estimate inlet solids volume fraction from
experimental value of solids holdup, MSOLID
MSOLID=2.56E-3;RINP=MSOLID/(dens*AREAD*XLEN)
** estimate inlet solids velocity and then gas inlet
velocity and volume fraction
UINP=FLOWP/(dens*AREAD*RINP);RING=1.-RINP;UING=UING/RING
FLOWG=RHOG*RING*UING*AREAD
GROUP 1. Run title and other preliminaries
GROUP 2. Transience; time-step specification
GROUP 3. X-direction grid specification
YVLAST=AREAD;GRDPWR(X,20,XLEN,1.0)
GROUP 4. Y-direction grid specification
GROUP 5. Z-direction grid specification
GROUP 6. Body-fitted coordinates or grid distortion
GROUP 7. Variables stored, solved & named
** C2 solved merely to avoid introducing ground coding
to calculate solids holdup
ONEPHS=F;SOLVE(P1,U1,U2,R1,R2,C2)
Activate storage for printout of interphase drag properties
STORE(REYN,VREL,CFIP,SIZE)
GROUP 8. Terms (in differential equations) & devices
GROUP 9. Properties of the medium (or media)
RHO1=RHOG;RHO2=dens;ENUL=ENULA
GROUP 10. Inter-phase-transfer processes and properties
CFIPS=GRND7;VARMIN(R2)=1.E-10
** CFIPA = minimum slip velocity CFIPB = particle size
CFIPA=1.E-4;CFIPB=DIAMP;CFIPD=7.
GROUP 11. Initialization of variable or porosity fields
FIINIT(U1)=UING;FIINIT(U2)=UINP;FIINIT(R2)=RINP;FIINIT(R1)=RING
GROUP 12. Unused
GROUP 13. Boundary conditions and special sources
INLET(IN,CELL,$1,$1,$1,$1,$1,$1,1,1)
VALUE(IN,P1,FLOWG);VALUE(IN,U1,UING)
VALUE(IN,P2,FLOWP);VALUE(IN,U2,UINP)
OUTLET(OUT,CELL,%1,%1,%1,%1,%1,%1,1,1)
** use expected outflow velocities to allow for slip
in the exit-cell outflow
COVAL(OUT,P1,RHO1*UING*1.E2,0)
COVAL(OUT,P2,RHO2*UINP*1.E2,0)
REYD=UING*DIAMD/ENULA;FRIC=0.316/REYD**0.25
** gas-phase wall friction
PATCH(GFRIC,VOLUME,1,NX,1,NY,1,NZ,1,1)
COVAL(GFRIC,U1,-0.5*RHO1*FRIC/DIAMD,0.0)
** gravity force
PATCH(GRAVITY,PHASEM,1,NX,1,NY,1,NZ,1,1)
COVAL(GRAVITY,U2,FIXFLU,-9.81*(1.-RHOG/dens))
** introduce C2 patch which will compute solids holdup
and print in RESULT file in net-source printout
PATCH(HOLDUP,PHASEM,1,NX,1,NY,1,NZ,1,1)
COVAL(HOLDUP,C2,FIXFLU,1.0)
GROUP 15. Termination of sweeps
LSWEEP=100
RESREF(P1)=1.E-12*(FLOWG+FLOWP)
RESREF(R1)=1.E-12*FLOWG;RESREF(R2)=1.E-12*FLOWP
RESREF(U1)=RESREF(R1)*UING;RESREF(U2)=RESREF(R2)*UINP
GROUP 16. Termination of iterations
GROUP 17. Under-relaxation devices
REAL(DTF);DTF=XLEN/UING/NX
RELAX(R1,LINRLX,0.5);RELAX(R2,LINRLX,0.5)
RELAX(U1,FALSDT,DTF);RELAX(U2,FALSDT,DTF)
GROUP 18. Limits on variables or increments to them
GROUP 19. Data communicated by satellite to GROUND
GROUP 20. Preliminary print-out
GROUP 21. Print-out of variables
OUTPUT(C2,N,N,N,N,N,N)
OUTPUT(CFIP,P,P,P,P,Y,P);NXPRIN=1;NYPRIN=1;NZPRIN=1
GROUP 22. Spot-value print-out
IXMON=NX/2;TSTSWP=-1
GROUP 23. Field print-out and plot control
GROUP 24. Dumps for restarts