TEXT(SCRS Combustion In A Duct
TITLE  
  DISPLAY
  The problem considered is methane gas entering at one end of
  a duct, and oxidant injected downstream at a uniform rate along
  the duct. The combustion of the resulting mixture is modelled by
  means of the built-in SCRS (simple-chemical reaction scheme). 
  
  The reaction can be diffusion- or chemistry-controlled, and for 
  the latter, the option is provided for calculations to be made 
  with either the eddy-break-up model or the Arrhenius law. 
  
  The gas emits and aborbs radiant energy which is modelled by means 
  of the 1-flux radiation model. The fuel inlet and gas outlet is 
  presumed transparent to radiation.
  ENDDIS
  PHOTON USE
    AUTOPLOT
    FILE
    PHI 5
 
    cl;D 1 TMP1;COL3 1
    text
     1
 
     axial temperature profile
    0.13201E+04 0.25859E+04 CR
    redr
    PAUSE
    CL
    D 1 FUEL;D 1 OXID;D 1 PROD
    COL3 1;COL9 2;COLF 3
    text
     1
 
     profiles of fuel, oxidant & product mass fractions
    0.75201E+03 0.25859E+04 CR
    redr
    PAUSE
  ENDUSE
 
    GROUP 1. Run title and other preliminaries
REAL(UIN,TIN,MFUIN,MOXIN,HFUIN,HOXIN,TKEIN)
REAL(WOX,WFU,WPR,CPOX,CPFU,CPPR)
REAL(HFU,STOIC,FSTOIC,EDR,AKRAT,EPSDKE)
INTEGER(ICOMB);CHAR(CMOD)
MESG( Enter required combustion model
MESG( Default: BURN - SCRS mixed-is-burnt
MESG( The options are:
MESG(  EBUM - SCRS finite-rate eddy break up
MESG(  ARRM - SCRS finite-rate arrhenius
READVDU(CMOD,CHAR,BURN)
CASE :CMOD: OF
WHEN BURN,4
+ MESG( SCRS mixed is burnt
+ ICOMB=0
WHEN EBUM,4
+ MESG( EBUM - SCRS finite-rate EBU model
+ ICOMB=1
WHEN ARRM,4
+ MESG( ARRM - SCRS finite-rate Arrhenius model
+ ICOMB=2
ENDCASE
  ** Define molecular masses and specific heats
WOX=29.0;WFU=16.0;WPR=28.0
CPFU=1.5E3;CPPR=1.5E3;CPOX=1.5E3
  ** Define heat of reaction & stoichometry
     1kg CH4 + s kg oxidant -> (1+s) kg product
       where s = 4.0/0.232
HFU=4.9E7;STOIC=17.24;FSTOIC=1./(1.+STOIC)
  ** Inlet velocity & temperature (in K)
UIN=1.0;TIN=288.0
 
  ** Inlet fuel mass fraction and enthalpies
MFUIN=1.0;HOXIN=CPOX*TIN
HFUIN=CPFU*TIN+MFUIN*HFU;MOXIN=2.0*STOIC*MFUIN
 
REAL(RADW,ABSORB,SCAT,SIGMA)
SIGMA=5.6697E-8;RADW=SIGMA*300.0**4;ABSORB=0.2;SCAT=0.05
    GROUP 3. X-direction grid specification
NX=30
GRDPWR(X,NX,XULAST,1.2)
    GROUP 7. Variables stored, solved & named
SOLVE(P1,U1,H1,MIXF);STORE(OXID,PROD,TMP1,DEN1)
IF(ICOMB.EQ.0) THEN
+ STORE(FUEL)
ELSE
+ SOLVE(FUEL)
ENDIF
  ** use k and ep to define turbulent time scale
     for eddy-break-up model
IF(ICOMB.EQ.1) THEN
+ STORE(KE,EP);TKEIN=0.1*UIN*UIN;FIINIT(KE)=TKEIN
+ EPSDKE=100.
+ FIINIT(EP)=EPSDKE*TKEIN
ENDIF
    GROUP 8. Terms (in differential equations) & devices
TERMS(H1,N,Y,Y,N,Y,N)
    GROUP 9. Properties of the medium (or media)
RHO1=GRND6;PRESS0=1.01325E5;RHO1A=WFU;RHO1B=WOX;RHO1C=WPR
RADIAT(ABSORB,SCAT,1.0)
IF(ICOMB.EQ.0) THEN
  ** mixing-controlled combustion
+ TMP1=GRND7
ELSE
  ** rate-controlled combustion
+ TMP1=GRND8
ENDIF
CP1=GRND10; CP1A=CPFU; CP1B=CPOX; CP1C=CPPR
TMP2A=FSTOIC;TMP2B=HFU
    GROUP 11. Initialization of variable or porosity fields
FIINIT(U1)=UIN;FIINIT(H1)=HFUIN;FIINIT(MIXF)=1.0
FIINIT(RADX)=RADW
FIINIT(FUEL)=1.0
    GROUP 13. Boundary conditions and special sources
PATCH(FUIN,CELL,1,1,1,1,1,1,1,1)
COVAL(FUIN,P1,FIXFLU,MFUIN);COVAL(FUIN,U1,ONLYMS,UIN)
COVAL(FUIN,H1,ONLYMS,HFUIN);COVAL(FUIN,MIXF,ONLYMS,1.0)
COVAL(FUIN,RADX,1.0,RADW)
IF(ICOMB.NE.0) THEN
+ COVAL(FUIN,FUEL,ONLYMS,1.0)
ENDIF
 
PATCH(OUT,HIGH,NX,NX,1,NY,1,1,1,1);COVAL(OUT,P1,FIXP,0.0)
COVAL(OUT,RADX,1.0,RADW)
 
PATCH(OX1,NORTH,2,NX,1,1,1,1,1,1)
COVAL(OX1,P1,FIXFLU,MOXIN);COVAL(OX1,H1,ONLYMS,HOXIN)
COVAL(OX1,U1,FIXFLU,0.0);COVAL(OX1,MIXF,ONLYMS,0.0)
 
IF(ICOMB.EQ.1) THEN
+ PATCH(CHSO,PHASEM,1,NX,1,NY,1,NZ,1,LSTEP)
+ COVAL(CHSO,FUEL,GRND9,GRND9)
+ CHSOA=FSTOIC
   ** Specify eddy-break-up constant, i.e.
      source = chsob*(ep/ke)*min
+ CHSOB=50.0
ENDIF
IF(ICOMB.EQ.2) THEN
+ PATCH(CHSO,VOLUME,1,NX,1,NY,1,NZ,1,LSTEP)
+ COVAL(CHSO,FUEL,GRND6,0.0)
   ** Specify arrhenius rate constants,i.e.
      source = akrat*mfu*mox*exp(EDR/(tmp1+tref))
+ EDR=1.E3;AKRAT=1.E2
+ CHSOE=0.0;CHSOD=EDR;CHSOA=AKRAT
+ CHSOB=-AKRAT/FSTOIC;CHSOC=AKRAT*(1./FSTOIC-1.)
ENDIF
    GROUP 15. Termination of sweeps
LSWEEP=25
IF(ICOMB.EQ.1) THEN
+ LSWEEP=40
ENDIF
IF(ICOMB.EQ.2) THEN
+ LSWEEP=200
ENDIF
    GROUP 16. Termination of iterations
    GROUP 17. Under-relaxation devices
VARMIN(FUEL)=0.0;VARMAX(FUEL)=1.0
VARMIN(TMP1)=0.5*TIN
VARMIN(DEN1)=0.1*PRESS0/(8314.43/WPR)/3500.0
DENPCO=T
REAL(DTF,RLXFAC);DTF=XULAST/UIN;RLXFAC=0.3
IF(ICOMB.EQ.2) THEN
+ DTF=DTF/1.E4;RLXFAC=0.1
+ RELAX(U1,FALSDT,DTF)
ENDIF
IF(ICOMB.NE.0) THEN
+ RELAX(FUEL,FALSDT,DTF)
ENDIF
RELAX(DEN1,LINRLX,RLXFAC)
    GROUP 21. Print-out of variables
TSTSWP=-1
    GROUP 20. Preliminary print-out
    GROUP 21. Print-out of variables
    GROUP 22. Spot-value print-out
IXMON=5
ITABL=1;IPLTL=LSWEEP
    GROUP 23. Field print-out and plot control
ITABL=3;NPLT=5
DISTIL=T
IF(ICOMB.EQ.0) THEN
+ EX(P1  )=3.485E+03;EX(U1  )=7.688E+01;EX(H1  )=7.232E+06
+ EX(RADX)=9.580E+04;EX(FUEL)=9.643E-02;EX(DEN1)=2.204E-01
+ EX(TMP1)=1.671E+03;EX(PROD)=7.747E-01;EX(OXID)=1.289E-01
+ EX(MIXF)=1.389E-01
ENDIF
IF(ICOMB.EQ.1) THEN
+ EX(U1  )=7.579E+01
+ EX(P1  )=3.505E+03;EX(U1  )=7.579E+01;EX(KE  )=1.000E-01
+ EX(EP  )=1.000E+01;EX(H1  )=7.235E+06;EX(RADX)=8.688E+04
+ EX(FUEL)=9.761E-02;EX(DEN1)=2.241E-01;EX(TMP1)=1.635E+03
+ EX(PROD)=7.535E-01;EX(OXID)=1.488E-01;EX(MIXF)=1.389E-01
ENDIF
IF(ICOMB.EQ.2) THEN
+ EX(P1  )=3.471E+03;EX(U1  )=6.592E+01;EX(H1  )=7.237E+06
+ EX(RADX)=4.994E+04;EX(FUEL)=1.034E-01;EX(DEN1)=2.481E-01
+ EX(TMP1)=1.448E+03;EX(PROD)=6.489E-01;EX(OXID)=2.478E-01
+ EX(MIXF)=1.389E-01
ENDIF