** LOAD(419) from the PHOENICS Input Library
 
    GROUP 1. Run title and other preliminaries
TEXT(Swirling Flow Test, Inlet U1=1m/s 
TITLE
 
  DISPLAY
    This example is used to test swirling flow in a polar duct.
    The incoming flow at the low end of the domain has an inlet
    U1 velocity of 1.0 m/s causing the flow to swirl throughout
    the rest of the duct.
  ENDDIS
 
    GROUP 3. X-direction grid specification
CARTES=F
NREGX=1; REGEXT(X,1)
IREGX=1; GRDPWR(X,5,1,1)
    GROUP 4. Y-direction grid specification
NREGY=1; REGEXT(Y,1)
IREGY=1; GRDPWR(Y,5,1,1)
    GROUP 5. Z-direction grid specification
NREGZ=1; REGEXT(Z,1)
IREGZ=1; GRDPWR(Z,4,6,1)
    GROUP 7. Variables stored, solved & named
#SOLVEL
STORE(ENUT)
    GROUP 9. Properties of the medium (or media)
PRESS0=1.E+05; RHO1=1.189;ENUL=1.589E-05
TURMOD(KEMODL)
    GROUP 11. Initialization of variable or porosity fields
FIINIT(KE)=2.0E-04
FIINIT(EP)=2.2656E-05
    GROUP 13. Boundary conditions and special sources
    Cyclic boundary condition activated at X-boundaries
XCYCLE=T
    INLET boundary condition, name INLET
INLET(INLET,LOW,#1,#1,#1,#1,#1,#1,#1,#NREGT)
VALUE(INLET,U1,1.0); VALUE(INLET,V1,0); VALUE(INLET,W1,1.0)
VALUE(INLET,KE,2.0E-04)
VALUE(INLET,EP,0.09*(2.0E-04**2)/(ENUL*10))
VALUE(INLET,P1,1.0*RHO1)
    OUTLET boundary condition, name OUT
OUTLET(OUT,HIGH,#1,#1,#1,#1,#1,#1,#1,#NREGT)
VALUE(OUT,P1,0)
VALUE(OUT,U1,0.0); VALUE(OUT,V1,0.0); VALUE(OUT,W1,0.0)
        VALUE(OUT,KE,SAME); VALUE(OUT,EP,SAME)
VALUE(OUT,KE,1E-10); VALUE(OUT,EP,0.09*(1.0E-10**2)/(ENUL*10))
    WALL boundary condition, name WL1
PATCH(WL1,NWALL,#1,#1,#1,#1,#1,#1,#1,#NREGT)
COVAL(WL1,U1,LOGLAW,0.0); COVAL(WL1,W1,LOGLAW,0.0)
COVAL(WL1,KE,LOGLAW,LOGLAW); COVAL(WL1,EP,LOGLAW,LOGLAW)
    GROUP 15. Termination of sweeps
LSWEEP=100
    GROUP 16. Termination of iterations
SELREF=T; RESFAC=1.E-03
    GROUP 17. Under-relaxation devices
REAL(MAXV,MINL,RELX);MAXV=1.0;MINL=ZWLAST/NZ; RELX=1.0
RELAX(P1,LINRLX,0.8)
RELAX(U1,FALSDT,MINL/MAXV*RELX); RELAX(V1,FALSDT,MINL/MAXV*RELX)
RELAX(W1,FALSDT,MINL/MAXV*RELX)
RELAX(KE,LINRLX,0.3); RELAX(EP,LINRLX,0.3)
    GROUP 22. Spot-value print-out
IXMON=NX/2; IYMON=NY/2; IZMON=NZ/2
    GROUP 23. Field print-out and plot control
ITABL=3; NPLT=1
    GROUP 24. Dumps for restarts
 LIBREF  =     419