DISPLAY
    Used to demonstrate various methods of solving temperature. The
    method is defined by the integer variable 'method'.
    method=1:  Solving enthalpy and storing temperature.
    method=2:  Solving for temperature directly.
    method=3:  Solving for temperature directly, but using the
               property file to define the material that is in each
               cell of the grid.
  ENDDIS
    GROUP 1. Run title and other preliminaries
TEXT(Temperature Solution Demonstration
TITLE
INTEGER(METHOD);METHOD=3
    GROUP 3. X-direction grid specification
CARTES=F;XULAST=3.14/6
    GROUP 4. Y-direction grid specification
RINNER=.005; GRDPWR(Y,30,.015,1)
    GROUP 7. Variables stored, solved & named
real(spht);spht=480
CASE METHOD OF
WHEN 1
+  SOLVE(H1); STORE(TMP1)
WHEN 2
+  SOLVE(TMP1)
WHEN 3
#soltem
+  STORE(PRPS)
ENDCASE
    GROUP 9. Properties of the medium (or media)
CASE METHOD OF
WHEN 1
+  RHO1=7800
+  +PRNDTL(H1)=-48/(RHO1*SPHT); TMP1=LINH; TMP1B=1/SPHT
WHEN 2
+  RHO1=7800
+  PRNDTL(TMP1)=-48/(RHO1*SPHT)
WHEN 3
cp1=spht
#use_props
ENDCASE
    GROUP 11. Initialization of variable or porosity fields
PATCH(METAL,INIVAL,1,NX,1,NY,1,NZ,1,1)
CASE METHOD OF
WHEN 1
+  INIT(METAL,H1,0,SPHT*200)
WHEN 2
+  INIT(METAL,TMP1,0,200)
WHEN 3
   Material 111 is Steel
+  INIT(METAL,PRPS,0,111); INIT(METAL,TEM1,0,200)
ENDCASE
    GROUP 13. Boundary conditions and special sources
PATCH(WL1,SWALL,1,NX,1,1,1,NZ,1,LSTEP)
PATCH(END,CELL,1,1,NY,NY,1,1,1,1)
CASE METHOD OF
WHEN 1
+  COVAL(WL1,H1,FIXVAL,SPHT*15); COVAL(END,H1,FIXVAL,SPHT*200)
WHEN 2
+  COVAL(WL1,TMP1,FIXVAL,15); COVAL(END,TMP1,FIXVAL,200)
WHEN 3
+  COVAL(WL1,TEM1,FIXVAL,15); COVAL(END,TEM1,FIXVAL,200)
ENDCASE
    GROUP 15. Termination of sweeps
LSWEEP=15
    GROUP 16. Termination of iterations
    GROUP 22. Spot-value print-out
IYMON=NY/2