GROUP 1. Run title and other preliminaries
TEXT(1D Radiant Heat Transfre In A Box 
TITLE
  DISPLAY
    Radiative heat transfer takes place between parallel flat
    wide surfaces. The medium between them is at rest, and can
    absorb, emit and scatter radiation, as well as conducting
    heat.
 
    Wall temperatures and emissivities are prescribed.
 
    The RADIAT command is used to activate the radiation model of
    subroutine GXRADI.
 
    The solved-for variables are enthalpy, H1, and the composite
    radiation flux, RADX, defined as the arithmetic mean of the
    radiation fluxes in the +X and -X directions.
 
    RADX has a diffusivity which depends on the scattering and
    absorption coefficients.
 
    Press RETURN to continue
readvdu(nphi,int,nphi)
    The wall boundary condition for RADX has a Value equal to the
    gross radiation flux emitted by the wall; thus the net flux is
    proportional to:
       sigma*Tw**4 - RADX
    The COefficient for RADX is a function of emissivity.
    The locally-defined parameters are as follows:
               GSIGMA         Stefan-Boltzmann constant
               SCAT           Scattering coefficient
               ABSORB         Absorption coefficient
               EMIH           emissivity of the hot wall
               EMIC           emissivity of the cold wall
               THOT           hot wall temperature
               TCOLD          cold wall temperature
REAL(GSIGMA,SCAT,ABSORB,EMIH,EMIC,THOT,TCOLD)
GSIGMA=5.6697E-8;SCAT=0.05;ABSORB=0.2;EMIH=0.5;EMIC=0.2
THOT=600.0;TCOLD=300.0
  ENDDIS
mesg(Hot and cold temperatures are         :THOT: and :TCOLD:
mesg(Scattering and absorption coeffs. are :SCAT: and :ABSORB:
    GROUP 3. X-direction grid specification
   ** Symmetrical power-law grid set by using negative number of
      intervals
GRDPWR(X,-20,1.0,1.5)
    GROUP 7. Variables stored, solved & named
RADIAT(FLUX,ABSORB,SCAT,H1)
    GROUP 9. 
TERMS(h1,n,n,p,p,p,p)    
    GROUP 9. Properties of the medium (or media)
CP1=1.0;TMP1=LINH;TMP1B=1.0/CP1;ENUL=1.0E-3
   ** Prandtl number of medium
PRNDTL(H1)=0.7
    GROUP 11. Initialization of variable or porosity fields
FIINIT(RADX)=GSIGMA*((THOT+TCOLD)*0.5)**4
FIINIT(H1)=(THOT+TCOLD)*0.5
    GROUP 13. Boundary conditions and special sources
   ** Net radiation flux from wall
PATCH(WESTR,WEST,1,1,1,NY,1,1,1,1)
COVAL(WESTR,RADX,EMIH/(2.0-EMIH),GSIGMA*THOT**4)
PATCH(EASTR,EAST,NX,NX,1,NY,1,1,1,1)
COVAL(EASTR,RADX,EMIC/(2.0-EMIC),GSIGMA*TCOLD**4)
   ** Heat conduction at wall
WALL(WESTH,WEST,1,1,1,NY,1,1,1,1);COVAL(WESTH,H1,1.0,THOT)
WALL(EASTH,EAST,NX,NX,1,NY,1,1,1,1);COVAL(EASTH,H1,1.0,TCOLD)
    GROUP 15. Termination of sweeps
LSWEEP=25
    GROUP 17. Under-relaxation devices
RELAX(H1,FALSDT,.04)
    GROUP 22. Spot-value print-out
IXMON=NX/2;NPLT=2
    GROUP 23. Field print-out and plot control
PATCH(XWISE,PROFIL,1,NX,1,1,1,1,1,1)
PLOT(XWISE,H1,0.0,0.0);PLOT(XWISE,RADX,0.0,0.0)
OUTPUT(H1,Y,Y,Y,Y,Y,Y)
ITABL=1;TSTSWP=-1