#cls
text(In-Form Equivalent Of PLANT Case Z101
title
libref=701
  DISPLAY
  
  This In-Form case does what Z101 does, but without fortran coding
  or re-compilation.
  
  First, case z101 is loaded. 
  Then NAMSAT = NONE is set, in order to deactivate PLANT entries. 
  Thereafter the following In-Form formulae do what is necessary 
  to ensure that the properties are correctly related to the 
  temperature, T1 . [Note that ... replaces the dollar-sign for ease
                                                         of display]
  (property var den1 is POL3(t1,1.1386e3,1.0388,5.8115E-4...
  ,-6.7765E-7))
  (PROPERTY VISL is EMU/DEN1)
  (PROPERTY PRNDTL(H1) is EMU*CP/COND)
  (STORED of T1 is H1/CP)
  (STORED of CP is... 
             4186.8*POL3(T1,.616,-.0040428,1.8333e-5,-2.38E-08))
  (STORED of EMU is 4.1868E-04*POL3(T1,69.647,...
    -0.5278,1.358e-3,-1.16E-06))
  (STORED of COND is 1.163*POL3(T1,-0.1909,.003155,...
     -1.0341e-5,1.0666E-8))

  The Q1 uses the In-Form statements:
      PROPERTY, STORED and LONGNAME.

  The Q1 contains PHOTON USE commands
  ENDDIS  

load(z101)
text(In-Form equivalent of PLANT case Z101
libref=701
  Note 1: The next line de-activates PLANT
namsat=none
rho1=1        ! these de-activate the rho1=grnd etc statements
enul=1        ! inserted by plant
prndtl(h1) =grnd2 ! set grnd2 for activation calculation of prndtl
  
  Note 2: the following settings have been chosen as being
  preferable to those of z101, in respect of convergence and 
  printout.
  
RELAX(U1,FALSDT,0.1);RELAX(W1,FALSDT,0.1);RELAX(P1,LINRLX,0.5)
RELAX(T1,LINRLX,0.05)   ! T1 is heavily under-relaxed because all
                        ! other properties depend upon it strongly
NXPRIN=-1; NZPRIN=-1; TSTSWP=-1 
  INFORM9BEGIN
     ** In-Form property formulae which are equivalent to the
        PLANT formulae of z100                               **
  
(property var den1 is POL3(t1,1.1386e3,1.0388,5.8115E-4$
,-6.7765E-7))

(LONGNAME of DEN1 is POL3(t1,1.1386e3,1.0388,5.8115E-4$
,-6.7765E-7))

(PROPERTY VISL is EMU/DEN1)
(LONGNAME VISL is EMU/DEN1)

(PROPERTY PRNDTL(H1) is EMU*CP/COND)
   ** Property correlations
  
     * Temperature
(STORED of T1 is H1/CP)
     * Heat capacity
(STORED of CP is 4186.8*POL3(T1,.616,-.0040428,1.8333e-5,-2.38E-08))

     * Dynamic viscosity
(STORED of EMU is 4.1868E-04*POL3(T1,69.647,$
-0.5278,1.358e-3,-1.16E-06))
     * Thermal conductivity
(STORED of COND is 1.163*POL3(T1,-0.1909,.003155,$
-1.0341e-5,1.0666E-8))
  INFORM9END
DISTIL=T
EX(P1)=1.158E-01; EX(U1)=1.161E-03; EX(W1)=2.308E-02
EX(H1)=5.252E+05; EX(CP)=1.723E+03; EX(COND)=1.298E-01
EX(EMU)=9.530E-04; EX(T1)=3.041E+02; EX(VISL)=6.450E-07;
EX(DEN1)=1.489E+03; EX(WCRT)=2.281E-02; EX(UCRT)=1.148E-03
  PHOTON USE
  P;;;;

  gr ou y 1
  msg             Duct geometry
  msg  Press Enter to continue
  pause;  set vec ref .04;  red;  vec y 1 sh
  msg             Xylene velocity distribution, m/s
  msg Press ENTER to continue
  pause;  vec off;red;  con H1 y 1 fil;.000001
  msg             Enthalpy contours, J/kg
  msg Press ENTER to continue
  pause;  con off;red;  con T1 y 1 fil;.000001
  msg             Temperature contours, K
  msg Press ENTER to continue
  pause;  con off;red;  con den1 y 1 fil;.000001
  msg             Density contours, kg/m^3
  msg Press ENTER to continue
  pause;  con off;red;  con EMU y 1 fil;.000001
  msg             Dynamic viscosity contours, N.s/m^2
  msg Press ENTER to continue
  pause;  con off;red;  con visl y 1 fil;.000001
  msg             Kinematic viscosity contours, m^2/s
  msg Press ENTER to continue
  pause;  con off;red;  con COND y 1 fil;.000001
  msg             Thermal conductivity contours, W/(m.K)
  msg Press ENTER to continue
  pause;  con off;red;  con CP y 1 fil;.000001
  msg             Heat capacity contours, J/(kg.K)
  msg Press E to finish
  ENDUSE
STOP