photon use
  p;;;;;
 
  msg The grid
  gr z 1 ;pause;gr off;red; gr ou z 1
  msg Contours of RADX
  con radx z 1 fi;0.001;pause;con off;red
  msg Contours of RADY
  con rady z 1 fi;0.001;pause;con off;red
  msg Contours of H1
  con h1 z 1 fi;0.001;pause;con off;red
  enduse
    GROUP 1. Run title and other preliminaries
TEXT(2D Radiant Heat Transfer In A Box 
TITLE
  DISPLAY
    Radiative heat transfer takes place in a 2D box, which
    contains a semi-transparent medium at rest.
 
    The east and north walls are at a temperature TCOLD;
    the west and south  walls have temperatures THOT1 in their
    first halves and THOT2 in their second halves.
 
    THOT2 > THOT1 > TCOLD.
 
    The solved-for variables are temperature and two radiation
    quantities, namely the composite fluxes in the X and Y
    directions, with the asumptions of the four-flux model.
  ENDDIS
REAL(GSIGMA,SCAT,ABSORB,EMIH,EMIC,THOT1,THOT2,TCOLD,TGAS)
GSIGMA=5.6697E-8;SCAT=0.05;ABSORB=0.3;EMIH=0.9;EMIC=0.9
THOT1=666.0;THOT2=777.0;TCOLD=293.0;TGAS=800.0
    GROUP 3. X-direction grid specification
GRDPWR(X,10,1.0,1.0)
    GROUP 4. Y-direction grid specification
GRDPWR(Y,10,1.0,1.0)
    GROUP 7. Variables stored, solved & named
RADIAT(FLUX,ABSORB,SCAT,H1)
    GROUP 8.
TERMS(H1,N,N,P,P,P,P)    
    GROUP 9. Properties of the medium (or media)
PRNDTL(H1)=0.7;CP1=1.0;TMP1=LINH;TMP1B=1.0/CP1
    GROUP 11. Initialization of variable or porosity fields
FIINIT(RADX)=GSIGMA*((THOT1+TCOLD)*0.5)**4
FIINIT(RADY)=GSIGMA*((THOT1+TCOLD)*0.5)**4
FIINIT(H1)=(THOT1+TCOLD)*0.5
    GROUP 13. Boundary conditions and special sources
   ** Radiation wall boundary conditions.
PATCH(HOTW1R,WEST,1,1,1,NY/2,1,1,1,1)
COVAL(HOTW1R,RADX,EMIH/(2.0-EMIH),GSIGMA*THOT1**4)
PATCH(HOTW2R,WEST,1,1,NY/2+1,NY,1,1,1,1)
COVAL(HOTW2R,RADX,EMIH/(2.0-EMIH),GSIGMA*THOT2**4)
PATCH(COLDER,EAST,NX,NX,1,NY,1,1,1,1)
COVAL(COLDER,RADX,EMIC/(2.0-EMIC),GSIGMA*TCOLD**4)
PATCH(HOTS1R,SOUTH,1,NX/2,1,1,1,1,1,1)
COVAL(HOTS1R,RADY,EMIH/(2.0-EMIH),GSIGMA*THOT1**4)
PATCH(HOTS2R,SOUTH,NX/2+1,NX,1,1,1,1,1,1)
COVAL(HOTS2R,RADY,EMIH/(2.0-EMIH),GSIGMA*THOT2**4)
PATCH(COLDNR,NORTH,1,NX,NY,NY,1,1,1,1)
COVAL(COLDNR,RADY,EMIC/(2.0-EMIC),GSIGMA*TCOLD**4)
   ** Conduction wall boundary conditions
PATCH(HOTW1H,WEST,1,1,1,NY/2,1,1,1,1)
COVAL(HOTW1H,H1,1.,THOT1)
PATCH(HOTW2H,WEST,1,1,NY/2+1,NY,1,1,1,1)
COVAL(HOTW2H,H1,1.,THOT2)
PATCH(COLDEH,EAST,NX,NX,1,NY,1,1,1,1)
COVAL(COLDEH,H1,1.,TCOLD)
PATCH(HOTS1H,SOUTH,1,NX,1,1,1,1,1,1)
COVAL(HOTS1H,H1,1.,THOT1)
PATCH(HOTS2H,SOUTH,NX/2+1,NX,1,1,1,1,1,1)
COVAL(HOTS2H,H1,1.,THOT2)
PATCH(COLDNH,NORTH,1,NX,NY,NY,1,1,1,1)
COVAL(COLDNH,H1,1.,TCOLD)
    GROUP 15. Termination of sweeps
RESFAC=0.1;SELREF=T;LSWEEP=30
    GROUP 16. Termination of iterations
LITER(RADX)=2;LITER(RADY)=2
    GROUP 17. Under-relaxation devices
RELAX(H1,FALSDT,0.01);RELAX(RADX,FALSDT,1.0);RELAX(RADY,FALSDT,1.0)
    GROUP 22. Spot-value print-out
IXMON=NX/2;IYMON=NY/2;TSTSWP=-1
    GROUP 23. Field print-out and plot control
NPLT=2;NXPRIN=2;NYPRIN=2
PATCH(DOMAIN,CONTUR,1,NX,1,NY,1,1,1,1)
PLOT(DOMAIN,H1,0.0,10.0);PLOT(DOMAIN,RADX,0.0,10.0)
PLOT(DOMAIN,RADY,0.0,10.0)
OUTPUT(H1,Y,Y,Y,Y,Y,Y)