#cls
text(In-Form Equivalent Of PLANT Case Z140
title
libref=740
  
  DISPLAY
  
  This In-Form case does what Z140 does, but without fortran coding
  or re-compilation.
  
  First, case z140 is loaded. Then NAMSAT = NONE is set, to 
  deactivate. Then, the following line provides for EL1
  to be calculated in accordance with the required formula:
  
  (PROPERTY var EL1 is MIN(.0166*EXP(60.*(.2-RG)-1.) , ...
  
  Finally, provision is made for the formula to be printed in the
  "field-values print-out", by setting the formula as the "long-
  name" of EL1, as follows:
  
  (LONGNAME of EL1 is MIN(.0166*EXP(60.*(.2-RG)-1.) , ...
  
  [Note: the dollar signs have been replaced by ... ]

  The Q1 contains PHOTON USE commands
  ENDDIS  
  PHOTON USE
  P



  gr ce ou x 1;set lhand
  vec x 1 sh
  msg                Velocity distribution
  msg  Press Enter to continue
  pause
  vec off;red
  con H1 x 1 fil;0.001
  msg                Temperature distribution
  msg  Press Enter to continue
  pause
  con off;red
  con KE x 1 fil;0.001
  msg                Turbulence energy distribution
  msg  Press Enter to continue
  pause
  con off;red
  con EL1 x 1 fil;0.001
  msg                Length scale distribution
  msg(Press Enter to continue
  pause
  con off;red
  con ENUT x 1 fil;0.001
  msg                Turbulence viscosity distribution
  ENDUSE

load(z140) 
text(In-Form equivalent of PLANT case Z140
libref=740

    ** The next line de-activates PLANT **
namsat=none
  
     ** In-Form property formulae which are equivalent to the
        PLANT formulae of z140                               **
  INFORM9BEGIN
el1=1 ! cancel call to GROUND
(PROPERTY var EL1 is MIN(.0166*EXP(60.*(.2-RG)-1.) ,$
MIN(.016*(ZG/0.2)^1.09 , 0.12)))

(LONGNAME of EL1 is MIN(.0166*EXP(60.*(.2-RG)-1.) ,$
MIN(.016*(ZG/0.2)^1.09 , 0.12)))
  INFORM9END
DISTIL=T
EX(P1)=1.492E-01; EX(V1)=2.481E-02; EX(W1)=6.473E-01
EX(H1)=9.695E-01; EX(EL1)=6.807E-02; EX(ENUT)=1.062E-02
EX(KE)=1.109E-01
STOP