TALK=T;RUN(1,1) Moving wall by In-Form; 745

    GROUP 1. Run title and other preliminaries
TEXT(Non-uniform moving-wall velocity
TITLE
  DISPLAY
   In-Form is used for specifyinhg non-uniform inlet, outlet and 
   wall boundary conditions, for:
         steady laminar flow and heat transfer
  in a plane channel. 

                      ------> Wall velocity proportional to x                                 
             //////////////////// North Wall ///////////////////////
            -------------------------------------------------------
  parabolic ->                                      outlet resistance       
  mass-flux -->                                     varies with                        
  velocity  ->                                      y value            
  and constant ----------------------------------------------------
  enthalpy   //////////////////// South Wall ///////////////////////
              ^ y      ------> Wall velocity proportional to x
              |-------> x-direction


  The inlet flow has a parabolic profile
  The outlet coefficient =  A + B * sin[ pi *( y/yv]ast - 1/2 )]
  where A and B are constants, yvlast is channel width.
  North and south walls moved with velocity proportionally
  to longitudinal distance, x 
  Their enthalpy is a piece-wise-linear function of x.

  South-wall boundary condition uses PATCH of SWALL type. 
  North wall boundary condition uses PATCH of NORTH type and 
    therefore need LAMWALL option.
  
  Solution should be symmetrical about channel centre plane.

  The Q1 contains PHOTON USE commands
  ENDDIS
  PHOTON USE
  p
  phi
  1 8 1
 
  msg picture is enlarged 8 times in y direction
  gr ou z 1
  msg contours of H1 with Pr = 0.7
  con h1 z 1 fi;0.001;upause 2
  msg velocity vectors
  vec z 1
  enduse

REAL(VELMAX,UWALLMAX,TWALLMAX,ACON,BCON,PI)
VELMAX=0.1; UWALLMAX=0.1; TWALLMAX=1.0; ACON=1.0; BCON=0.5
PI=3.14159
  GROUP 3. X-direction grid specification
GRDPWR(X,20,0.2,1.0)
 
    GROUP 4. Y-direction grid specification
GRDPWR(Y,20,0.01,1.0)
 
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,U1,H1)
 
    GROUP 8. Terms (in differential equations) & devices
  ** De-activate the built-in source term
TERMS(H1,N,Y,Y,Y,Y,Y)
 
    GROUP 9. Properties of the medium (or media)
ENUL=1.545E-5; PRNDTL(H1)=0.7 ;RHO1=1.189 ! air at room temperature
    GROUP 13. Boundary conditions and special sources
  
  Inlet
PATCH(INL,WEST,1,1,1,NY,1,1,1,1)  ! parabolic velocity, uniform H1
(SOURCE of P1 at INL is RHO1*VELMAX*(1.-(2.*YG/YVLAST-1)^2))
(SOURCE of U1 at INL is VELMAX*(1.-(2.*YG/YVLAST-1)^2) with ONLYMS)
(SOURCE of V1 at INL is 0.0 with ONLYMS)
(SOURCE of H1 at INL is TWALLMAX*0.2 with ONLYMS)
 
  Walls   
CHAR(FORM)
FORM=pwl3(xg,0,0,.4*xulast,-.5*:twallmax:,.5*xulast,$
2.0*:twallmax:,xulast,:twallmax:)  ! piece-wise linear formula for H1
           
PATCH(SW,SWALL,1,NX,1,1,1,NZ,1,1)
(SOURCE of U1 at SW is UWALLMAX*XU/XULAST)
(SOURCE of H1 at SW is :FORM:)
PATCH(NW,NORTH,1,NX,NY,NY,1,NZ,1,1)
(SOURCE of U1 at NW is UWALLMAX*XU/XULAST with LAMWALL)
(SOURCE of H1 at NW is :FORM: with LAMWALL)

  Outlet 
PATCH(OUT,EAST,NX,NX,1,NY,1,NZ,1,1)

FORM=-P1*(:ACON:+:BCON:*COS(:PI:*(YG/:YVLAST:-0.5)))
(SOURCE of P1 at OUT is :FORM: with LINE)
 
    GROUP 15. Termination of sweeps
LSWEEP=50
SELREF=T; RESFAC=0.1
    GROUP 17. Under-relaxation devices
RELAX(U1,FALSDT,0.1); RELAX(V1,FALSDT,0.1)
    GROUP 22. Spot-value print-out
IYMON=19; IXMON=10; TSTSWP=-1
#conprom
#maxabs
#endpause
distil=t