Testing k-e model when solving for Temperature (TEM1).
 
    GROUP 1. Run title and other preliminaries
TEXT(HotBox N-W Aper N-S Grav XY-Plane 
TITLE
    GROUPS 3. & 4. X & Y-direction grid specification.
GRDPWR(X,8,0.8,1.0); GRDPWR(Y,10,1.0,1.0)
    GROUP 7. Variables stored, solved & named
#solvel
#soltem
STORE(BLOK)
    STOVAR puts the index number for TEM1 which has been assigned by
    the Satellite into the variable IVARBK
STOVAR(TEM1,IVARBK); ISOLBK=1
    GROUP 8. Terms (in differential equations) & devices
ISOLX=0; ISOLY=0
    GROUP 9. Properties of the medium (or media)
#use_props
TURMOD(KEMODL); IENUTA=6;ENUTA=0.01;ENUTB=4.
    GROUP 11. Initialization of variable or porosity fields
INIADD=F; FIINIT(TEM1)=10.0;:fluid:=air20; FIINIT(BLOK)=1.0
PATCH(SOLID,INIVAL,NX/2,NX/2+1,NY/2-1,NY/2,1,1,1,LSTEP)
    Material 111 is steel
INIT(SOLID,PRPS,0.0,steel)
CONPOR(SOLID,-1.0,CELL,-(NX/2),-(NX/2+1),-(NY/2-1),-(NY/2),-1,-1)
COVAL(SOLID,BLOK,0.0,2.0)
    GROUP 13. Boundary conditions and special sources
PATCH(APT1,WEST,1,1,1,NY/5,1,1,1,LSTEP)
COVAL(APT1,P1,FIXP,0.); COVAL(APT1,TEM1,ONLYMS,10)
 
PATCH(APT2,NORTH,3*NX/4+1,NX,NY,NY,1,1,1,LSTEP)
COVAL(APT2,P1,FIXP,0.); COVAL(APT2,TEM1,ONLYMS,10)
 
PATCH(HOTBLOCK,VOLUME,NX/2,NX/2+1,NY/2-1,NY/2,1,1,1,LSTEP)
COVAL(HOTBLOCK,TEM1,FIXFLU,1.250E+02)
 
#gravity
gravdir=1; Tref=0.0
#bouss
 
    GROUP 15. Termination of sweeps
LSWEEP=30
    GROUP 16. Termination of iterations
LITER(TEM1)=15
    GROUP 17. Under-relaxation devices
RELAX(U1,FALSDT,5.0); RELAX(V1,FALSDT,5.0); RELAX(TEM1,FALSDT,1.0E6)
RELAX(KE,FALSDT,0.1); RELAX(EP,FALSDT,0.1)
    GROUP 19. Data communicated by satellite to GROUND
USEGRD=F
    GROUP 21. Print-out of variables
OUTPUT(BLOK,N,N,N,N,N,N)
    GROUP 22. Spot-value print-out
IXMON=NX/2; IYMON=NY/2+1
    GROUP 23. Field print-out and plot control
ITABL=3; NPLT=1
PATCH(MAP,CONTUR,1,NX,1,NY,1,1,1,1)
PLOT(MAP,U1,0.0,10); PLOT(MAP,V1,0.0,10)
PLOT(MAP,TEM1,0.0,10); PLOT(MAP,PRPS,0.0,10)
    GROUP 24. Dumps for restarts