TALK=F;RUN( 1, 1)
PHOTON USE
p;;;;
set prop off
vi 1 2 3
msg Temperature contours on plane at mid-y
con tem1 y 25 fi; 0.01
msg press return to display the box
pause
con off
red
msg Iso-surface mark=0.99 being drawn. Please wait
sur mark x 0.99 col 10
ENDUSE
************************************************************
Group 1. Run Title
TEXT(Box-shaped In-Form object
DISPLAY
A box-shaped In-Form object is used for the specification
of the initial (and unchanging) values of the material index,
PRPS.
The value assigned is 100, which corresponds to aluminium.
The object is surrounded by air, and placed between a hot and a
cold wall.
The steady-state temperature distribution as influenced by
conduction alone.
ENDDIS
LIBREF=383
************************************************************
Group 2. Transience
STEADY=T
************************************************************
Groups 3, 4, 5 Grid Information
NX=50;NY=50;NZ=50
XULAST=1.0; YVLAST=1.0; ZWLAST=1.0
#UNIGRID
Group 7. Variables: STOREd,SOLVEd,NAMEd
* Solved variables list
SOLVE(TEM1)
SOLUTN(TEM1,Y,Y,Y,P,P,P)
* Stored variables list
STORE(PRPS,MARK) ! MARK is set to 1. in cells inside the box
************************************************************
Group 9 Properties
SPEDAT(SET,MATERIAL,100,L,T) ! needed to warn earth to load the
! properties of material to be set
! in in-form object
************************************************************
Group 11.Initialise Var/Porosity Fields
patch(patch1,volume,1,nx,1,ny,1,nz,1,1) ! the space within which
! infob_1 will be placed
FIINIT(PRPS) = 0.0
FIINIT(PRPS) = 0.0 !
inform11begin
(stored of mark at patch1 is 1.0 with infob_1) ! MARK object
(initial of prps is 100 with infob_1) ! initialise PRPS
real(x0,y0,z0,xs,ys,zs,al,be,th) ! declarations
x0=xulast/4 ! x/y/z position of box
y0=yvlast/4 !
z0=zwlast/4 !
xs=xulast/2 ! x/y/z size of box
ys=yvlast/2 !
zs=zwlast/2 !
al=0.25 ! alpha/beta/theta angles of coordinate system
be=0.25 ! of box
th=0.25 !
(infob at patch1 is box(x0,y0,z0,xs,ys,zs,al,be,th) with infob_1)
inform11end
************************************************************
Group 13. Boundary & Special Sources
patch(low,lwall,1,nx,1,ny,1,1,1,1)
coval(low,tem1,1,-1)
patch(high,hwall,1,nx,1,ny,nz,nz,1,1)
coval(high,tem1,1,1)
************************************************************
Group 15. Terminate Sweeps
LSWEEP = 2 ! many sweeps are not needed for this linear problem
RESFAC = 1.000000E-03
yzpr=t
tstswp=-1
#endpause
#maxabs
Liter(tem1)=200