TEXT(2D Subsonic Turbulent Round Jet
TITLE
  DISPLAY
  The problem considered is the near-field of a subsonic turbulent
  round jet issuing into stagnant surroundings at Mach 0.95. The
  stagnation enthalpy of the nozzle fluid is equal to that of the
  free stream, so that with the assumption of unit Prandtl numbers
  the energy equation need not be solved. The k-e model is used
  and the calculations are started at the jet discharge plane. The
  parabolic marching integration is carried out until about 10
  diameters downstream. The calculations are made with 30 radial
  grid cells and a forward step size of 5% (DZW1) of the local grid
  width. The radial width of the grid increases linearly with
  downstream distance so as to accommodate the jet spread.
  ENDDIS
   So as to allow a direct computation of dimensionless flow
   variables, the flow equations are normalised such that the flow
   variables can be interpreted as: P/Po; RHO/RHOo; T/To; U/Uref;
   H/Href; KE/Uref**2; EP*L/Uref**3; and ENUT/(Uref*L).
 
   Here: Po, RHOo and To are the inlet total pressure, density
   and temperature; Uref=Ao/SQRT(GAMMA); L is the nozzle diameter;
   and Href=(gam-1.)*Ho/gam, where Ho is the inlet total enthalpy
   and gam is the specific heat ratio. Ao is the acoustic velocity
   at To (see Palacio et al, Int.J.Heat Mass Transfer, Vol.33,
   No.6, p1193, [1990] ).
 
 
  PHOTON USE
   P
   PARPHI
 
 
 
   vec x 1 sh
   pau;cl
   con mach x 1 fi;.1
   pau;cl
   con enut x 1 fi;.1
   pau cl;
   con tmp1 x 1 fi;.1
  ENDUSE
 
REAL(AIN,CP,GAM,GM1,PTOT,HTOT,RHTOT,PAMB,HAMB,MIN,PIN,HIN,RHOIN)
REAL(WIN,EPSIN,TKEIN,DTF,DN,RAD,PRAT,RCON,RGAM,TTOT,TIN,UAC)
REAL(FLOWIN,AOIN,UREF,DYGDZ);CHAR(CTURB);BOOLEAN(GEXPAN)
   **  GEXPAN=T activates a linear y-grid expansion with z
GEXPAN=T
   **  Gas properties
GAM=1.4;GM1=GAM-1.;RCON=1.0;CP=RCON*GAM/GM1;RGAM=1./GAM
 
   **  INLET CONDITIONS & NOZZLE DIAMETER
PTOT=1.0;RHTOT=1.0;TTOT=1.0;MIN=0.95;DN=1.0
HTOT=CP*TTOT
 
RAD=0.5*DN
PIN=PTOT/(1.+GM1*MIN*MIN/2.)**(GAM/GM1)
RHOIN=RHTOT*(PIN/PTOT)**RGAM;WIN=MIN*(GAM*PIN/RHOIN)**0.5
TIN=PIN/(RCON*RHOIN);HIN=CP*TIN
AOIN=(GAM*PTOT/RHTOT)*0.5;UREF=AOIN/GAM**0.5
    ** Set static pressure ratio, i.e. PIN/PAMB
PRAT=1.0
    ** Ambient pressure
PAMB=PIN/PRAT;HAMB=HTOT
    GROUP 1. Run title and other preliminaries
    GROUP 2. Transience; time-step specification
PARAB=T
    GROUP 3. X-direction grid specification
CARTES=F;XULAST=0.1;AIN=0.5*XULAST*RAD*RAD
    GROUP 4. Y-direction grid specification
NY=30;YVLAST=DN;NREGY=2
IF(GEXPAN) THEN
+ DYGDZ=0.085*1.5;AZYV=1.0;ZWADD=DN/DYGDZ
ENDIF
IREGY=1;GRDPWR(Y,20,RAD,1.0);IREGY=2;GRDPWR(Y,10,RAD,1.3)
    GROUP 5. Z-direction grid specification
NZ=140;AZDZ=PROPY;DZW1=0.05
    GROUP 6. Body-fitted coordinates or grid distortion
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1)
SOLUTN(W1,P,P,P,P,P,N);SOLUTN(V1,P,P,P,P,P,N)
  ** Provide storage for the density.
STORE(RHO1,MACH,ENUT,LEN1,H1,TMP1)
TURMOD(KEMODL)
    GROUP 8. Terms (in differential equations) & devices
DENPCO=T
  ** improve accuracy by accounting for grid inclination
     in calculation of radial convection fluxes
IF(GEXPAN) THEN
+ V1AD=GRND1
ENDIF
    GROUP 9. Properties of the medium (or media)
RHO1=IDEALGAS;RHO1B=1./RCON;PRESS0=0.0
DRH1DP=IDEALGAS;RHO1C=RGAM
TMP1=VARSTAGH;CP1=CP
ENUL=1.8E-5/(UREF*DN)
    GROUP 10. Inter-phase-transfer processes and properties
    GROUP 11. Initialization of variable or porosity fields
TKEIN=(0.1*WIN)**2;EPSIN=0.1643*TKEIN**1.5/(0.1*RAD/DN)
FIINIT(EP)=EPSIN; FIINIT(KE)=TKEIN
FIINIT(W1)=WIN;FIINIT(RHO1)=RHOIN;FIINIT(P1)=PIN
FIINIT(H1)=HTOT
INIADD=F
PATCH(INITFS,INIVAL,1,1,#2,#2,1,1,1,1)
COVAL(INITFS,W1,0.0,0.0)
    GROUP 13. Boundary conditions and special sources
INLET(IN,LOW,1,NX,#1,#1,1,1,1,1)
VALUE(IN,P1,RHOIN*WIN);VALUE(IN,W1,WIN)
VALUE(IN,KE,TKEIN);VALUE(IN,EP,EPSIN)
 
PATCH(NB,NORTH,1,1,NY,NY,1,NZ,1,1)
COVAL(NB,P1,1.E3,PAMB);COVAL(NB,W1,ONLYMS,0.0)
 
    GROUP 16. Termination of iterations
FLOWIN=RHOIN*WIN*AIN
SELREF=F;RESREF(P1)=1.E-12*FLOWIN
RESREF(W1)=1.E-12*FLOWIN*WIN
RESREF(KE)=1.E-12*FLOWIN*TKEIN;RESREF(EP)=1.E-12*FLOWIN*EPSIN
RESREF(V1)=RESREF(W1)
    GROUP 17. Under-relaxation devices
DTF=10.*DZW1*YVLAST/(WIN+UAC)
RELAX(V1,FALSDT,DTF);RELAX(W1,FALSDT,DTF)
RELAX(KE,LINRLX,0.2);RELAX(EP,LINRLX,0.2);KELIN=3
RELAX(P1,LINRLX,0.15);RELAX(RHO1,LINRLX,0.05)
    GROUP 18. Limits on variables or increments to them
VARMIN(W1)=1.E-10
VARMIN(RHO1)=1.0E-4*RHTOT;VARMIN(H1)=1.0E-10
VARMAX(RHO1)=5.0*RHTOT;VARMAX(H1)=HTOT;VARMAX(P1)=5.0*PTOT
    GROUP 19. Data communicated by satellite to GROUND
    GROUP 20. Preliminary print-out
    GROUP 21. Print-out of variables
    GROUP 22. Spot-value print-out
IXMON=1;IYMON=20;IZMON=1
    GROUP 23. Field print-out and plot control
ITABL=2;NPLT=5;NYPRIN=2;NZPRIN=NZ/5
IF(NZ.GT.1) THEN
+ IDISPA=2;IDISPB=1;IDISPC=NZ
ENDIF
IPARAB=1
LITHYD=60;TSTSWP=-1;IPLTL=LITHYD