GROUP 1. Run title and other preliminaries
TEXT(Impinging Jet In Rectangular Grid
TITLE
DISPLAY
This run illustrates the flow arising when a cold round
laminar jet impinges directly on to a flat surface
(referred to as the floor). The jet enters the domain
through the low boundary at iz=1, and it is spread over
several cells in order to represent the round shape of the
jet, as indicated in the diagram on the right:
|--------------------->x |---|---|---|---------->x
| \ |---|---|---|
| \ |---|---|
| \ |---| \
| \ | \
| \ | cells through
| jet \ | which jet enters
z| \ | domain.
V| \ y|
| \------ V
|______________________floor
ENDDIS
A regular cartesian grid is used instead of a cylindrical-
polar grid in order to test that a round jet will spread
isotropically through a cartesian grid. It is important
that this should occur when the jet is part of a larger
problem that requires a cartesian grid.
Interesting variants of this problem include changes to:
the jet velocity; the location of the jet; and oblique
impingement.
REAL(RJ,WJ,AA,DX)
INTEGER(JJ1)
RJ.....jet radius
WJ.....velocity of the jet.
AA.....ratio used in specification of geometric progression
of grid-step size.
DX.....grid increment in the x direction.
GROUP 3. X-direction grid specification
NX=12; RJ=0.1; AA=1.3; DX=.25*RJ
**The following settings prescribe an x-direction grid
spacing which expands geometrically...
XFRAC(1)=RJ*.5;XFRAC(2)=RJ*.75; XFRAC(3)=RJ
DO JJ=4,11
+ JJ1=JJ-1; XFRAC(JJ)=XFRAC(JJ1)+DX; DX=DX*AA
ENDDO
XFRAC(12)=1.0
GROUP 4. Y-direction grid specification
NY=12
**The following statements set the y-direction grid
spacing equal to that of the x-direction spacings...
DO JJ=1,12
+ YFRAC(JJ)=XFRAC(JJ)
ENDDO
GROUP 5. Z-direction grid specification
**A uniform grid spacing is used for the z direction...
GRDPWR(Z,10,1.0,1.0)
GROUP 7. Variables stored, solved & named
SOLVE(P1,U1,V1,W1)
**The pressure is solved whole field...
SOLUTN(P1,Y,Y,Y,N,N,N)
GROUP 9. Properties of the medium (or media)
ENUL=0.01; WJ=10.0
GROUP 13. Boundary conditions and special sources
**Three PATCHs are used to represent the inflow of the jet
for the cells shown in the diagram above...
INLET(JET1,LOW,1,1,1,3,1,1,1,1)
VALUE(JET1,P1,WJ); VALUE(JET1,W1,WJ)
INLET(JET2,LOW,2,2,1,2,1,1,1,1)
VALUE(JET2,P1,WJ); VALUE(JET2,W1,WJ)
INLET(JET3,LOW,3,3,1,1,1,1,1,1)
VALUE(JET3,P1,WJ); VALUE(JET3,W1,WJ)
**Fixed pressure boundaries are prescribed at the east and
north boundaries (symmetry planes are implied by default
at the west and south boundaries)...
PATCH(FREE1,EAST,NX,NX,1,NY,1,NZ,1,1)
COVAL(FREE1,P1,1000.,0.0); COVAL(FREE1,W1,ONLYMS,0.0)
COVAL(FREE1,U1,ONLYMS,0.0); COVAL(FREE1,V1,ONLYMS,0.0)
PATCH(FREE2,NORTH,1,NX,NY,NY,1,NZ,1,1)
COVAL(FREE2,P1,1000.,0.0); COVAL(FREE2,W1,ONLYMS,0.0)
COVAL(FREE2,U1,ONLYMS,0.0); COVAL(FREE2,V1,ONLYMS,0.0)
**On the floor, laminar friction is activated for cells
outside of the inlet orifice...
PATCH(FREE3,LOW,4,NX,1,NY,1,1,1,1)
COVAL(FREE3,P1,1000.,0.); COVAL(FREE3,W1,ONLYMS,0.0)
COVAL(FREE3,U1,ONLYMS,0.0); COVAL(FREE3,V1,ONLYMS,0.0)
PATCH(FREE4,LOW,1,4,4,NY,1,1,1,1)
COVAL(FREE4,P1,1000.,0.); COVAL(FREE4,W1,ONLYMS,0.0)
COVAL(FREE4,U1,ONLYMS,0.0); COVAL(FREE4,V1,ONLYMS,0.0)
PATCH(FREE5,LOW,3,3,2,3,1,1,1,1)
COVAL(FREE5,P1,1000.,0.); COVAL(FREE5,W1,ONLYMS,0.0)
COVAL(FREE5,U1,ONLYMS,0.0); COVAL(FREE5,V1,ONLYMS,0.0)
PATCH(FREE6,LOW,2,2,3,3,1,1,1,1)
COVAL(FREE6,P1,1000.,0.); COVAL(FREE6,W1,ONLYMS,0.0)
COVAL(FREE6,U1,ONLYMS,0.0); COVAL(FREE6,V1,ONLYMS,0.0)
PATCH(FLOOR,HWALL,1,NX,1,NY,NZ,NZ,1,1)
COVAL(FLOOR,U1,1.0,0.0); COVAL(FLOOR,V1,1.0,0.0)
GROUP 15. Termination of sweeps
LSWEEP=60
GROUP 17. Under-relaxation devices
RELAX(U1,FALSDT,1.0); RELAX(V1,FALSDT,1.0); RELAX(W1,FALSDT,1.0)
GROUP 22. Spot-value print-out
IXMON=NX/2; IYMON=NY/2; IZMON=NZ
GROUP 23. Field print-out and plot control
NPLT=2; ITABL=3; IXPRL=8; IYPRL=8; NZPRIN=4
**Contour plot of pressure up to the eighth control volume...
PATCH(IXEQ10,CONTUR,1,8,1,8,NZ,NZ,1,1)
PLOT(IXEQ10,P1,0.0,20.0)
ICHR=3