GROUP 1. Run title and other preliminaries
TEXT(3D Radiant Heat Transfer In A Box 
TITLE
 
    This case is the same as library case number 552, but
    TEM1 is solved for, and not H1.
 
REAL(GSIGMA,SCAT,ABSORB,EMIH,EMIC,TWW,TWN,TWL,TWH,TWA,EPA)
GSIGMA=5.6697E-8;SCAT=0.05;ABSORB=0.3;EMIH=0.9;EMIC=0.9
TWW=500.0;TWN=700.0;TWL=300.0;TWH=1200.0
    GROUP 3. X-direction grid specification
GRDPWR(X,8,1.0,1.0)
    GROUP 4. Y-direction grid specification
GRDPWR(Y,8,1.0,1.0)
    GROUP 5. Z-direction grid specification
GRDPWR(Z,8,1.0,1.0)
    GROUP 7. Variables stored, solved & named
RADIAT(FLUX,ABSORB,SCAT,TEM1)
    GROUP 8. Terms (in differential equations) & devices
TERMS(TEM1,N,N,P,P,P,P)    
    GROUP 9. Properties of the medium (or media)
PRNDTL(TEM1)=0.73;REAL(RPR);RPR=1.0/PRNDTL(TEM1)
    GROUP 11. Initialization of variable or porosity fields
TWA=(TWW+TWN)*0.5;EPA=GSIGMA*(TWA)**4
FIINIT(RADX)=EPA;FIINIT(RADY)=EPA;FIINIT(RADZ)=EPA
FIINIT(TEM1)=TWA
    GROUP 13. Boundary conditions and special sources
   ** Radiation and enthalpy sources - West wall
PATCH(HOTWR,WEST,1,1,1,NY,1,NZ,1,1)
COVAL(HOTWR,RADX,EMIC/(2.0-EMIC),GSIGMA*TWW**4)
PATCH(HOTWH,WWALL,1,1,1,NY,1,NZ,1,1)
COVAL(HOTWH,TEM1,RPR,TWW)
   ** North wall
PATCH(HOTNR,NORTH,1,NX,NY,NY,1,NZ,1,1)
COVAL(HOTNR,RADY,EMIC/(2.0-EMIC),GSIGMA*TWN**4)
PATCH(HOTNH,NWALL,1,NX,NY,NY,1,NZ,1,1)
COVAL(HOTNH,TEM1,RPR,TWN)
   ** Low wall
PATCH(HOTLR,LOW,1,NX,1,NY,1,1,1,1)
COVAL(HOTLR,RADZ,EMIC/(2.0-EMIC),GSIGMA*TWL**4)
PATCH(HOTLH,LWALL,1,NX,1,NY,1,1,1,1)
COVAL(HOTLH,TEM1,RPR,TWL)
   ** High wall
PATCH(HOTHR,HIGH,1,NX,1,NY,NZ,NZ,1,1)
COVAL(HOTHR,RADZ,EMIH/(2.0-EMIH),GSIGMA*TWH**4)
PATCH(HOTHH,HWALL,1,NX,1,NY,NZ,NZ,1,1)
COVAL(HOTHH,TEM1,RPR,TWH)
    GROUP 15. Termination of sweeps
LSWEEP=10
    GROUP 16. Termination of iterations
LITER(RADX)=2;LITER(RADY)=2;LITER(RADZ)=2
    GROUP 17. Under-relaxation devices
RELAX(TEM1,FALSDT,0.01)
    GROUP 22. Spot-value print-out
IXMON=NX/2;IYMON=NY/2;IZMON=NZ/2
    GROUP 23. Field print-out and plot control
YZPR=T;IXPRF=NX/2;IXPRL=NX/2;NYPRIN=2;NZPRIN=2
PATCH(MIDPLANE,CONTUR,1,NX,1,NY,NZ/2,NZ/2,1,1)
PLOT(MIDPLANE,TEM1,0.0,10.0)
PLOT(MIDPLANE,RADX,0.0,10.0);PLOT(MIDPLANE,RADY,0.0,10.0)
PLOT(MIDPLANE,RADZ,0.0,10.0)
    GROUP 24. Dumps for restarts
TSTSWP=-1;NPLT=1;ITABL=3