xprtbegin ... start of the inputs to expert via q1
  expsol f .... expert is not used in the solver
  expdtf t .... expert is used to adjust false time step
  indtf 2   ... adjust the false time step of all velocities
  inres 7   ... monitor the residuals of variable 3
  ifrsts 10 ... first adjustment sweep
  ifrequ 5 ... adjustments will be made every ifrequ sweeps
  facdec 0.25 .. decreases will be by a factor of facdec
  facinc 5.0 .. increases will be by a factor of facinc
  exprin t .... print adjusted false time steps in result file
  expend  ..... end of the inputs to expert via q1
  xprtend
expert=t
  photon use
  p
 
 
 
 
  up z
  msg the grid. press return for temperature contours
  gr x 1;pause; gr off;red;gr ou x 1
  msg temperature contours. press return for velocity vectors
  con temp x 1 fi;0.0002;pause; con off;red;se re ve 2;vec x 1 sh
  msg velocity vectors. press return for reduced-pressure contours
  pause;vec off;red;con p1 x 1 fi;0.0002
  enduse
 
  GROUP 1. RUN TITLE AND OTHER PRELIMINARIES
TEXT(Laminar Free Convection In Cavity 
TITLE
  DISPLAY
  A two-dimensional square cavity is formed between two vertical
  walls, one of which is heated and the other cooled. The top and
  bottom of the cavity are bounded by walls at which there is
  friction but no heat transfer.
  ENDDIS
 
                   SPECIAL DATA
                   ============
 
    DVO1DT    the coefficient of thermal expansion      1/k
    AGRAV     gravity                                   m/s^2
    HREF      reference enthalpy                        j/kg
    CAVL      the length of the cavity                  m
 
REAL(TREF,AGRAV,CAVL,THOT,TCOLD)
DVO1DT = 2.874E-01*CP1; AGRAV = 9.81; TREF  = 0.0; CAVL  = 3.626E-02
THOT=10.0; TCOLD=-10.0
    GROUP 4. Y-DIRECTION GRID SPECIFICATION
  *** The value of yvlast = zwlast = cavl , determines the
      Rayleigh number; this run is set for Ra=1e5 (a laminar value)
NREGY=3
IREGY=1; GRDPWR(Y,10,0.15*CAVL,1.0)
IREGY=2; GRDPWR(Y,20,0.70*CAVL,1.0)
IREGY=3; GRDPWR(Y,10,0.15*CAVL,1.0)
 
    GROUP 5. z-direction grid specification
GRDPWR(Z,40,CAVL,1.0)
 
    GROUP 7. Variables stored, solved & named
   *** whole-field solver for p1 is activated.
SOLVE(P1,V1,W1,H1); SOLUTN(P1,Y,Y,Y,N,N,N); NAME(H1)=TEMP
 
    GROUP 8. TERMS (IN DIFFERENTIAL EQUATIONS) & DEVICES
   *** deactivate the built-in source in temp equation.
TERMS(TEMP,N,Y,Y,Y,Y,Y)
    CSG3=CNGR
 
    GROUP 9. PROPERTIES OF THE MEDIUM (OR MEDIA)
RHO1=1.207; ENUL=1.5E-04; PRNDTL(TEMP)=0.71
 
    GROUP 13. Boundary conditions and special sources
 
   1. Hot wall boundary: constant temperature of 10 deg.
WALL (HOT,SOUTH,1,1,1,1,1,NZ,1,1)
COVAL(HOT,W1,1.0,0.0); COVAL(HOT,TEMP,1.0,10.0)
 
   2. Cold wall boundary: constant temperature of -10 deg.
WALL (COLD,NORTH,1,1,NY,NY,1,NZ,1,1)
COVAL(COLD,W1,1.0,0.0); COVAL(COLD,TEMP,1.0,-10.0)
 
   3. Low wall boundary: adiabatic but with friction
WALL (LOWAL,LOW,1,1,1,NY,1,1,1,1); COVAL(LOWAL,V1,1.0,0.0)
 
   4. High wall boundary: adiabatic but with friction
WALL (HIWAL,HIGH,1,1,1,NY,NZ,NZ,1,1); COVAL(HIWAL,V1,1.0,0.0)
 
   5. Buoyancy force
#gravity
gravdir=6; href=0.0
#bouss
 
   6. Reference pressure at the centre of the cavity
PATCH(REFP,CELL,1,1,NY/2,NY/2,NZ/2,NZ/2,1,1)
COVAL(REFP,P1,FIXP,0.0);COVAL(REFP,V1,ONLYMS,0.0)
COVAL(REFP,TEMP,ONLYMS,SAME)
    GROUP 15. TERMINATION OF SWEEPS
LSWEEP=100; SELREF=T; RESFAC=10.
 
    GROUP 16. Termination of iterations
LITER(P1)=-30; LITER(V1)=20;LITER(W1)=20
    GROUP 17. Under-relaxation devices
RELAX(V1,FALSDT,1.E-03); RELAX(W1,FALSDT,1.E-03)
RELAX(TEMP,FALSDT,1.0)
varmin(temp)=-1.e11;varmax(temp) =0.1*(THOT-TCOLD)  ! recommended 
                                                    ! for buoyancy
    GROUP 19. Data communicated by satellite to GROUND
 
    GROUP 22. Spot-value print-out
IYMON=5; IZMON=20; NYPRIN=NY/5; NZPRIN=NZ/5; NPLT=1
TSTSWP=-1
 
    GROUP 23. Field print-out and plot control
  *** Temperature and velocity profiles
PATCH(PROF,PROFIL,1,1,1,NY,NZ/2,NZ/2,1,1)
PLOT (PROF,W1,0.0,0.0); PLOT (PROF,TEMP,-10.0,10.0)
 
  *** Temperature contours
PATCH(CONT,CONTUR,1,1,1,NY,1,NZ,1,1)
PLOT (CONT,TEMP,0.0,10.0)