DISPLAY
     A fluid flows steadily in a direction normal to a
  flat plate. The Reynolds Number (i.e. velocity times
  plate width divided by kinematic viscosity) equals 10.0.
  The flow has one plane of symmetry which is represented
  by an impermeable frictionless boundary.
     This case is similar to one solved by PHOENICS-81
   and described in the report  PDR/CHAM UK/15.
  ENDDIS
 
    GROUP 1. Run title and other preliminaries
TEXT(2D Low-Re Flow Past A Plate       
TITLE
REAL(REYNO,W1IN); REYNO=10.0; W1IN=1.0
 
    GROUP 4. Y-direction grid specification
GRDPWR(Y,20,4.0,1.0)
 
    GROUP 5. Z-direction grid specification
GRDPWR(Z,70,14.,1.)
 
    GROUP 7. Variables stored, solved & named
SOLVE(P1,V1,W1); SOLUTN(P1,Y,Y,Y,N,N,N)
 
    GROUP 9. Properties of the medium (or media)
ENUL=W1IN*YVLAST*0.5/REYNO
 
    GROUP 11. Initialization of variable or porosity fields
FIINIT(W1)=W1IN
   **Plate
CONPOR(PLAT,0.0,HIGH,1,1,1,NY/4,-20,-20)
 
    GROUP 13. Boundary conditions and special sources
   **Upstream boundary
INLET(UPSTRM,LOW,1,1,1,NY,1,1,1,1)
VALUE(UPSTRM,P1,RHO1*W1IN)
VALUE(UPSTRM,W1,W1IN)
   **Downstream boundary
PATCH(DWNSTRM,HIGH,1,1,1,NY,NZ,NZ,1,1)
COVAL(DWNSTRM,P1,1.E5,0.0); COVAL(DWNSTRM,W1,ONLYMS,W1IN)
   **High-y boundary
PATCH(TOP,NORTH,1,1,NY,NY,1,NZ,1,1)
COVAL(TOP,P1,1.E5,0.); COVAL(TOP,W1,ONLYMS,W1IN)
   **Plate (the necessary patch has been generated by the CONPOR
   **in group 11 above).
COVAL(PLAT,W1,FIXVAL,0.0)
 
    GROUP 15. Termination of sweeps
LSWEEP=20; RESREF(P1)=1.E-6*RHO1*W1IN*YVLAST
 
    GROUP 16. Termination of iterations
LITER(P1)=-50
 
    GROUP 17. Under-relaxation devices
RELAX(V1,FALSDT,1.0); RELAX(W1,FALSDT,1.0)
 
    GROUP 21. Print-out of variables
OUTPUT(HPOR,N,N,N,N,N,N)
 
    GROUP 22. Spot-value print-out
IYMON=10; IZMON=25
 
    GROUP 23. Field print-out and plot control
NYPRIN=2; NZPRIN=2; IYPRL=10; IZPRF=20; IZPRL=40; NPLT=1
PATCH(PROF,PROFIL,1,1,1,NY,25,25,1,1); PLOT(PROF,W1,0.0,0.0)
PATCH(CONT,CONTUR,1,1,1,NY,1,NZ,1,1); PLOT(CONT,P1,0.0,10.0)
PLOT(CONT,W1,0.0,10); PLOT(CONT,V1,0.0,10.0)