#cls
text(In-Form Equivalent Of PLANT Case Z117
title
libref=717
  DISPLAY
 
  This In-Form case does without Fortran coding what PLANT case
  Z117 does with it, namely:
    
  solves a two-dimensional steady diffusion problem  with  
  space-dependent  source and boundary conditions.  
  It can be tested against exact solution  fields.  

  Governing equation: d(dT/dX)/dX + d(dT/dX)/dX +  S(X,Y)  =  0
    wherein the source S is defined by:  S(X,Y)  =  2.sinX.sinY
  Boundary  conditions:
  at Y = 0 ;  T = 0
  at Y = 1 ;  T = sin1.sinX
  at X = 0 ;  T = 0
  at X = 1 ;  T = sin1.sinY
  Exact solution:               T(X,Y) = sinX.sinY
  
  The Q1 uses the In-Form statements: STORED and SOURCE.
  
  The Q1 contains PHOTON USE commands
  ENDDIS  
  PHOTON USE
  p
 
 

 
  gr ou z 1
  msg           Temperature contours
  msg           (Numerical solution)
  con h1 z 1 fi;0.001
  msg Press Enter to continue
  pause
  con off;red
  con exac z 1 fi;0.001
  msg           Temperature contours
  msg             (Exact solution)
  msg Press e to END
  ENDUSE

     ** In-Form formulae which are equivalent to the
        PLANT formulae of z117                      **
load(z117)
text(In-Form equivalent of PLANT case Z117
libref=717
  INFORM13BEGIN
     ** The next line de-activates PLANT **
namsat=none
YEQ1=SKIP
XEQ1=SKIP
COVAL(SOURCE,H1,0.,0.)
  INFORM13END
STORE(ENUL)  
  
  INFORM13BEGIN
PATCH(IYEQ1,NORTH,1,NX,NY,NY,1,1,1,1)
(SOURCE of H1 at IYEQ1 is SIN(1.)*SIN(XG) with LAMW)

PATCH(IXEQ1,EWALL,NX,NX,1,NY,1,1,1,1)
(SOURCE of H1 at IXEQ1 is SIN(1.)*SIN(YG))

PATCH(ISOURCE,VOLUME,1,NX,1,NY,1,1,1,1)
(SOURCE of H1 at ISOURCE is 2.*SIN(XG)*SIN(YG))
  INFORM13END
  INFORM7BEGIN
(STORED of EXAC is SIN(XG)*SIN(YG))
  INFORM7END
DISTIL=T
EX(H1)=2.114E-01;EX(ENUL)=1.000E+00
EX(EXAC)=2.114E-01
STOP