PHOTON USE
  ext
 
 
 
  view 1 2 3
  msg Temperature contours
  con tem1 z m fi;0.001
  con tem1 y m fi;0.001
  con tem1 x m fi;0.001
  gr x m;gr y m;gr z m
  msg Note contact resistance between upper and lower regions
  msg impeding heat flow from top towards the bottom.
  msg Press e to END
  enduse
 
    GROUP 1. Run title and other preliminaries
TEXT(Contact Resistance To Heat Condctn
TITLE
mesg(PC486/50 time last reported as appx. 30.sec
  DISPLAY
 
  Library Q1 file (case 100) has been slightly  modified to
  exemplify the use of the "contact-resistance" feature, which
  permits the simulation of thin (sub-grid-scale) sheets of
  material which conducts heat poorly.
 
  The high-south-east corner of the cube has TEMP=0.0; there is a
  patch heated to TEMP=100.0 on the north face of the cube; and
  the contact resistance stretches across the cube between iyres
  and iyres+1 .
 
  enddis
 
REAL(XLENGTH,YLENGTH,ZLENGTH,CONDUCT,CUBRES,FACTOR)
XLENGTH=1.0;YLENGTH=1.0;ZLENGTH=1.0;CONDUCT=1.0
NX=10;NY=10;NZ=10
CUBRES=ylength*nx*ny/conduct;FACTOR=10.0
 
  Groups 3,4 & 5 domain size and grid
NX=10;NY=10;NZ=10;xulast=xlength;yvlast=ylength;zwlast=zlength
#unigrid
 
    GROUP 7. Variables stored, solved & named
SOLVE(TEM1);SOLUTN(TEM1,Y,Y,Y,N,N,Y)
 
    GROUP 8. Terms (in differential equations) & devices
   **For pure conduction, cut out built-in source and convection
     terms
TERMS(TEM1,N,N,Y,N,Y,Y)
    GROUP 9. Properties of the medium (or media)
PRNDTL(TEM1)=-conduct
    GROUP 12. Local adjustments of convection and diffusion
DO II=1,5
MESG(
ENDDO
INTEGER(IYRES)
IYRES=NY/2
mesg(NY = :NY:; iyres = :iyres: OK? If not, insert new value
READVDU(IYRES,INT,IYRES)
mesg(Extra resistance = :FACTOR: * cube thickness / conductivity
mesg(OK? If not, insert new value
READVDU(FACTOR,REAL,FACTOR)
  ** contact-resistance patch: the node to node resistance becomes
     (nominal resistance + val)/co  (see PATCH in Encyclopaedia)
PATCH(GP12DFN,NORTH,1,NX,IYRES,IYRES,1,NZ,1,1)
COVAL(GP12DFN,TEM1,1.0,CUBRES*FACTOR)
 
    GROUP 13. Boundary conditions and special sources
PATCH(COLD,SWALL,NX,NX,1,1,NZ,NZ,1,1)
COVAL(COLD,TEM1,1.0,0.0)
 
PATCH(HEATER,NWALL,3,4,NY,NY,3,4,1,1)
COVAL(HEATER,TEM1,1.0,100.0)
 
mesg(Change hot and cold patches to cover whole north and south
mesg(faces of cube, to make solution 1D and easy to check? (y/n)
READVDU(ANS,CHAR,N)
IF(:ANS:.EQ.Y) THEN
 PATCH(COLD,SWALL,1,NX,1,1,1,NZ,1,1)
 PATCH(HEATER,NWALL,1,NX,NY,NY,1,NZ,1,1)
ENDIF
    GROUP 16. Termination of iterations
LITER(TEM1)=-100;OVRRLX= 1.7
ISOLX=1;ISOLY=1;ISOLZ=1;RESREF(TEM1)=1.E-6
LSWEEP=3
 
    GROUP 21. Print-out of variables
OUTPUT(TEM1,Y,Y,Y,Y,Y,Y)
 
    GROUP 22. Spot-value print-out
IXMON=NX/2+1;IYMON=NY/2+1;IZMON=NZ/2+1;UWATCH=T
itabl=2
    GROUP 23. Field print-out and plot control
NXPRIN=NX/5;NYPRIN=NY/5;NZPRIN=NZ/5;NPLT=1;UWATCH=T
    GROUP 24. Dumps for restarts