GROUP 1. Run title and other preliminaries
TEXT(2DTrans Buoyant Flow Of Melt In A Ladle
TITLE
  DISPLAY
  The case considered is 2d transient turbulent fluid flow and
  heat transfer of liquid steel (melt) in a ladle. This case
  has been studied numerically by Chakraborty and Sahai (Metall.
  Trans. B, Vol.23B, p135, 1992). 
  
  The cylindrical ladle is 3.35m in diameter, and the melt depth 
  is 4m, and the holding period before release of the melt into 
  the mold is 20 minutes.
  
  The melt is taken to be stagnant and isothermal at the start
  of the holding period. The free surface is presumed flat, and
  heat loss rates are prescribed at both walls and the free
  surface. Convection currents are set up in the melt due to
  buoyancy forces resulting from the cooling of the melt with
  time. After about 5 or 10 minutes, it is expected that a
  clockwise overall recirculation pattern will be established
  within the melt.
  ENDDIS
 
                         Q=-100000 W/m2
              --------------|-------------
              |        -------->         |/
              |                          |/
              :           --->           |/
  Symmetrical | ^                        |/
    centre    | |    ^                 | |/
     line     : |    |            |    |--->Q=-12500 W/m2
      of      | |                 v    | |/
     ladle    |                        v |/
              :          <---            |/
       Z ^    |                          |/
         |    |        <--------         |/
         |    --------------|-------------
         |-------> Y        V
                        Q=-12500 W/m2
  PHOTON USE
    P
 
 
 
    UP Z
    VEC X 1 SH
    PAU;CL
    CON TMP1 X 1 FI;.01
  ENDUSE
REAL(CPM,RHORM,TCM);CPM=750.0;RHORM=7000.0;TCM=41.0
    GROUP 2. Transience; time-step specification
   ** Recommend DT=2s but use DT=4s for library purposes
      Estimated runtime = 30min on Pentium P200
REAL(TTOTAL,DTIME);TTOTAL=20.*60.;DTIME=4.0
LSTEP=TTOTAL/DTIME
STEADY=F;GRDPWR(T,LSTEP,TTOTAL,1.0)
    GROUP 3. X-direction grid specification
CARTES=F;XULAST=0.1
    GROUP 4. Y-direction grid specification
YVLAST=1.675
REAL(RADC);RADC=1.675/2.0
NREGY=2
   ** Chakraborty and Sahai use NY=25
INTEGER(NYRG1,NYRG2)
IREGY=1;NYRG1=5;GRDPWR(Y,NYRG1,RADC, 1.3)
IREGY=2;NYRG2=7;GRDPWR(Y,NYRG2,RADC,-1.3)
    GROUP 5. Z-direction grid specification
ZWLAST=4.0
NREGZ=2
   ** Chakraborty and Sahai use NZ=30
INTEGER(NZRG1,NZRG2)
IREGZ=1;NZRG1=8;GRDPWR(Z,NZRG1,2.0, 1.3)
IREGZ=2;NZRG2=8;GRDPWR(Z,NZRG2,2.0,-1.3)
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1,H1);STORE(RHO1,TMP1,ENUT)
TURMOD(KEMODL)
SOLUTN(P1,Y,Y,Y,N,N,N);SOLUTN(H1,Y,Y,Y,P,P,N)
SOLUTN(V1,P,P,Y,P,P,N);SOLUTN(W1,P,P,Y,P,P,N)
    GROUP 8. Terms (in differential equations) & devices
    GROUP 9. Properties of the medium (or media)
ENUL=5.0E-3/RHORM
  ** Set the temperature as TMP1=TMP1A+TMP1B*H1
     i.e. TMP1=To + (H-Ho)/CP1  where Ho=0.0 & To=1580.
TMP1=GRND2;TMP1A=1580.0;TMP1B=1.0/CPM; cp1=cpm
  ** Set the density as RHO1A+RHO1B*H1
     i.e. RHO1=RHOo + 1.4*(Ho-H)/CP1  where RHOo=RHORM
RHO1=GRND1;RHO1A=RHORM;RHO1B=-1.4/CPM
PRNDTL(H1)=ENUL*RHORM*CPM/TCM;PRT(H1)=0.9
CP1=CPM
    GROUP 11. Initialization of variable or porosity fields
FIINIT(H1)=0.0;FIINIT(RHO1)=RHORM;FIINIT(TMP1)=1580.0
    GROUP 13. Boundary conditions and special sources
  ** Heat loss flux from TOP surface
PATCH(QTOP,HIGH,1,1,1,NY,NZ,NZ,1,LSTEP)
COVAL(QTOP,H1,FIXFLU,-100000.0)
 
  ** BOTTOM wall
WALL(BOTTOM,LOW,1,1,1,NY,1,1,1,LSTEP)
 
  ** Heat loss flux through BOTTOM wall
PATCH(QBOT,LOW,1,1,1,NY,1,1,1,LSTEP)
COVAL(QBOT,H1,FIXFLU,-12500.0)
 
  ** Side wall
WALL(SIDEW,NORTH,1,1,NY,NY,1,NZ,1,LSTEP)
 
  ** Heat loss fluxes through SIDE wall
PATCH(QSIDE,NORTH,1,1,NY,NY,1 ,NZ,1,LSTEP)
COVAL(QSIDE,H1,FIXFLU,-12500.0)
 
  ** Buoyancy
PATCH(BUOYANCY,PHASEM,1,1,1,NY,1,NZ,1,LSTEP)
COVAL(BUOYANCY,W1,FIXFLU,GRND2)
BUOYA=0.0;BUOYB=0.0;BUOYC=-9.81;BUOYD=RHORM
    GROUP 15. Termination of sweeps
LSWEEP=30
SELREF=F;RESREF(P1)=1.0E-12
LITER(P1)=100;LITER(H1)=100;ENDIT(P1)=GRND1
    GROUP 17. Under-relaxation devices
    GROUP 19.
   ** Dump PHI files every 5 minutes
IDISPA = 75;CSG1   = G
SPEDAT(SET,GXMONI,TRANSIENT,L,F)
         GROUP 20. Preliminary print-out
    GROUP 21. Print-out of variables
OUTPUT(TMP1,Y,Y,Y,Y,Y,Y)
NTPRIN=75
    GROUP 22. Spot-value print-out
IXMON=1;IYMON=NY-1;IZMON=NZ-1
NPRMON=10000;TSTSWP=-1;ITABL=3;NPLT=5
    GROUP 23. Field print-out and plot control
DISTIL=T
EX(P1  )=3.135E+02;EX(W1  )=2.190E-02;EX(H1  )=7.389E+03
EX(TMP1)=1.570E+03;EX(RHO1)=7.014E+03