GROUP 1. Run title and other preliminaries
TEXT(1D 30-Degree X-Direction Diffuser 
TITLE
  DISPLAY
  This run shows the flow in a one-dimensional x-direction
  diffuser. Porosities are used to represent the non-uniform
  cross-section area.
  Interesting changes include:changes to the density of the fluid
  and inlet velocity.
  ENDDIS
 
    GROUP 3. X-direction grid specification
GRDPWR(X,5,1.0,1.0)
 
    GROUP 7. Variables stored, solved & named
SOLVE(P1,U1)
  ** Provide storage for porosities on the east faces.
STORE(EPOR)
 
    GROUP 11. Initialization of variable or porosity fields
  ** Set varying-cross section area by means of non-uniform
     porosities.
INIADD=T     
PATCH(SECTN,LINVLX,1,NX,1,1,1,1,1,1);INIT(SECTN,EPOR,1.1547,1.239)
 
    GROUP 13. Boundary conditions and special sources
  ** Inlet
INLET(IN,WEST,1,1,1,1,1,1,1,1)
VALUE(IN,P1,2.1547);VALUE(IN,U1,1.751)
  ** Outlet
PATCH(OUTLET,FREEE,NX,NX,1,1,1,1,1,1)
COVAL(OUTLET,P1,FIXP,0.0)
COVAL(OUTLET,U1,ONLYMS,0.0)
 
    GROUP 15. Termination of sweeps
LSWEEP=20
 
    GROUP 17. Under-relaxation devices
RELAX(U1,FALSDT,1.0)
 
    GROUP 23. Field print-out and plot control
PATCH(LONGPLOT,PROFIL,1,NX,1,1,1,1,1,1)
PLOT(LONGPLOT,P1,-0.6,1.0);PLOT(LONGPLOT,U1,1.1,1.8)